perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Carp;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '9,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '9,Connection Type',
  52                   'sort' => '9,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   wx => '0,Want WX,yesno',
  55                   talk => '0,Want Talk,yesno',
  56                   ann => '0,Want Announce,yesno',
  57                   here => '0,Here?,yesno',
  58                   confmode => '0,In Conference?,yesno',
  59                   dx => '0,DX Spots,yesno',
  60                   redirect => '0,Redirect messages to',
  61                   lang => '0,Language',
  62                   func => '9,Function',
  63                   loc => '9,Local Vars', # used by func to store local variables in
  64                   beep => '0,Want Beeps,yesno',
  65                   lastread => '9,Last Msg Read',
  66                   outbound => '9,outbound?,yesno',
  67                   remotecmd => '9,doing rcmd,yesno',
  68                   pagelth => '0,Page Length',
  69                   pagedata => '9,Page Data Store',
  70                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  71                   isolate => '9,Isolate network,yesno',
  72                   delayed => '9,Delayed messages,parray',
  73                   annfilter => '9,Announce Filter',
  74                   wwvfilter => '9,WWV Filter',
  75                   spotfilter => '9,Spot Filter',
  76                   passwd => '9,Passwd List,parray',
  77                  );
  78
  79 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
  80 sub alloc
  81 {
  82         my ($pkg, $call, $conn, $user) = @_;
  83         my $self = {};
  84
  85         die "trying to create a duplicate channel for $call" if $channels{$call};
  86         $self->{call} = $call;
  87         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
  88         if (defined $user) {
  89                 $self->{user} = $user;
  90                 $self->{lang} = $user->lang;
  91                 $user->new_group() if !$user->group;
  92                 $self->{group} = $user->group;
  93         }
  94         $self->{startt} = $self->{t} = time;
  95         $self->{state} = 0;
  96         $self->{oldstate} = 0;
  97         $self->{lang} = $main::lang if !$self->{lang};
  98         $self->{func} = "";
  99         bless $self, $pkg;
 100         return $channels{$call} = $self;
 101 }
 102
 103 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 104 sub get
 105 {
 106         my ($pkg, $call) = @_;
 107         return $channels{$call};
 108 }
 109
 110 # obtain all the channel objects
 111 sub get_all
 112 {
 113         my ($pkg) = @_;
 114         return values(%channels);
 115 }
 116
 117 # obtain a channel object by searching for its connection reference
 118 sub get_by_cnum
 119 {
 120         my ($pkg, $conn) = @_;
 121         my $self;
 122
 123         foreach $self (values(%channels)) {
 124                 return $self if ($self->{conn} == $conn);
 125         }
 126         return undef;
 127 }
 128
 129 # get rid of a channel object [$obj->del()]
 130 sub del
 131 {
 132         my $self = shift;
 133
 134         $self->{group} = undef;         # belt and braces
 135         delete $channels{$self->{call}};
 136 }
 137
 138 # is it an ak1a cluster ?
 139 sub is_ak1a
 140 {
 141         my $self = shift;
 142         return $self->{'sort'} eq 'A';
 143 }
 144
 145 # is it a user?
 146 sub is_user
 147 {
 148         my $self = shift;
 149         return $self->{'sort'} eq 'U';
 150 }
 151
 152 # is it a connect type
 153 sub is_connect
 154 {
 155         my $self = shift;
 156         return $self->{'sort'} eq 'C';
 157 }
 158
 159 # handle out going messages, immediately without waiting for the select to drop
 160 # this could, in theory, block
 161 sub send_now
 162 {
 163         my $self = shift;
 164         my $conn = $self->{conn};
 165         my $sort = shift;
 166         my $call = $self->{call};
 167
 168         for (@_) {
 169                 chomp;
 170                 $conn->send_now("$sort$call|$_") if $conn;
 171                 dbg('chan', "-> $sort $call $_") if $conn;
 172         }
 173         $self->{t} = time;
 174 }
 175
 176 #
 177 # the normal output routine
 178 #
 179 sub send                                                # this is always later and always data
 180 {
 181         my $self = shift;
 182         my $conn = $self->{conn};
 183         my $call = $self->{call};
 184
 185         for (@_) {
 186                 chomp;
 187                 $conn->send_later("D$call|$_") if $conn;
 188                 dbg('chan', "-> D $call $_") if $conn;
 189         }
 190         $self->{t} = time;
 191 }
 192
 193 # send a file (always later)
 194 sub send_file
 195 {
 196         my ($self, $fn) = @_;
 197         my $call = $self->{call};
 198         my $conn = $self->{conn};
 199         my @buf;
 200
 201         open(F, $fn) or die "can't open $fn for sending file ($!)";
 202         @buf = <F>;
 203         close(F);
 204         $self->send(@buf);
 205 }
 206
 207 # this will implement language independence (in time)
 208 sub msg
 209 {
 210         my $self = shift;
 211         return DXM::msg($self->{lang}, @_);
 212 }
 213
 214 # stick a broadcast on the delayed queue
 215 sub delay
 216 {
 217         my $self = shift;
 218         my $s = shift;
 219
 220         $self->{delayed} = [] unless $self->{delayed};
 221         push @{$self->{delayed}}, $s;
 222 }
 223
 224 # change the state of the channel - lots of scope for debugging here :-)
 225 sub state
 226 {
 227         my $self = shift;
 228         if (@_) {
 229                 $self->{oldstate} = $self->{state};
 230                 $self->{state} = shift;
 231                 $self->{func} = '' unless defined $self->{func};
 232                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 233
 234                 # if there is any queued up broadcasts then splurge them out here
 235                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 236                         for (@{$self->{delayed}}) {
 237                                 $self->send($_);
 238                         }
 239                         delete $self->{delayed};
 240                 }
 241         }
 242         return $self->{state};
 243 }
 244
 245 # disconnect this channel
 246 sub disconnect
 247 {
 248         my $self = shift;
 249         my $user = $self->{user};
 250         my $conn = $self->{conn};
 251         my $call = $self->{call};
 252
 253         $self->finish();
 254         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 255         $user->close() if defined $user;
 256         $conn->disconnect() if $conn;
 257         $self->del();
 258 }
 259
 260 #
 261 # just close all the socket connections down without any fiddling about, cleaning, being
 262 # nice to other processes and otherwise telling them what is going on.
 263 #
 264 # This is for the benefit of forked processes to prepare for starting new programs, they
 265 # don't want or need all this baggage.
 266 #
 267
 268 sub closeall
 269 {
 270         my $ref;
 271         foreach $ref (values %channels) {
 272                 $ref->{conn}->disconnect() if $ref->{conn};
 273         }
 274 }
 275
 276 # various access routines
 277
 278 #
 279 # return a list of valid elements
 280 #
 281
 282 sub fields
 283 {
 284         return keys(%valid);
 285 }
 286
 287 #
 288 # return a prompt for a field
 289 #
 290
 291 sub field_prompt
 292 {
 293         my ($self, $ele) = @_;
 294         return $valid{$ele};
 295 }
 296
 297 no strict;
 298 sub AUTOLOAD
 299 {
 300         my $self = shift;
 301         my $name = $AUTOLOAD;
 302         return if $name =~ /::DESTROY$/;
 303         $name =~ s/.*:://o;
 304
 305         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 306         @_ ? $self->{$name} = shift : $self->{$name} ;
 307 }
 308
 309 1;
 310 __END__;