perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2007 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35
  36 use strict;
  37
  38 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  39                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  40                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  41                         $investigation_int $pc19_version $myprot_version
  42                         %nodehops $baddx $badspotter $badnode $censorpc
  43                         $allowzero $decode_dk0wcy $send_opernam @checklist
  44                         $eph_pc15_restime $pc9x_past_age $pc9x_dupe_age
  45                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  46                         $pc92Ain $pc92Cin $pc92Din $pc92Kin $pc9x_time_tolerance
  47                         $pc92filterdef
  48                    );
  49
  50 $pc9x_dupe_age = 60;                    # catch loops of circular (usually) D records
  51 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  52 $pc92_slug_changes = 60*5;              # slug any changes going outward for this long
  53 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  54 $pc9x_time_tolerance = 15*60;   # the time on a pc9x is allowed to be out by this amount
  55 $pc9x_past_age = (122*60)+              # maximum age in the past of a px9x (a config record might be the only
  56         $pc9x_time_tolerance;           # thing a node might send - once an hour and we allow an extra hour for luck)
  57                                 # this is actually the partition between "yesterday" and "today" but old.
  58
  59 $pc92filterdef = bless ([
  60                           # tag, sort, field, priv, special parser
  61                           ['call', 'c', 0],
  62                           ['by', 'c', 0],
  63                           ['dxcc', 'nc', 1],
  64                           ['itu', 'ni', 2],
  65                           ['zone', 'nz', 3],
  66                          ], 'Filter::Cmd');
  67
  68
  69 # incoming talk commands
  70 sub handle_10
  71 {
  72         my $self = shift;
  73         my $pcno = shift;
  74         my $line = shift;
  75         my $origin = shift;
  76         my $pc = shift;
  77
  78         # this is to catch loops caused by bad software ...
  79         if (eph_dup($line, $pc10_dupe_age)) {
  80                 return;
  81         }
  82
  83         # will we allow it at all?
  84         if ($censorpc) {
  85                 my @bad;
  86                 if (@bad = BadWords::check($pc->[3])) {
  87                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
  88                         return;
  89                 }
  90         }
  91
  92         # is it for me or one of mine?
  93         my ($from, $to, $via, $call, $dxchan);
  94         $from = $pc->[1];
  95         if ($pc->[5] gt ' ') {
  96                 $via = $pc->[2];
  97                 $to = $pc->[5];
  98         } else {
  99                 $to = $pc->[2];
 100         }
 101
 102         # if this is a 'nodx' node then ignore it
 103         if ($badnode->in($pc->[6]) || ($via && $badnode->in($via))) {
 104                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 105                 return;
 106         }
 107
 108         # if this is a 'bad spotter' user then ignore it
 109         my $nossid = $from;
 110         $nossid =~ s/-\d+$//;
 111         if ($badspotter->in($nossid)) {
 112                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 113                 return;
 114         }
 115
 116         # if we are converting announces to talk is it a dup?
 117         if ($ann_to_talk) {
 118                 if (AnnTalk::is_talk_candidate($from, $pc->[3]) && AnnTalk::dup($from, $to, $pc->[3])) {
 119                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 120                         return;
 121                 }
 122         }
 123
 124         # convert this to a PC93, coming from mycall with origin set and process it as such
 125         $main::me->normal(pc93($to, $from, $via, $pc->[3], $pc->[6]));
 126 }
 127
 128 # DX Spot handling
 129 sub handle_11
 130 {
 131         my $self = shift;
 132         my $pcno = shift;
 133         my $line = shift;
 134         my $origin = shift;
 135         my $pc = shift;
 136
 137         # route 'foreign' pc26s
 138         if ($pcno == 26) {
 139                 if ($pc->[7] ne $main::mycall) {
 140                         $self->route($pc->[7], $line);
 141                         return;
 142                 }
 143         }
 144
 145 #       my ($hops) = $pc->[8] =~ /^H(\d+)/;
 146
 147         # is the spotted callsign blank? This should really be trapped earlier but it
 148         # could break other protocol sentences. Also check for lower case characters.
 149         if ($pc->[2] =~ /^\s*$/) {
 150                 dbg("PCPROT: blank callsign, dropped") if isdbg('chanerr');
 151                 return;
 152         }
 153         if ($pc->[2] =~ /[a-z]/) {
 154                 dbg("PCPROT: lowercase characters, dropped") if isdbg('chanerr');
 155                 return;
 156         }
 157
 158
 159         # if this is a 'nodx' node then ignore it
 160         if ($badnode->in($pc->[7])) {
 161                 dbg("PCPROT: Bad Node $pc->[7], dropped") if isdbg('chanerr');
 162                 return;
 163         }
 164
 165         # if this is a 'bad spotter' or an unknown user then ignore it. BUT if it's got an IP address then allow it through
 166         my $nossid = $pc->[6];
 167         $nossid =~ s/-\d+$//;
 168         if ($badspotter->in($nossid)) {
 169                 dbg("PCPROT: Bad Spotter $pc->[6], dropped") if isdbg('chanerr');
 170                 return;
 171         }
 172 #       unless (is_ipaddr($pc->[8]) || DXUser::get_current($pc->[6])) {
 173 #               dbg("PCPROT: Unknown Spotter $pc->[6], dropped") if isdbg('chanerr');
 174 #               return;
 175 #       }
 176
 177         # convert the date to a unix date
 178         my $d = cltounix($pc->[3], $pc->[4]);
 179         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 180         if (!$d || (($pcno == 11 || $pcno == 61) && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 181                 dbg("PCPROT: Spot ignored, invalid date or out of range ($pc->[3] $pc->[4])\n") if isdbg('chanerr');
 182                 return;
 183         }
 184
 185         # is it 'baddx'
 186         if ($baddx->in($pc->[2]) || BadWords::check($pc->[2])) {
 187                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 188                 return;
 189         }
 190
 191         # do some de-duping
 192         $pc->[5] =~ s/^\s+//;                   # take any leading blanks off
 193         $pc->[2] = unpad($pc->[2]);             # take off leading and trailing blanks from spotted callsign
 194         if ($pc->[2] =~ /BUST\w*$/) {
 195                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 196                 return;
 197         }
 198         if ($censorpc) {
 199                 my @bad;
 200                 if (@bad = BadWords::check($pc->[5])) {
 201                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 202                         return;
 203                 }
 204         }
 205
 206         my @spot = Spot::prepare($pc->[1], $pc->[2], $d, $pc->[5], $nossid, $pc->[7], $pc->[8]);
 207         # global spot filtering on INPUT
 208         if ($self->{inspotsfilter}) {
 209                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 210                 unless ($filter) {
 211                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 212                         return;
 213                 }
 214         }
 215
 216         # this goes after the input filtering, but before the add
 217         # so that if it is input filtered, it isn't added to the dup
 218         # list. This allows it to come in from a "legitimate" source
 219         if (Spot::dup(@spot[0..4,5])) {
 220                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 221                 return;
 222         }
 223
 224         # add it
 225         Spot::add(@spot);
 226
 227         my $ip = '';
 228         $ip ||= $spot[14] if exists $spot[14];
 229         if (isdbg('progress')) {
 230                 my $sip = $ip ? sprintf "($ip)" : '' unless $ip =~ m|[\(\)\*]|;
 231                 $sip ||= '';
 232                 my $d = ztime($spot[2]);
 233                 my $s = "SPOT: $spot[1] on $spot[0] \@ $d by $spot[4]$sip\@$spot[7]";
 234                 $s .= $spot[3] ? " '$spot[3]'" : q{ ''};
 235                 $s .=  " route: $origin";
 236                 dbg($s);
 237         }
 238
 239         #
 240         # @spot at this point contains:-
 241         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 242         # then  spotted itu, spotted cq, spotters itu, spotters cq
 243         # you should be able to route on any of these
 244         #
 245
 246         # fix up qra locators of known users
 247         my $user = DXUser::get_current($spot[4]);
 248         if ($user) {
 249                 my $qra = $user->qra;
 250                 unless ($qra && is_qra($qra)) {
 251                         my $lat = $user->lat;
 252                         my $long = $user->long;
 253                         if (defined $lat && defined $long) {
 254                                 $user->qra(DXBearing::lltoqra($lat, $long));
 255                                 $user->put unless $self->{_nospawn};
 256                         }
 257                 }
 258
 259                 # send a remote command to a distant cluster if it is visible and there is no
 260                 # qra locator and we havn't done it for a month.
 261
 262                 unless ($user->qra) {
 263                         my $node;
 264                         my $to = $user->homenode;
 265                         my $last = $user->lastoper || 0;
 266                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 267                                 my $cmd = "forward/opernam $spot[4]";
 268                                 # send the rcmd but we aren't interested in the replies...
 269                                 my $dxchan = $node->dxchan;
 270                                 if ($dxchan && $dxchan->is_clx) {
 271                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 272                                 } else {
 273                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 274                                 }
 275                                 if ($to ne $pc->[7]) {
 276                                         $to = $pc->[7];
 277                                         $node = Route::Node::get($to);
 278                                         if ($node) {
 279                                                 $dxchan = $node->dxchan;
 280                                                 if ($dxchan && $dxchan->is_clx) {
 281                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 282                                                 } else {
 283                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 284                                                 }
 285                                         }
 286                                 }
 287                                 $user->lastoper($main::systime);
 288                                 $user->put unless $self->{_nospawn};
 289                         }
 290                 }
 291         }
 292
 293         # local processing
 294         if (defined &Local::spot) {
 295                 my $r;
 296                 eval {
 297                         $r = Local::spot($self, @spot);
 298                 };
 299                 return if $r;
 300         }
 301
 302         # DON'T be silly and send on PC26s!
 303         return if $pcno == 26;
 304
 305         # send out the filtered spots
 306         send_dx_spot($self, $line, @spot) if @spot;
 307 }
 308
 309 # announces
 310 sub handle_12
 311 {
 312         my $self = shift;
 313         my $pcno = shift;
 314         my $line = shift;
 315         my $origin = shift;
 316         my $pc = shift;
 317
 318         # announce duplicate checking
 319         $pc->[3] =~ s/^\s+//;                   # remove leading blanks
 320
 321         if ($censorpc) {
 322                 my @bad;
 323                 if (@bad = BadWords::check($pc->[3])) {
 324                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 325                         return;
 326                 }
 327         }
 328
 329         # if this is a 'nodx' node then ignore it
 330         if ($badnode->in($pc->[5])) {
 331                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 332                 return;
 333         }
 334
 335         # if this is a 'bad spotter' user then ignore it
 336         my $nossid = $pc->[1];
 337         $nossid =~ s/-\d+$//;
 338         if ($badspotter->in($nossid)) {
 339                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 340                 return;
 341         }
 342
 343         # ignore PC12s from origins that use PCxx protocol
 344         my $oref = Route::get($origin);
 345         if ($oref->do_pc9x) {
 346                 dbg("PCPROT: PC12 rxed from PC9x node, ignored") if isdbg('chanerr');
 347                 return;
 348         }
 349
 350         my $dxchan;
 351
 352         if ((($dxchan = DXChannel::get($pc->[2])) && $dxchan->is_user) || $pc->[4] =~ /^[\#\w.]+$/){
 353                 $self->send_chat(0, $line, @$pc[1..6]);
 354         } elsif ($pc->[2] eq '*' || $pc->[2] eq $main::mycall) {
 355
 356                 # ignore something that looks like a chat line coming in with sysop
 357                 # flag - this is a kludge...
 358                 if ($pc->[3] =~ /^\#\d+ / && $pc->[4] eq '*') {
 359                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 360                         return;
 361                 }
 362
 363                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 364                 # or one saying 'to <call>' to a talk if we can route to the recipient
 365                 if ($ann_to_talk) {
 366                         my $call = AnnTalk::is_talk_candidate($pc->[1], $pc->[3]);
 367                         if ($call) {
 368                                 my $ref = Route::get($call);
 369                                 if ($ref) {
 370                                         $dxchan = $ref->dxchan;
 371                                         $dxchan->talk($pc->[1], $call, undef, $pc->[3], $pc->[5]) if $dxchan != $self;
 372                                         return;
 373                                 }
 374                         }
 375                 }
 376
 377                 # send it
 378                 $self->send_announce(0, $line, @$pc[1..6]);
 379         } else {
 380                 $self->route($pc->[2], $line);
 381         }
 382
 383         # local processing
 384         if (defined &Local::ann) {
 385                 my $r;
 386                 eval {
 387                         $r = Local::ann($self, $line, @$pc[1..6]);
 388                 };
 389                 return if $r;
 390         }
 391 }
 392
 393 sub handle_15
 394 {
 395         my $self = shift;
 396         my $pcno = shift;
 397         my $line = shift;
 398         my $origin = shift;
 399         my $pc = shift;
 400
 401         if (eph_dup($line, $eph_pc15_restime)) {
 402                 return;
 403         } else {
 404                 unless ($self->{isolate}) {
 405                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 406                 }
 407         }
 408 }
 409
 410 # incoming user
 411 sub handle_16
 412 {
 413         my $self = shift;
 414         my $pcno = shift;
 415         my $line = shift;
 416         my $origin = shift;
 417         my $pc = shift;
 418
 419         # general checks
 420         my $dxchan;
 421         my $ncall = $pc->[1];
 422         my $newline = "PC16^";
 423
 424         # dos I want users from this channel?
 425         unless ($self->user->wantpc16) {
 426                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 427                 return;
 428         }
 429
 430         # is it me?
 431         if ($ncall eq $main::mycall) {
 432                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 433                 return;
 434         }
 435
 436         my $h;
 437         $h = 1 if DXChannel::get($ncall);
 438         if ($h && $self->{call} ne $ncall) {
 439                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 440                 return;
 441         }
 442
 443         if (eph_dup($line)) {
 444                 return;
 445         }
 446
 447         # isolate now means only accept stuff from this call only
 448         if ($self->{isolate} && $ncall ne $self->{call}) {
 449                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 450                 return;
 451         }
 452
 453         my $parent = Route::Node::get($ncall);
 454
 455         if ($parent) {
 456                 $dxchan = $parent->dxchan;
 457                 if ($dxchan && $dxchan ne $self) {
 458                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 459                         return;
 460                 }
 461
 462                 # input filter if required
 463                 return unless $self->in_filter_route($parent);
 464         } else {
 465                 $parent = Route::Node->new($ncall);
 466         }
 467
 468         unless ($h) {
 469                 if ($parent->via_pc92) {
 470                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 471                         return;
 472                 }
 473         }
 474
 475         my $i;
 476         my @rout;
 477         for ($i = 2; $i < $#$pc; $i++) {
 478                 my ($call, $conf, $here) = $pc->[$i] =~ /^(\S+) (\S) (\d)/o;
 479                 next unless $call && $conf && defined $here && is_callsign($call);
 480                 next if $call eq $main::mycall;
 481
 482                 eph_del_regex("^PC17\\^$call\\^$ncall");
 483
 484                 $conf = $conf eq '*';
 485
 486                 # reject this if we think it is a node already
 487                 my $r = Route::Node::get($call);
 488                 my $u = DXUser::get_current($call) unless $r;
 489                 if ($r || ($u && $u->is_node)) {
 490                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 491                         next;
 492                 }
 493
 494                 $r = Route::User::get($call);
 495                 my $flags = Route::here($here)|Route::conf($conf);
 496
 497                 if ($r) {
 498                         my $au = $r->addparent($parent);
 499                         if ($r->flags != $flags) {
 500                                 $r->flags($flags);
 501                                 $au = $r;
 502                         }
 503                         push @rout, $r if $h && $au;
 504                 } else {
 505                         my @ans = $parent->add_user($call, $flags);
 506                         push @rout, @ans if $h && @ans;
 507                 }
 508
 509                 # add this station to the user database, if required
 510                 my $user = DXUser::get_current($ncall);
 511                 $user = DXUser->new($call) unless $user;
 512                 $user->homenode($parent->call) if !$user->homenode;
 513                 $user->node($parent->call);
 514                 $user->lastin($main::systime) unless DXChannel::get($call);
 515                 $user->put unless $self->{_nospawn};
 516
 517                 # send info to all logged in thingies
 518                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 519                 $self->tell_buddies('loginb', $call, $ncall);
 520         }
 521         if (@rout) {
 522                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 523 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 524         }
 525 }
 526
 527 # remove a user
 528 sub handle_17
 529 {
 530         my $self = shift;
 531         my $pcno = shift;
 532         my $line = shift;
 533         my $origin = shift;
 534         my $pc = shift;
 535
 536         my $dxchan;
 537         my $ncall = $pc->[2];
 538         my $ucall = $pc->[1];
 539
 540         eph_del_regex("^PC16\\^$ncall.*$ucall");
 541
 542         # do I want users from this channel?
 543         unless ($self->user->wantpc16) {
 544                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 545                 return;
 546         }
 547
 548         if ($ncall eq $main::mycall) {
 549                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 550                 return;
 551         }
 552
 553         # isolate now means only accept stuff from this call only
 554         if ($self->{isolate} && $ncall ne $self->{call}) {
 555                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 556                 return;
 557         }
 558
 559         my $uref = Route::User::get($ucall);
 560         unless ($uref) {
 561                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 562                 return;
 563         }
 564         my $parent = Route::Node::get($ncall);
 565         unless ($parent) {
 566                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 567                 return;
 568         }
 569
 570         $dxchan = DXChannel::get($ncall);
 571         if ($dxchan && $dxchan ne $self) {
 572                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 573                 return;
 574         }
 575
 576         unless ($dxchan) {
 577                 if ($parent->via_pc92) {
 578                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 579                         return;
 580                 }
 581         }
 582
 583         if (DXChannel::get($ucall)) {
 584                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 585                 return;
 586         }
 587
 588         # input filter if required and then remove user if present
 589 #               return unless $self->in_filter_route($parent);
 590         $parent->del_user($uref);
 591
 592         # send info to all logged in thingies
 593         my $user = DXUser::get_current($ncall);
 594         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 595         $self->tell_buddies('logoutb', $ucall, $ncall);
 596
 597         if (eph_dup($line)) {
 598                 return;
 599         }
 600
 601         $self->route_pc17($origin, $line, $parent, $uref);
 602 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 603 }
 604
 605 # link request
 606 sub handle_18
 607 {
 608         my $self = shift;
 609         my $pcno = shift;
 610         my $line = shift;
 611         my $origin = shift;
 612         my $pc = shift;
 613
 614         $self->state('init');
 615
 616         my $parent = Route::Node::get($self->{call});
 617
 618         # record the type and version offered
 619         if (my ($version) = $pc->[1] =~ /DXSpider Version: (\d+\.\d+)/) {
 620                 $self->{version} = 53 + $version;
 621                 $self->user->version(53 + $version);
 622                 $parent->version(0 + $version);
 623                 my ($build) = $pc->[1] =~ /Build: (\d+(?:\.\d+)?)/;
 624                 $self->{build} = 0 + $build;
 625                 $self->user->build(0 + $build);
 626                 $parent->build(0 + $build);
 627                 dbg("$self->{call} = DXSpider version $version build $build");
 628                 unless ($self->is_spider) {
 629                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 630                         $self->user->sort('S');
 631                         $self->user->put unless $self->{_nospawn};
 632                         $self->sort('S');
 633                 }
 634 #               $self->{handle_xml}++ if DXXml::available() && $pc->[1] =~ /\bxml/;
 635         } else {
 636                 dbg("$self->{call} = Unknown software ($pc->[1] $pc->[2])");
 637                 $self->version(50.0);
 638                 $self->version($pc->[2] / 100) if $pc->[2] && $pc->[2] =~ /^\d+$/;
 639                 $self->user->version($self->version);
 640         }
 641
 642         if ($pc->[1] =~ /\bpc9x/) {
 643                 if ($self->{isolate}) {
 644                         dbg("$self->{call} pc9x recognised, but node is isolated, using old protocol");
 645                 } elsif (!$self->user->wantpc9x) {
 646                         dbg("$self->{call} pc9x explicitly switched off, using old protocol");
 647                 } else {
 648                         $self->{do_pc9x} = 1;
 649                         dbg("$self->{call} Set do PC9x");
 650                 }
 651         }
 652
 653         # first clear out any nodes on this dxchannel
 654         my @rout = $parent->del_nodes;
 655         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 656         $self->send_local_config();
 657         $self->send(pc20());
 658 }
 659
 660 sub check_add_node
 661 {
 662         my $call = shift;
 663
 664         # add this station to the user database, if required (don't remove SSID from nodes)
 665         my $chan = DXChannel::get($call);
 666         my $user;
 667         $user = $chan->user if $chan;
 668         $user ||= DXUser::get($call);
 669         unless ($user) {
 670                 $user = DXUser->new($call);
 671                 $user->priv(1);         # I have relented and defaulted nodes
 672                 $user->lockout(1);
 673                 $user->homenode($call);
 674                 $user->node($call);
 675                 $user->sort('A');
 676                 $user->lastin($main::systime); # this make it last longer than just this invocation
 677                 $user->put unless $chan && $chan->{_nospawn};                           # just to make sure it gets written away!!!
 678         }
 679         return $user;
 680 }
 681
 682 # incoming cluster list
 683 sub handle_19
 684 {
 685         my $self = shift;
 686         my $pcno = shift;
 687         my $line = shift;
 688         my $origin = shift;
 689         my $pc = shift;
 690
 691         my $i;
 692         my $newline = "PC19^";
 693
 694         # new routing list
 695         my (@rout, @pc92out);
 696
 697         # first get the INTERFACE node
 698         my $parent = Route::Node::get($self->{call});
 699         unless ($parent) {
 700                 dbg("PCPROT: my parent $self->{call} has disappeared");
 701                 $self->disconnect;
 702                 return;
 703         }
 704
 705         my $h;
 706
 707         # parse the PC19
 708         #
 709         # We are making a major change from now on. We are only going to accept
 710         # PC19s from directly connected nodes.  This means that we are probably
 711         # going to throw away most of the data that we are being sent.
 712         #
 713         # The justification for this is that most of it is wrong or out of date
 714         # anyway.
 715         #
 716         # From now on we are only going to believe PC92 data and locally connected
 717         # non-pc92 nodes.
 718         #
 719         for ($i = 1; $i < $#$pc-1; $i += 4) {
 720                 my $here = $pc->[$i];
 721                 my $call = uc $pc->[$i+1];
 722                 my $conf = $pc->[$i+2];
 723                 my $ver = $pc->[$i+3];
 724                 next unless defined $here && defined $conf && is_callsign($call);
 725
 726                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
 727
 728                 # check for sane parameters
 729                 #                               $ver = 5000 if $ver eq '0000';
 730                 next unless $ver && $ver =~ /^\d+$/;
 731                 next if $ver < 5000;    # only works with version 5 software
 732                 next if length $call < 3; # min 3 letter callsigns
 733                 next if $call eq $main::mycall || $call eq $main::myalias;
 734
 735                 # check that this PC19 isn't trying to alter the wrong dxchan
 736                 $h = 0;
 737                 my $dxchan = DXChannel::get($call);
 738                 if ($dxchan) {
 739                         if ($dxchan == $self) {
 740                                 $h = 1;
 741                         } else {
 742                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 743                                 next;
 744                         }
 745                 }
 746
 747                 # isolate now means only accept stuff from this call only
 748                 if ($self->{isolate} && $call ne $self->{call}) {
 749                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
 750                         next;
 751                 }
 752
 753                 my $user = check_add_node($call);
 754
 755 #               if (eph_dup($genline)) {
 756 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
 757 #                       next;
 758 #               }
 759
 760
 761                 unless ($h) {
 762                         if ($parent->via_pc92) {
 763                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 764                                 next;
 765                         }
 766                 }
 767
 768                 my $r = Route::Node::get($call);
 769                 my $flags = Route::here($here)|Route::conf($conf);
 770
 771                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
 772                 if ($r) {
 773                         my $ar;
 774                         if ($call ne $parent->call) {
 775                                 if ($self->in_filter_route($r)) {
 776                                         $ar = $parent->add($call, $ver, $flags);
 777 #                                       push @rout, $ar if $ar;
 778                                 } else {
 779                                         next;
 780                                 }
 781                         }
 782                         if ($r->version ne $ver || $r->flags != $flags) {
 783                                 $r->version($ver);
 784                                 $r->flags($flags);
 785                         }
 786                         push @rout, $r;
 787                 } else {
 788                         if ($call eq $self->{call} || $user->wantroutepc19) {
 789                                 my $new = Route->new($call); # throw away
 790                                 if ($self->in_filter_route($new)) {
 791                                         my $ar = $parent->add($call, $ver, $flags);
 792                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
 793                                         push @rout, $ar if $ar;
 794                                         push @pc92out, $r if $h;
 795                                 } else {
 796                                         next;
 797                                 }
 798                         }
 799                 }
 800
 801                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 802                 my $mref = DXMsg::get_busy($call);
 803                 $mref->stop_msg($call) if $mref;
 804
 805                 $user->lastin($main::systime) unless DXChannel::get($call);
 806                 $user->put unless $self->{_nospawn};
 807         }
 808
 809         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
 810         # but remember there will only be one (pair) these because any extras will be
 811         # thrown away.
 812         if (@rout) {
 813 #               $self->route_pc21($self->{call}, $line, @rout);
 814                 $self->route_pc19($self->{call}, $line, @rout);
 815         }
 816         if (@pc92out && !$pc92_slug_changes) {
 817                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
 818         }
 819 }
 820
 821 # send local configuration
 822 sub handle_20
 823 {
 824         my $self = shift;
 825         my $pcno = shift;
 826         my $line = shift;
 827         my $origin = shift;
 828         my $pc = shift;
 829
 830         if ($self->{do_pc9x} && $self->{state} ne 'init92') {
 831                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 832                 $self->{do_pc9x} = 0;
 833         }
 834         $self->send_local_config;
 835         $self->send(pc22());
 836         $self->state('normal');
 837         $self->{lastping} = 0;
 838         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 839 }
 840
 841 # delete a cluster from the list
 842 #
 843 # This should never occur for directly connected nodes.
 844 #
 845 sub handle_21
 846 {
 847         my $self = shift;
 848         my $pcno = shift;
 849         my $line = shift;
 850         my $origin = shift;
 851         my $pc = shift;
 852
 853         my $call = uc $pc->[1];
 854
 855         eph_del_regex("^PC1[679].*$call");
 856
 857         # if I get a PC21 from the same callsign as self then ignore it
 858         if ($call eq $self->{call}) {
 859                 dbg("PCPROT: self referencing PC21 from $self->{call}");
 860                 return;
 861         }
 862
 863         # for the above reason and also because of the check for PC21s coming
 864         # in for self->call from outside being ignored further down
 865         # we don't need any isolation code here, because we will never
 866         # act on a PC21 with self->call in it.
 867
 868         my $parent = Route::Node::get($self->{call});
 869         unless ($parent) {
 870                 dbg("PCPROT: my parent $self->{call} has disappeared");
 871                 $self->disconnect;
 872                 return;
 873         }
 874
 875         my @rout;
 876
 877         if ($call ne $main::mycall && $call ne $main::myalias) { # don't allow malicious buggers to disconnect me!
 878                 my $node = Route::Node::get($call);
 879                 if ($node) {
 880
 881                         if ($node->via_pc92) {
 882                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
 883                                 return;
 884                         }
 885
 886                         my $dxchan = DXChannel::get($call);
 887                         if ($dxchan && $dxchan != $self) {
 888                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chan');
 889                                 return;
 890                         }
 891
 892                         # input filter it
 893                         return unless $self->in_filter_route($node);
 894
 895                         # routing objects, force a PC21 if it is local
 896                         push @rout, $node->del($parent);
 897                         push @rout, $call if $dxchan && @rout == 0;
 898                 }
 899         } else {
 900                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chan');
 901                 return;
 902         }
 903
 904         if (eph_dup($line)) {
 905                 return;
 906         }
 907
 908         if (@rout) {
 909                 $self->route_pc21($origin, $line, @rout);
 910 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
 911         }
 912 }
 913
 914
 915 sub handle_22
 916 {
 917         my $self = shift;
 918         my $pcno = shift;
 919         my $line = shift;
 920         my $origin = shift;
 921         my $pc = shift;
 922
 923         if ($self->{do_pc9x}) {
 924                 if ($self->{state} ne 'init92') {
 925                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 926                         $self->{do_pc9x} = 0;
 927                 }
 928         }
 929         $self->{lastping} = 0;
 930         $self->state('normal');
 931         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 932 }
 933
 934 # WWV info
 935 sub handle_23
 936 {
 937         my $self = shift;
 938         my $pcno = shift;
 939         my $line = shift;
 940         my $origin = shift;
 941         my $pc = shift;
 942
 943         # route foreign' pc27s
 944         if ($pcno == 27) {
 945                 if ($pc->[8] ne $main::mycall) {
 946                         $self->route($pc->[8], $line);
 947                         return;
 948                 }
 949         }
 950
 951
 952         # do some de-duping
 953         my $d = cltounix($pc->[1], sprintf("%02d18Z", $pc->[2]));
 954         my $sfi = unpad($pc->[3]);
 955         my $k = unpad($pc->[4]);
 956         my $i = unpad($pc->[5]);
 957         my ($r) = $pc->[6] =~ /R=(\d+)/;
 958         $r = 0 unless $r;
 959         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
 960                 dbg("PCPROT: WWV Date ($pc->[1] $pc->[2]) out of range") if isdbg('chanerr');
 961                 return;
 962         }
 963
 964         # global wwv filtering on INPUT
 965         my @dxcc = ((Prefix::cty_data($pc->[7]))[0..2], (Prefix::cty_data($pc->[8]))[0..2]);
 966         if ($self->{inwwvfilter}) {
 967                 my ($filter, $hops) = $self->{inwwvfilter}->it(@$pc[7,8], $origin, @dxcc);
 968                 unless ($filter) {
 969                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
 970                         return;
 971                 }
 972         }
 973         $pc->[7] =~ s/-\d+$//o;         # remove spotter's ssid
 974         if (Geomag::dup($d,$sfi,$k,$i,$pc->[6],$pc->[7])) {
 975                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 976                 return;
 977         }
 978
 979         # note this only takes the first one it gets
 980         Geomag::update($d, $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 981         dbg("WWV: <$pc->[2]>, sfi=$sfi k=$k info=$i '$pc->[6]' $pc->[7]\@$pc->[8] $r route: $origin") if isdbg('progress');
 982
 983         if (defined &Local::wwv) {
 984                 my $rep;
 985                 eval {
 986                         $rep = Local::wwv($self, $pc->[1], $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 987                 };
 988                 return if $rep;
 989         }
 990
 991         # DON'T be silly and send on PC27s!
 992         return if $pcno == 27;
 993
 994         # broadcast to the eager world
 995         send_wwv_spot($self, $line, $d, $pc->[2], $sfi, $k, $i, @$pc[6..8]);
 996 }
 997
 998 # set here status
 999 sub handle_24
1000 {
1001         my $self = shift;
1002         my $pcno = shift;
1003         my $line = shift;
1004         my $origin = shift;
1005         my $pc = shift;
1006
1007         my $call = uc $pc->[1];
1008         my ($nref, $uref);
1009         $nref = Route::Node::get($call);
1010         $uref = Route::User::get($call);
1011         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
1012
1013         if (eph_dup($line)) {
1014                 return;
1015         }
1016
1017         $nref->here($pc->[2]) if $nref;
1018         $uref->here($pc->[2]) if $uref;
1019         my $ref = $nref || $uref;
1020         return unless $self->in_filter_route($ref);
1021
1022         $self->route_pc24($origin, $line, $ref, $pc->[3]);
1023 }
1024
1025 # merge request
1026 sub handle_25
1027 {
1028         my $self = shift;
1029         my $pcno = shift;
1030         my $line = shift;
1031         my $origin = shift;
1032         my $pc = shift;
1033
1034         if ($pc->[1] ne $main::mycall) {
1035                 $self->route($pc->[1], $line);
1036                 return;
1037         }
1038         if ($pc->[2] eq $main::mycall) {
1039                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chan');
1040                 return;
1041         }
1042
1043         Log('DXProt', "Merge request for $pc->[3] spots and $pc->[4] WWV from $pc->[2]");
1044
1045         # spots
1046         if ($pc->[3] > 0) {
1047                 my @in = reverse Spot::search(1, undef, undef, 0, $pc->[3]);
1048                 my $in;
1049                 foreach $in (@in) {
1050                         $self->send(pc26(@{$in}[0..4], $pc->[2]));
1051                 }
1052         }
1053
1054         # wwv
1055         if ($pc->[4] > 0) {
1056                 my @in = reverse Geomag::search(0, $pc->[4], time, 1);
1057                 my $in;
1058                 foreach $in (@in) {
1059                         $self->send(pc27(@{$in}[0..5], $pc->[2]));
1060                 }
1061         }
1062 }
1063
1064 sub handle_26 {goto &handle_11}
1065 sub handle_27 {goto &handle_23}
1066
1067 # mail/file handling
1068 sub handle_28
1069 {
1070         my $self = shift;
1071         my $pcno = shift;
1072         my $line = shift;
1073         my $origin = shift;
1074         my $pc = shift;
1075
1076         if ($pc->[1] eq $main::mycall) {
1077                 no strict 'refs';
1078                 my $sub = "DXMsg::handle_$pcno";
1079                 &$sub($self, @$pc);
1080         } else {
1081                 $self->route($pc->[1], $line) unless $self->is_clx;
1082         }
1083 }
1084
1085 sub handle_29 {goto &handle_28}
1086 sub handle_30 {goto &handle_28}
1087 sub handle_31 {goto &handle_28}
1088 sub handle_32 {goto &handle_28}
1089 sub handle_33 {goto &handle_28}
1090
1091 sub handle_34
1092 {
1093         my $self = shift;
1094         my $pcno = shift;
1095         my $line = shift;
1096         my $origin = shift;
1097         my $pc = shift;
1098
1099         if (eph_dup($line, $eph_pc34_restime)) {
1100                 return;
1101         } else {
1102                 $self->process_rcmd($pc->[1], $pc->[2], $pc->[2], $pc->[3]);
1103         }
1104 }
1105
1106 # remote command replies
1107 sub handle_35
1108 {
1109         my $self = shift;
1110         my $pcno = shift;
1111         my $line = shift;
1112         my $origin = shift;
1113         my $pc = shift;
1114
1115         eph_del_regex("^PC35\\^$pc->[2]\\^$pc->[1]\\^");
1116         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[1], $pc->[3]);
1117 }
1118
1119 sub handle_36 {goto &handle_34}
1120
1121 # database stuff
1122 sub handle_37
1123 {
1124         my $self = shift;
1125         my $pcno = shift;
1126         my $line = shift;
1127         my $origin = shift;
1128         my $pc = shift;
1129
1130         if ($pc->[1] eq $main::mycall) {
1131                 no strict 'refs';
1132                 my $sub = "DXDb::handle_$pcno";
1133                 &$sub($self, @$pc);
1134         } else {
1135                 $self->route($pc->[1], $line) unless $self->is_clx;
1136         }
1137 }
1138
1139 # node connected list from neighbour
1140 sub handle_38
1141 {
1142         my $self = shift;
1143         my $pcno = shift;
1144         my $line = shift;
1145         my $origin = shift;
1146         my $pc = shift;
1147 }
1148
1149 # incoming disconnect
1150 sub handle_39
1151 {
1152         my $self = shift;
1153         my $pcno = shift;
1154         my $line = shift;
1155         my $origin = shift;
1156         my $pc = shift;
1157
1158         if ($pc->[1] eq $self->{call}) {
1159                 $self->disconnect(1);
1160         } else {
1161                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1162         }
1163 }
1164
1165 sub handle_40 {goto &handle_28}
1166
1167 # user info
1168 sub handle_41
1169 {
1170         my $self = shift;
1171         my $pcno = shift;
1172         my $line = shift;
1173         my $origin = shift;
1174         my $pc = shift;
1175
1176         my $call = $pc->[1];
1177         my $sort = $pc->[2];
1178         my $val = $pc->[3];
1179
1180         my $l = "PC41^$call^$sort";
1181         if (eph_dup($l, $eph_info_restime)) {
1182                 return;
1183         }
1184
1185         # input filter if required
1186         #                       my $ref = Route::get($call) || Route->new($call);
1187         #                       return unless $self->in_filter_route($ref);
1188
1189         if ($val eq $sort || $val =~ /^\s*$/) {
1190                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1191                 return;
1192         }
1193
1194         if ($call eq $main::mycall || $call eq $main::myalias) {
1195                 dbg "DXPROT: PC41 trying to update $call from outside via $origin, ignored";
1196                 return;
1197         }
1198         my $chan = DXChannel::get($call);
1199         if ($chan) {
1200                 dbg "DXPROT: PC41 trying to update online $call from outside via $origin, ignored";
1201                 return;
1202         }
1203
1204         # add this station to the user database, if required
1205         my $user = DXUser::get_current($call);
1206         $user = DXUser->new($call) unless $user;
1207
1208         if ($sort == 1) {
1209                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1210                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1211                         return;
1212                 }
1213                 $user->name($val);
1214         } elsif ($sort == 2) {
1215                 $user->qth($val);
1216         } elsif ($sort == 3) {
1217                 if (is_latlong($val)) {
1218                         my ($lat, $long) = DXBearing::stoll($val);
1219                         $user->lat($lat) if $lat;
1220                         $user->long($long) if $long;
1221                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1222                 } else {
1223                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1224                         return;
1225                 }
1226         } elsif ($sort == 4) {
1227                 $user->homenode($val);
1228         } elsif ($sort == 5) {
1229                 if (is_qra(uc $val)) {
1230                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1231                         $user->lat($lat) if $lat && !$user->lat;
1232                         $user->long($long) if $long && !$user->long;
1233                         $user->qra(uc $val);
1234                 } else {
1235                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1236                         return;
1237                 }
1238         }
1239         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1240         $user->put unless $self->{_nospawn};
1241
1242         unless ($self->{isolate}) {
1243                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1244         }
1245
1246         #  perhaps this IS what we want after all
1247         #                       $self->route_pc41($ref, $call, $sort, $val, $pc->[4]);
1248 }
1249
1250 sub handle_42 {goto &handle_28}
1251
1252
1253 # database
1254 sub handle_44 {goto &handle_37}
1255 sub handle_45 {goto &handle_37}
1256 sub handle_46 {goto &handle_37}
1257 sub handle_47 {goto &handle_37}
1258 sub handle_48 {goto &handle_37}
1259
1260 # message and database
1261 sub handle_49
1262 {
1263         my $self = shift;
1264         my $pcno = shift;
1265         my $line = shift;
1266         my $origin = shift;
1267         my $pc = shift;
1268
1269         if (eph_dup($line)) {
1270                 return;
1271         }
1272
1273         if ($pc->[1] eq $main::mycall) {
1274                 DXMsg::handle_49($self, @$pc);
1275         } else {
1276                 $self->route($pc->[1], $line) unless $self->is_clx;
1277         }
1278 }
1279
1280 # keep alive/user list
1281 sub handle_50
1282 {
1283         my $self = shift;
1284         my $pcno = shift;
1285         my $line = shift;
1286         my $origin = shift;
1287         my $pc = shift;
1288
1289         return if (eph_dup($line));
1290
1291         my $call = $pc->[1];
1292
1293         my $node = Route::Node::get($call);
1294         if ($node) {
1295                 return unless $node->call eq $self->{call};
1296                 $node->usercount($pc->[2]) unless $node->users;
1297                 $node->reset_obs;
1298                 $node->PC92C_dxchan($self->call, $pc->[-1]);
1299
1300                 # input filter if required
1301 #               return unless $self->in_filter_route($node);
1302
1303                 unless ($self->{isolate}) {
1304                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1305                 }
1306 #               $self->route_pc50($origin, $line, $node, $pc->[2], $pc->[3]) unless eph_dup($line);
1307         }
1308 }
1309
1310 # incoming ping requests/answers
1311 sub handle_51
1312 {
1313         my $self = shift;
1314         my $pcno = shift;
1315         my $line = shift;
1316         my $origin = shift;
1317         my $pc = shift;
1318
1319         my $to = $pc->[1];
1320         my $from = $pc->[2];
1321         my $flag = $pc->[3];
1322
1323         if ($to eq $main::myalias) {
1324                 dbg("DXPROT: Ping addressed to \$myalias ($main::myalias), ignored") if isdbg('chan');
1325                 return;
1326         }
1327
1328         # is it for us?
1329         if ($to eq $main::mycall) {
1330                 if ($flag == 1) {
1331                         $self->send(pc51($from, $to, '0'));
1332                 } else {
1333                         DXXml::Ping::handle_ping_reply($self, $from);
1334                 }
1335         } else {
1336                 if (eph_dup($line)) {
1337                         return;
1338                 }
1339                 # route down an appropriate thingy
1340                 $self->route($to, $line);
1341         }
1342 }
1343
1344 sub handle_61 { goto &handle_11; }
1345
1346 # dunno but route it
1347 sub handle_75
1348 {
1349         my $self = shift;
1350         my $pcno = shift;
1351         my $line = shift;
1352         my $origin = shift;
1353         my $pc = shift;
1354
1355         my $call = $pc->[1];
1356         if ($call ne $main::mycall) {
1357                 $self->route($call, $line);
1358         }
1359 }
1360
1361 # WCY broadcasts
1362 sub handle_73
1363 {
1364         my $self = shift;
1365         my $pcno = shift;
1366         my $line = shift;
1367         my $origin = shift;
1368         my $pc = shift;
1369
1370         my $call = $pc->[1];
1371
1372         # do some de-duping
1373         my $d = cltounix($call, sprintf("%02d18Z", $pc->[2]));
1374         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
1375                 dbg("PCPROT: WCY Date ($call $pc->[2]) out of range") if isdbg('chanerr');
1376                 return;
1377         }
1378         $pc = [ map { unpad($_) } @$pc ];
1379         if (WCY::dup($d)) {
1380                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1381                 return;
1382         }
1383
1384         my $wcy = WCY::update($d, @$pc[2..12]);
1385         dbg("WCY: <$pc->[2]> K=$pc->[5] expK=$pc->[6] A=$pc->[4] R=$pc->[7] SFI=$pc->[3] SA=$pc->[8] GMF=$pc->[9] Au=$pc->[10] $pc->[11]\@$pc->[12] route: $origin") if isdbg('progress');
1386
1387         if (defined &Local::wcy) {
1388                 my $rep;
1389                 eval {
1390                         $rep = Local::wcy($self, @$pc[1..12]);
1391                 };
1392                 return if $rep;
1393         }
1394
1395         # broadcast to the eager world
1396         send_wcy_spot($self, $line, $d, @$pc[2..12]);
1397 }
1398
1399 # remote commands (incoming)
1400 sub handle_84
1401 {
1402         my $self = shift;
1403         my $pcno = shift;
1404         my $line = shift;
1405         my $origin = shift;
1406         my $pc = shift;
1407
1408         $self->process_rcmd($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1409 }
1410
1411 # remote command replies
1412 sub handle_85
1413 {
1414         my $self = shift;
1415         my $pcno = shift;
1416         my $line = shift;
1417         my $origin = shift;
1418         my $pc = shift;
1419
1420         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1421 }
1422
1423 # decode a pc92 call: flag call : version : build
1424 sub _decode_pc92_call
1425 {
1426         my $icall = shift;
1427         my @part = split /:/, $icall;
1428         my ($flag, $call) = unpack "A A*", $part[0];
1429         unless (defined $flag && $flag ge '0' && $flag le '7') {
1430                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1431                 return ();
1432         }
1433         unless ($call && is_callsign($call)) {
1434                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1435                 return ();
1436         }
1437         my $is_node = $flag & 4;
1438         my $is_extnode = $flag & 2;
1439         my $here = $flag & 1;
1440         my $ip  = $part[3];
1441         $ip ||= $part[1] if $part[1] && ($part[1] =~ /^(?:\d+\.)+/ || $part[1] =~ /^(?:(?:[abcdef\d]+)?,)+/);
1442         $ip =~ s/,/:/g if $ip;
1443         return ($call, $is_node, $is_extnode, $here, $part[1], $part[2], $ip);
1444 }
1445
1446 # decode a pc92 call: flag call : version : build
1447 sub _encode_pc92_call
1448 {
1449         my $ref = shift;
1450
1451         # plain call or value
1452         return $ref unless ref $ref;
1453
1454         my $ext = shift || 0;
1455         my $flag = 0;
1456         my $call = $ref->call;
1457         my $extra = '';
1458         $flag |= $ref->here ? 1 : 0;
1459         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1460                 $flag |= 4;
1461                 my $dxchan = DXChannel::get($call);
1462                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1463                 if (($ext & 1) && $ref->version) {
1464                         my $version = $ref->version || 1.0;
1465                         $version =  $version * 100 + 5300 if $version < 50;
1466                         $extra .= ":" . $version;
1467                 }
1468         }
1469         if (($ext & 2) && $ref->ip) {
1470                 my $ip = $ref->ip;
1471                 $ip =~ s/:/,/g;
1472                 $extra .= ':' . $ip;
1473         }
1474         return "$flag$call$extra";
1475 }
1476
1477 my %things_add;
1478 my %things_del;
1479
1480 sub _add_thingy
1481 {
1482         my $parent = shift;
1483         my $s = shift;
1484         my $dxchan = shift;
1485         my $hops = shift;
1486
1487         my ($call, $is_node, $is_extnode, $here, $version, $build, $ip) = @$s;
1488         my @rout;
1489
1490         # remove spurious IPV6 prefix on IPV4 addresses
1491         $ip =~ s/^::ffff:// if $ip;
1492
1493         if ($call) {
1494                 my $ncall = $parent->call;
1495                 if ($is_node) {
1496                         dbg("ROUTE: added node $call to $ncall") if isdbg('routelow');
1497                         @rout = $parent->add($call, $version, Route::here($here), $ip);
1498                         my $r = Route::Node::get($call);
1499                         $r->PC92C_dxchan($dxchan->call, $hops) if $r;
1500                         if ($ip) {
1501                                 $r->ip($ip);
1502                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1503                         }
1504                 } else {
1505                         dbg("ROUTE: added user $call to $ncall") if isdbg('routelow');
1506                         @rout = $parent->add_user($call, Route::here($here), $ip);
1507                         $dxchan->tell_buddies('loginb', $call, $ncall) if $dxchan;
1508                         my $r = Route::User::get($call);
1509                         if ($ip) {
1510                                 $r->ip($ip);
1511                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1512                         }
1513                 }
1514                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1515                         $things_add{$call} = Route::get($call);
1516                         delete $things_del{$call};
1517                 }
1518         }
1519         return @rout;
1520 }
1521
1522 sub _del_thingy
1523 {
1524         my $parent = shift;
1525         my $s = shift;
1526         my $dxchan = shift;
1527         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1528         my @rout;
1529         if ($call) {
1530                 my $ref;
1531                 if ($is_node) {
1532                         $ref = Route::Node::get($call);
1533                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1534                         @rout = $ref->del($parent) if $ref;
1535                 } else {
1536                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1537                         $ref = Route::User::get($call);
1538                         if ($ref) {
1539                                 $dxchan->tell_buddies('logoutb', $call, $parent->call) if $dxchan;
1540                                 @rout = $parent->del_user($ref);
1541                         }
1542                 }
1543                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1544                         $things_del{$call} = $ref unless exists $things_add{$call};
1545                         delete $things_add{$call};
1546                 }
1547         }
1548         return @rout;
1549 }
1550
1551 # this will only happen if we are slugging changes and
1552 # there are some changes to be sent, it will create an add or a delete
1553 # or both
1554 sub gen_pc92_changes
1555 {
1556         my @add = values %things_add;
1557         my @del = values %things_del;
1558         return (\@add, \@del);
1559 }
1560
1561 sub clear_pc92_changes
1562 {
1563         %things_add = %things_del = ();
1564         $last_pc92_slug = $main::systime;
1565 }
1566
1567 my $_last_time;
1568 my $_last_occurs;
1569 my $_last_pc9x_id;
1570
1571 sub last_pc9x_id
1572 {
1573         return $_last_pc9x_id;
1574 }
1575
1576 sub gen_pc9x_t
1577 {
1578         if (!$_last_time || $_last_time != $main::systime) {
1579                 $_last_time = $main::systime;
1580                 $_last_occurs = 0;
1581                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1582         } else {
1583                 $_last_occurs++;
1584                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1585         }
1586 }
1587
1588 sub check_pc9x_t
1589 {
1590         my $call = shift;
1591         my $t = shift;
1592         my $pc = shift;
1593         my $create = shift;
1594
1595         # check that the time is between 0 >= $t < 86400
1596         unless ($t >= 0 && $t < 86400) {
1597                 dbg("PCPROT: time invalid t: $t, ignored") if isdbg('chanerr');
1598                 return undef;
1599         }
1600
1601         # check that the time of this pc9x is within tolerance (default 15 mins either way)
1602         my $now = $main::systime - $main::systime_daystart ;
1603         my $diff = abs($now - $t);
1604         unless ($diff < $pc9x_time_tolerance || 86400 - $diff < $pc9x_time_tolerance) {
1605                 my $c = ref $call ? $call->call : $call;
1606                 dbg("PC9XERR: $c time out of range t: $t now: $now diff: $diff > $pc9x_time_tolerance, ignored") if isdbg('chan');
1607                 return undef;
1608         }
1609
1610         my $parent = ref $call ? $call : Route::Node::get($call);
1611         if ($parent) {
1612                 # we only do this for external calls whose routing table
1613                 # record come and go. The reference for mycall is permanent
1614                 # and not that frequently used, it also never times out, so
1615                 # the id on it is completely unreliable. Besides, only commands
1616                 # originating on this box will go through this code...
1617                 if ($parent->call ne $main::mycall) {
1618                         my $lastid = $parent->lastid;
1619                         if (defined $lastid) {
1620                                 if ($t < $lastid) {
1621                                         # note that this is where we determine whether this pc9x has come in yesterday
1622                                         # but is still greater (modulo 86400) than the lastid or is simply an old
1623                                         # duplicate sentence. To determine this we need to do some module 86400
1624                                         # arithmetic. High numbers mean that this is an old duplicate sentence,
1625                                         # low numbers that it is a new sentence.
1626                                         #
1627                                         # Typically you will see yesterday being taken on $t = 84, $lastid = 86235
1628                                         # and old dupes with $t = 234, $lastid = 256 (which give answers 249 and
1629                                         # 86378 respectively in the calculation below).
1630                                         #
1631                                         if ($t+86400-$lastid > $pc9x_past_age) {
1632                                                 dbg("PCPROT: dup id on $t <= lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1633                                                 return undef;
1634                                         }
1635                                 } elsif ($t == $lastid) {
1636                                         dbg("PCPROT: dup id on $t == lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1637                                         return undef;
1638                                 } else {
1639                                         # check that if we have a low number in lastid that yesterday's numbers
1640                                         # (likely in the 85000+ area) don't override them, thus causing flip flopping
1641                                         if ($lastid+86400-$t < $pc9x_past_age) {
1642                                                 dbg("PCPROT: dup id on $t in yesterday, lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1643                                                 return undef;
1644                                         }
1645                                 }
1646                         }
1647                 }
1648         } elsif ($create) {
1649                 $parent = Route::Node->new($call);
1650         } else {
1651                 dbg("PCPROT: $call does not exist, ignored") if isdbg('pc92dedupe');
1652                 return undef;
1653         }
1654         if (isdbg('pc92dedupe')) {
1655                 my $exists = exists $parent->{lastid}; # naughty, naughty :-)
1656                 my $val = $parent->{lastid};
1657                 my $s = $exists ? (defined $val ? $val : 'exists/undef') : 'undef';
1658                 dbg("PCPROT: $call pc92 id lastid $s -> $t");
1659         }
1660         $parent->lastid($t);
1661
1662         return $parent;
1663 }
1664
1665 sub pc92_handle_first_slot
1666 {
1667         my $self = shift;
1668         my $slot = shift;
1669         my $parent = shift;
1670         my $t = shift;
1671         my $hops = shift;
1672         my $oparent = $parent;
1673
1674         my @radd;
1675
1676         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$slot;
1677         if ($call && $is_node) {
1678                 if ($call eq $main::mycall) {
1679                         dbg("PCPROT: $call looped back onto \$main::mycall ($main::mycall), ignored") if isdbg('chan');
1680                         return;
1681                 }
1682                 if ($call eq $main::myalias) {
1683                         dbg("PCPROT: $call looped back onto \$main::myalias ($main::myalias), ignored") if isdbg('chan');
1684                         return;
1685                 }
1686                 # this is only accepted from my "self".
1687                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
1688                 # locally connected. Local nodes always take precedence. But we remember the lastid
1689                 # to try to reduce the number of dupe PC92s for this external node.
1690                 if (DXChannel::get($call) && $call ne $self->{call}) {
1691                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
1692                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
1693                         return;
1694                 }
1695                 if ($is_extnode) {
1696                         # reparent to external node (note that we must have received a 'C' or 'A' record
1697                         # from the true parent node for this external before we get one for the this node
1698                         unless ($parent = Route::Node::get($call)) {
1699                                 if ($is_extnode && $oparent) {
1700                                         @radd = _add_thingy($oparent, $slot, $self, $hops);
1701                                         $parent = $radd[0];
1702                                 } else {
1703                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
1704                                         return;
1705                                 }
1706                         }
1707                         $parent = check_pc9x_t($call, $t, 92) || return;
1708                         $parent->via_pc92(1);
1709                         $parent->PC92C_dxchan($self->{call}, $hops);
1710                 }
1711         } else {
1712                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
1713                 return;
1714         }
1715         $parent->here(Route::here($here));
1716         $parent->version($version || $pc19_version) if $version;
1717         $parent->build($build) if $build;
1718         $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1719         return ($parent, @radd);
1720 }
1721
1722 # DXSpider routing entries
1723 sub handle_92
1724 {
1725         my $self = shift;
1726         my $pcno = shift;
1727         my $line = shift;
1728         my $origin = shift;
1729         my $pc = shift;
1730
1731         my (@radd, @rdel);
1732
1733         my $pcall = $pc->[1];
1734         my $t = $pc->[2];
1735         my $sort = $pc->[3];
1736         my $hops = $pc->[-1];
1737
1738         # this catches loops of A/Ds
1739 #       if (eph_dup($line, $pc9x_dupe_age)) {
1740 #               return;
1741 #       }
1742
1743         if ($pcall eq $main::mycall) {
1744                 dbg("PCPROT: looped back, ignored") if isdbg('chan');
1745                 return;
1746         }
1747
1748         if ($pcall eq $main::myalias) {
1749                 dbg("PCPROT: looped back to \$myalias ($main::myalias), misconfiguration ignored") if isdbg('chan');
1750                 return;
1751         }
1752
1753         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
1754                 if ($self->{isolate}) {
1755                         dbg("DXPROT: PC9x received, but $pcall is isolated, ignored");
1756                         return;
1757                 } elsif (!$self->user->wantpc9x) {
1758                         dbg("DXPROT: PC9x explicitly switched off on $pcall, ignored");
1759                         return;
1760                 } else {
1761                         $self->state('init92');
1762                         $self->{do_pc9x} = 1;
1763                         dbg("DXPROT: Do pc9x set on $pcall");
1764                 }
1765         }
1766         unless ($self->{do_pc9x}) {
1767                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1768                 return;
1769         }
1770
1771         # don't create routing entries for D records that don't already exist
1772         # this is what causes all those PC92 loops!
1773         my $parent = check_pc9x_t($pcall, $t, 92, $sort ne 'D') || return;
1774         my $oparent = $parent;
1775
1776         $parent->do_pc9x(1);
1777         $parent->via_pc92(1);
1778
1779         if ($sort eq 'F' || $sort eq 'R') {
1780
1781                 # this is the route finding section
1782                 # here is where the consequences of the 'find' command
1783                 # are dealt with
1784
1785                 my $from = $pc->[4];
1786                 my $target = $pc->[5];
1787
1788                 if ($sort eq 'F') {
1789                         my $flag;
1790                         my $ref;
1791                         my $dxchan;
1792                         if ($ref = DXChannel::get($target)) {
1793                                 $flag = 1;              # we are directly connected
1794                         } else {
1795                                 $ref = Route::get($target);
1796                                 $dxchan = $ref->dxchan;
1797                                 $flag = 2;
1798                         }
1799                         if ($ref && $flag && $dxchan) {
1800                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
1801                                 return;
1802                         }
1803                 } elsif ($sort eq 'R') {
1804                         if (my $dxchan = DXChannel::get($from)) {
1805                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @$pc[6,7]);
1806                         } else {
1807                                 my $ref = Route::get($from);
1808                                 if ($ref) {
1809                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
1810                                         if (@dxchan) {
1811                                                 $_->send($line) for @dxchan;
1812                                         } else {
1813                                                 dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1814                                         }
1815                                 } else {
1816                                         dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1817                                 }
1818                         }
1819                         return;
1820                 }
1821
1822         } elsif ($sort eq 'K') {
1823                 $pc92Kin += length $line;
1824
1825                 # remember the last channel we arrived on
1826                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1827
1828                 my @ent = _decode_pc92_call($pc->[4]);
1829
1830                 if (@ent) {
1831                         my $add;
1832
1833                         ($parent, $add) = $self->pc92_handle_first_slot(\@ent, $parent, $t, $hops);
1834                         return unless $parent; # dupe
1835
1836                         push @radd, $add if $add;
1837                         $parent->reset_obs;
1838                         $parent->version($ent[4]) if $ent[4];
1839                         $parent->build($ent[5]) if $ent[5];
1840
1841                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1842                 }
1843         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
1844
1845                 $pc92Ain += length $line if $sort eq 'A';
1846                 $pc92Cin += length $line if $sort eq 'C';
1847                 $pc92Din += length $line if $sort eq 'D';
1848
1849                 # remember the last channel we arrived on
1850                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1851
1852                 # this is the main route section
1853                 # here is where all the routes are created and destroyed
1854
1855                 # cope with missing duplicate node calls in the first slot
1856                 my $me = $pc->[4] || '';
1857                 $me ||= _encode_pc92_call($parent) unless $me ;
1858
1859                 my @ent = map {my @a = _decode_pc92_call($_); @a ? \@a : ()} grep {$_ && /^[0-7]/} $me, @$pc[5 .. $#$pc];
1860
1861                 if (@ent) {
1862
1863                         # look at the first one which will always be a node of some sort
1864                         # except in the case of 'A' or 'D' in which the $pcall is used
1865                         # otherwise use the node call and update any information
1866                         # that needs to be done.
1867                         my $add;
1868
1869                         ($parent, $add) = $self->pc92_handle_first_slot($ent[0], $parent, $t, $hops);
1870                         return unless $parent; # dupe
1871
1872                         shift @ent;
1873                         push @radd, $add if $add;
1874                 }
1875
1876                 # do a pass through removing any references to either mycall
1877                 my @nent;
1878                 for (@ent) {
1879                         my $dxc;
1880                         next unless $_ && @$_;
1881                         if ($_->[0] eq $main::mycall) {
1882                                 dbg("PCPROT: $_->[0] refers to me, ignored") if isdbg('chanerr');
1883                                 next;
1884                         }
1885                         push @nent, $_;
1886                 }
1887
1888                 if ($sort eq 'A') {
1889                         for (@nent) {
1890                                 push @radd, _add_thingy($parent, $_, $self, $hops);
1891                         }
1892                 } elsif ($sort eq 'D') {
1893                         for (@nent) {
1894                                 push @rdel, _del_thingy($parent, $_, $self);
1895                         }
1896                 } elsif ($sort eq 'C') {
1897                         my (@nodes, @users);
1898
1899                         # we reset obscounts on config records as well as K records
1900                         $parent->reset_obs;
1901                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1902
1903                         #
1904                         foreach my $r (@nent) {
1905                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
1906                                 if ($r->[0]) {
1907                                         if ($r->[1]) {
1908                                                 push @nodes, $r->[0];
1909                                         } else {
1910                                                 push @users, $r->[0];
1911                                         }
1912                                 } else {
1913                                         dbg("PCPROT: pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr');
1914                                 }
1915                         }
1916
1917                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
1918
1919                         # add users here
1920                         foreach my $r (@nent) {
1921                                 my $call = $r->[0];
1922                                 if ($call) {
1923                                         push @radd,_add_thingy($parent, $r, $self, $hops) if grep $call eq $_, (@$nnodes, @$nusers);
1924                                 }
1925                         }
1926                         # del users here
1927                         foreach my $r (@$dnodes) {
1928                                 push @rdel,_del_thingy($parent, [$r, 1], $self);
1929                         }
1930                         foreach my $r (@$dusers) {
1931                                 push @rdel,_del_thingy($parent, [$r, 0], $self);
1932                         }
1933
1934                         # remember this last PC92C for rebroadcast on demand
1935                         $parent->last_PC92C($line);
1936                 } else {
1937                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
1938                         return;
1939                 }
1940
1941                 foreach my $r (@rdel) {
1942                         next unless $r;
1943
1944                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
1945                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
1946                 }
1947                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
1948                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
1949                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
1950                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
1951                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
1952         }
1953
1954         # broadcast it if we get here
1955         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1956 }
1957
1958 # get all the routes for a thing, bearing in mind that the thing (e.g. a user)
1959 # might be on two or more nodes at the same time or that there may be more than
1960 # one equal distance neighbour to a node.
1961 #
1962 # What this means that if sh/route g1tlh shows that he is on (say) two nodes, then
1963 # a Route::findroutes is done on each of those two nodes, the best route(s) taken from
1964 # each and then combined to give a set of dxchans to send the PC9x record down
1965 #
1966 sub find_pc9x_routes
1967 {
1968         my $to = shift;
1969         my $ref = Route::get($to);
1970         my @parent;
1971         my %cand;
1972
1973         if ($ref->isa('Route::User')) {
1974                 my $dxchan = DXChannel::get($to);
1975                 push @parent, $to if $dxchan;
1976                 push @parent, $ref->parents;
1977         } else {
1978                 @parent = $to;
1979         }
1980         foreach my $p (@parent) {
1981                 my $lasthops;
1982                 my @routes = Route::findroutes($p);
1983                 foreach my $r (@routes) {
1984                         $lasthops = $r->[0] unless defined $lasthops;
1985                         if ($r->[0] == $lasthops) {
1986                                 $cand{$r->[1]->call} = $r->[1];
1987                         } else {
1988                                 last;
1989                         }
1990                 }
1991         }
1992         return values %cand;
1993 }
1994
1995 sub handle_93
1996 {
1997         my $self = shift;
1998         my $pcno = shift;
1999         my $line = shift;
2000         my $origin = shift;
2001         my $pc = shift;
2002
2003 #       $self->{do_pc9x} ||= 1;
2004
2005         my $pcall = $pc->[1];                   # this is now checked earlier
2006
2007         # remember that we are converting PC10->PC93 and self will be $main::me if it
2008         # comes from us
2009         unless ($self->{do_pc9x}) {
2010                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
2011                 return;
2012         }
2013
2014         my $t = $pc->[2];
2015         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
2016
2017         my $to = uc $pc->[3];
2018         my $from = uc $pc->[4];
2019         my $via = uc $pc->[5];
2020         my $text = $pc->[6];
2021         my $onode = uc $pc->[7];
2022         $onode = $pcall if @$pc <= 8;
2023
2024         # this is catch loops caused by bad software ...
2025         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
2026                 return;
2027         }
2028
2029         if (isdbg('progress')) {
2030                 my $vs = $via ne '*' ? " via $via" : '';
2031                 my $s = "ANNTALK: $from\@$onode$vs -> $to '$text' route: $origin";
2032                 dbg($s);
2033         }
2034
2035         # will we allow it at all?
2036         if ($censorpc) {
2037                 my @bad;
2038                 if (@bad = BadWords::check($text)) {
2039                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
2040                         return;
2041                 }
2042         }
2043
2044         # if this is a 'bad spotter' user then ignore it
2045         my $nossid = $from;
2046         $nossid =~ s/-\d+$//;
2047         if ($badspotter->in($nossid)) {
2048                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
2049                 return;
2050         }
2051
2052         # ignore PC93 coming in from outside this node with a target of local
2053         if ($to eq 'LOCAL' && $self != $main::me) {
2054                 dbg("PCPROT: incoming LOCAL chat not from local node, ignored") if isdbg('chanerr');
2055                 return;
2056         }
2057
2058         # if it is routeable then then treat it like a talk
2059         my $ref = Route::get($to);
2060         if ($ref) {
2061                 my $dxchan;
2062
2063                 # convert to PC10 or local talks where appropriate
2064                 # PC93 capable nodes of the same hop count all get a copy
2065                 # if there is a PC10 node then it will get a copy and that
2066                 # will be it. Hopefully such a node will not figure highly
2067                 # in the route list, unless it is local, 'cos it don't issue PC92s!
2068                 # note that both local and PC93s at the same time are possible if the
2069                 # user on more than one node.
2070                 my @routes = find_pc9x_routes($to);
2071                 my $lasthops;
2072                 foreach $dxchan (@routes) {
2073                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
2074                                 if ($dxchan->{do_pc9x}) {
2075                                         $dxchan->send($line);
2076                                 } else {
2077                                         $dxchan->talk($from, $to, $via, $text, $onode);
2078                                 }
2079                         } else {
2080                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
2081                         }
2082                 }
2083                 return;
2084
2085         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
2086                 # announces
2087                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
2088                 my $wx = $to eq 'WX' ? '1' : '0';
2089                 my $local = $via eq 'LOCAL' ? '*' : $via;
2090
2091                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
2092                 return if $via eq 'LOCAL';
2093         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
2094                 # chat messages really only locally connected users
2095                 $self->send_chat(1, $line, $from, '*', $text, $to, $pcall, '0');
2096         }
2097
2098         # broadcast this chat sentence everywhere unless it is targetted to 'LOCAL'
2099         $self->broadcast_route_pc9x($pcall, undef, $line, 0) unless $to eq 'LOCAL' || $via eq 'LOCAL';
2100 }
2101
2102 # if get here then rebroadcast the thing with its Hop count decremented (if
2103 # there is one). If it has a hop count and it decrements to zero then don't
2104 # rebroadcast it.
2105 #
2106 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
2107 #        REBROADCAST!!!!
2108 #
2109
2110 sub handle_default
2111 {
2112         my $self = shift;
2113         my $pcno = shift;
2114         my $line = shift;
2115         my $origin = shift;
2116         my $pc = shift;
2117
2118         unless (eph_dup($line)) {
2119                 if ($pcno >= 90) {
2120                         my $pcall = $pc->[1];
2121                         unless (is_callsign($pcall)) {
2122                                 dbg("PCPROT: invalid callsign string '$pc->[1]', ignored") if isdbg('chanerr');
2123                                 return;
2124                         }
2125                         my $t = $pc->[2];
2126                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
2127                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
2128                 } else {
2129                         unless ($self->{isolate}) {
2130                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
2131                         }
2132                 }
2133         }
2134 }
2135
2136 1;