perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Carp;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '9,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '9,Connection Type',
  52                   'sort' => '9,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   wx => '0,Want WX,yesno',
  55                   talk => '0,Want Talk,yesno',
  56                   ann => '0,Want Announce,yesno',
  57                   here => '0,Here?,yesno',
  58                   confmode => '0,In Conference?,yesno',
  59                   dx => '0,DX Spots,yesno',
  60                   redirect => '0,Redirect messages to',
  61                   lang => '0,Language',
  62                   func => '9,Function',
  63                   loc => '9,Local Vars', # used by func to store local variables in
  64                   beep => '0,Want Beeps,yesno',
  65                   lastread => '9,Last Msg Read',
  66                   outbound => '9,outbound?,yesno',
  67                   remotecmd => '9,doing rcmd,yesno',
  68                   pagelth => '0,Page Length',
  69                   pagedata => '9,Page Data Store',
  70                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  71                   isolate => '9,Isolate network,yesno',
  72                   delayed => '9,Delayed messages,parray',
  73                  );
  74
  75 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
  76 sub alloc
  77 {
  78         my ($pkg, $call, $conn, $user) = @_;
  79         my $self = {};
  80
  81         die "trying to create a duplicate channel for $call" if $channels{$call};
  82         $self->{call} = $call;
  83         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
  84         if (defined $user) {
  85                 $self->{user} = $user;
  86                 $self->{lang} = $user->lang;
  87                 $user->new_group() if !$user->group;
  88                 $self->{group} = $user->group;
  89         }
  90         $self->{startt} = $self->{t} = time;
  91         $self->{state} = 0;
  92         $self->{oldstate} = 0;
  93         $self->{lang} = $main::lang if !$self->{lang};
  94         $self->{func} = "";
  95         bless $self, $pkg;
  96         return $channels{$call} = $self;
  97 }
  98
  99 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 100 sub get
 101 {
 102         my ($pkg, $call) = @_;
 103         return $channels{$call};
 104 }
 105
 106 # obtain all the channel objects
 107 sub get_all
 108 {
 109         my ($pkg) = @_;
 110         return values(%channels);
 111 }
 112
 113 # obtain a channel object by searching for its connection reference
 114 sub get_by_cnum
 115 {
 116         my ($pkg, $conn) = @_;
 117         my $self;
 118
 119         foreach $self (values(%channels)) {
 120                 return $self if ($self->{conn} == $conn);
 121         }
 122         return undef;
 123 }
 124
 125 # get rid of a channel object [$obj->del()]
 126 sub del
 127 {
 128         my $self = shift;
 129
 130         $self->{group} = undef;         # belt and braces
 131         delete $channels{$self->{call}};
 132 }
 133
 134 # is it an ak1a cluster ?
 135 sub is_ak1a
 136 {
 137         my $self = shift;
 138         return $self->{'sort'} eq 'A';
 139 }
 140
 141 # is it a user?
 142 sub is_user
 143 {
 144         my $self = shift;
 145         return $self->{'sort'} eq 'U';
 146 }
 147
 148 # is it a connect type
 149 sub is_connect
 150 {
 151         my $self = shift;
 152         return $self->{'sort'} eq 'C';
 153 }
 154
 155 # handle out going messages, immediately without waiting for the select to drop
 156 # this could, in theory, block
 157 sub send_now
 158 {
 159         my $self = shift;
 160         my $conn = $self->{conn};
 161         my $sort = shift;
 162         my $call = $self->{call};
 163
 164         for (@_) {
 165                 chomp;
 166                 $conn->send_now("$sort$call|$_") if $conn;
 167                 dbg('chan', "-> $sort $call $_") if $conn;
 168         }
 169         $self->{t} = time;
 170 }
 171
 172 #
 173 # the normal output routine
 174 #
 175 sub send                                                # this is always later and always data
 176 {
 177         my $self = shift;
 178         my $conn = $self->{conn};
 179         my $call = $self->{call};
 180
 181         for (@_) {
 182                 chomp;
 183                 $conn->send_later("D$call|$_") if $conn;
 184                 dbg('chan', "-> D $call $_") if $conn;
 185         }
 186         $self->{t} = time;
 187 }
 188
 189 # send a file (always later)
 190 sub send_file
 191 {
 192         my ($self, $fn) = @_;
 193         my $call = $self->{call};
 194         my $conn = $self->{conn};
 195         my @buf;
 196
 197         open(F, $fn) or die "can't open $fn for sending file ($!)";
 198         @buf = <F>;
 199         close(F);
 200         $self->send(@buf);
 201 }
 202
 203 # this will implement language independence (in time)
 204 sub msg
 205 {
 206         my $self = shift;
 207         return DXM::msg($self->{lang}, @_);
 208 }
 209
 210 # stick a broadcast on the delayed queue
 211 sub delay
 212 {
 213         my $self = shift;
 214         my $s = shift;
 215
 216         $self->{delayed} = [] unless $self->{delayed};
 217         push @{$self->{delayed}}, $s;
 218 }
 219
 220 # change the state of the channel - lots of scope for debugging here :-)
 221 sub state
 222 {
 223         my $self = shift;
 224         if (@_) {
 225                 $self->{oldstate} = $self->{state};
 226                 $self->{state} = shift;
 227                 $self->{func} = '' unless defined $self->{func};
 228                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 229
 230                 # if there is any queued up broadcasts then splurge them out here
 231                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 232                         for (@{$self->{delayed}}) {
 233                                 $self->send($_);
 234                         }
 235                         delete $self->{delayed};
 236                 }
 237         }
 238         return $self->{state};
 239 }
 240
 241 # disconnect this channel
 242 sub disconnect
 243 {
 244         my $self = shift;
 245         my $user = $self->{user};
 246         my $conn = $self->{conn};
 247         my $call = $self->{call};
 248
 249         $self->finish();
 250         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 251         $user->close() if defined $user;
 252         $conn->disconnect() if $conn;
 253         $self->del();
 254 }
 255
 256 #
 257 # just close all the socket connections down without any fiddling about, cleaning, being
 258 # nice to other processes and otherwise telling them what is going on.
 259 #
 260 # This is for the benefit of forked processes to prepare for starting new programs, they
 261 # don't want or need all this baggage.
 262 #
 263
 264 sub closeall
 265 {
 266         my $ref;
 267         foreach $ref (values %channels) {
 268                 $ref->{conn}->disconnect() if $ref->{conn};
 269         }
 270 }
 271
 272 # various access routines
 273
 274 #
 275 # return a list of valid elements
 276 #
 277
 278 sub fields
 279 {
 280         return keys(%valid);
 281 }
 282
 283 #
 284 # return a prompt for a field
 285 #
 286
 287 sub field_prompt
 288 {
 289         my ($self, $ele) = @_;
 290         return $valid{$ele};
 291 }
 292
 293 no strict;
 294 sub AUTOLOAD
 295 {
 296         my $self = shift;
 297         my $name = $AUTOLOAD;
 298         return if $name =~ /::DESTROY$/;
 299         $name =~ s/.*:://o;
 300
 301         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 302         @_ ? $self->{$name} = shift : $self->{$name} ;
 303 }
 304
 305 1;
 306 __END__;