perl/Route.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the abstracted routing for all protocols and
   4 # is probably what I SHOULD have done the first time.
   5 #
   6 # Heyho.
   7 #
   8 # This is just a container class which I expect to subclass
   9 #
  10 # Copyright (c) 2001 Dirk Koopman G1TLH
  11 #
  12 # $Id$
  13 #
  14
  15 package Route;
  16
  17 use DXDebug;
  18 use DXChannel;
  19 use Prefix;
  20
  21 use strict;
  22
  23
  24 use vars qw($VERSION $BRANCH);
  25
  26 main::mkver($VERSION = q$Revision$);
  27
  28 use vars qw(%list %valid $filterdef);
  29
  30 %valid = (
  31                   call => "0,Callsign",
  32                   flags => "0,Flags,phex",
  33                   dxcc => '0,Country Code',
  34                   itu => '0,ITU Zone',
  35                   cq => '0,CQ Zone',
  36                   state => '0,State',
  37                   city => '0,City',
  38                   aranea => '0, By Aranea,yesno',
  39                  );
  40
  41 $filterdef = bless ([
  42                           # tag, sort, field, priv, special parser
  43                           ['channel', 'c', 0],
  44                           ['channel_dxcc', 'nc', 1],
  45                           ['channel_itu', 'ni', 2],
  46                           ['channel_zone', 'nz', 3],
  47                           ['call', 'c', 4],
  48                           ['by', 'c', 4],
  49                           ['call_dxcc', 'nc', 5],
  50                           ['by_dxcc', 'nc', 5],
  51                           ['call_itu', 'ni', 6],
  52                           ['by_itu', 'ni', 6],
  53                           ['call_zone', 'nz', 7],
  54                           ['by_zone', 'nz', 7],
  55                           ['channel_state', 'ns', 8],
  56                           ['call_state', 'ns', 9],
  57                           ['by_state', 'ns', 9],
  58                          ], 'Filter::Cmd');
  59
  60
  61 sub new
  62 {
  63         my $pkg = shift;
  64         my $call = shift;
  65
  66         $pkg = ref $pkg if ref $pkg;
  67
  68         my $self = bless {call => $call}, $pkg;
  69         dbg("create $pkg with $call") if isdbg('routelow');
  70
  71         # add in all the dxcc, itu, zone info
  72         ($self->{dxcc}, $self->{itu}, $self->{cq}, $self->{state}, $self->{city}) =
  73                 Prefix::cty_data($call);
  74
  75         $self->{flags} = 1;
  76
  77         return $self;
  78 }
  79
  80 #
  81 # get a callsign from a passed reference or a string
  82 #
  83
  84 sub _getcall
  85 {
  86         my $self = shift;
  87         my $thingy = shift;
  88         $thingy = $self unless $thingy;
  89         $thingy = $thingy->call if ref $thingy;
  90         $thingy = uc $thingy if $thingy;
  91         return $thingy;
  92 }
  93
  94 #
  95 # add and delete a callsign to/from a list
  96 #
  97
  98 sub _addlist
  99 {
 100         my $self = shift;
 101         my $field = shift;
 102         my @out;
 103         foreach my $c (@_) {
 104                 confess "Need a ref here" unless ref($c);
 105
 106                 my $call = $c->{call};
 107                 unless (grep $_ eq $call, @{$self->{$field}}) {
 108                         push @{$self->{$field}}, $call;
 109                         dbg(ref($self) . " adding $call to " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 110                         push @out, $c;
 111                 }
 112         }
 113         return @out;
 114 }
 115
 116 sub _dellist
 117 {
 118         my $self = shift;
 119         my $field = shift;
 120         my @out;
 121         foreach my $c (@_) {
 122                 confess "Need a ref here" unless ref($c);
 123                 my $call = $c->{call};
 124                 if (grep $_ eq $call, @{$self->{$field}}) {
 125                         $self->{$field} = [ grep {$_ ne $call} @{$self->{$field}} ];
 126                         dbg(ref($self) . " deleting $call from " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 127                         push @out, $c;
 128                 }
 129         }
 130         return @out;
 131 }
 132
 133 sub is_empty
 134 {
 135         my $self = shift;
 136         return @{$self->{$_[0]}} == 0;
 137 }
 138
 139 #
 140 # flag field constructors/enquirers
 141 #
 142 # These can be called in various ways:-
 143 #
 144 # Route::here or $ref->here returns 1 or 0 depending on value of the here flag
 145 # Route::here(1) returns 1 (the bit value of the here flag)
 146 # $ref->here(1) or $ref->here(0) sets the here flag
 147 #
 148 # these are now redundant really as we are not interested in conferences
 149 # and here is back to being '1'.
 150
 151 sub here
 152 {
 153         my $self = shift;
 154         $self->{flags} = shift if @_;
 155         return $self->{flags};
 156 }
 157
 158 # conferencing in the ak1a sense is not supported
 159 sub conf
 160 {
 161         my $self = shift;
 162         return 0;
 163 }
 164
 165 sub parents
 166 {
 167         my $self = shift;
 168         return @{$self->{parent}};
 169 }
 170
 171 #
 172 # display routines
 173 #
 174
 175 sub user_call
 176 {
 177         my $self = shift;
 178         my $call = sprintf "%s", $self->{call};
 179         return $self->here ? "$call" : "($call)";
 180 }
 181
 182 sub config
 183 {
 184         my $self = shift;
 185         my $nodes_only = shift;
 186         my $level = shift;
 187         my $seen = shift;
 188         my @out;
 189         my $line;
 190         my $call = $self->user_call;
 191         my $printit = 1;
 192
 193         # allow ranges
 194         if (@_) {
 195                 $printit = grep $call =~ m|$_|, @_;
 196         }
 197
 198         if ($printit) {
 199                 $line = ' ' x ($level*2) . "$call";
 200                 $call = ' ' x length $call;
 201
 202                 # recursion detector
 203                 if ((DXChannel::get($self->{call}) && $level > 1) || grep $self->{call} eq $_, @$seen) {
 204                         $line .= ' ...';
 205 #                       push @out, $line;
 206                         return @out;
 207                 }
 208                 push @$seen, $self->{call};
 209
 210                 # print users
 211                 unless ($nodes_only) {
 212                         if (@{$self->{users}}) {
 213                                 $line .= '->';
 214                                 foreach my $ucall (sort @{$self->{users}}) {
 215                                         my $uref = Route::User::get($ucall);
 216                                         my $c;
 217                                         if ($uref) {
 218                                                 $c = $uref->user_call;
 219                                         } else {
 220                                                 $c = "$ucall?";
 221                                         }
 222                                         if ((length $line) + (length $c) + 1 < 79) {
 223                                                 $line .= $c . ' ';
 224                                         } else {
 225                                                 $line =~ s/\s+$//;
 226                                                 push @out, $line;
 227                                                 $line = ' ' x ($level*2) . "$call->$c ";
 228                                         }
 229                                 }
 230                         }
 231                 }
 232                 $line =~ s/->$//g;
 233                 $line =~ s/\s+$//;
 234                 push @out, $line if length $line;
 235         }
 236
 237         # deal with more nodes
 238         foreach my $ncall (sort @{$self->{nodes}}) {
 239                 my $nref = Route::Node::get($ncall);
 240
 241                 if ($nref) {
 242                         my $c = $nref->user_call;
 243 #                       dbg("recursing from $call -> $c") if isdbg('routec');
 244                         push @out, $nref->config($nodes_only, $level+1, $seen, @_);
 245                 } else {
 246                         push @out, ' ' x (($level+1)*2)  . "$ncall?" if @_ == 0 || (@_ && grep $ncall =~ m|$_|, @_);
 247                 }
 248         }
 249
 250         return @out;
 251 }
 252
 253 sub cluster
 254 {
 255         my $nodes = Route::Node::count();
 256         my $tot = Route::User::count();
 257         my $users = scalar DXCommandmode::get_all();
 258         my $maxusers = Route::User::max();
 259         my $uptime = main::uptime();
 260
 261         return " $nodes nodes, $users local / $tot total users  Max users $maxusers  Uptime $uptime";
 262 }
 263
 264 #
 265 # routing things
 266 #
 267
 268 sub get
 269 {
 270         my $call = shift;
 271         return Route::Node::get($call) || Route::User::get($call);
 272 }
 273
 274 # find all the possible dxchannels which this object might be on
 275 sub alldxchan
 276 {
 277         my $self = shift;
 278         my @dxchan;
 279 #       dbg("Trying node $self->{call}") if isdbg('routech');
 280
 281         my $dxchan = DXChannel::get($self->{call});
 282         push @dxchan, $dxchan if $dxchan;
 283
 284         # it isn't, build up a list of dxchannels and possible ping times
 285         # for all the candidates.
 286         unless (@dxchan) {
 287                 foreach my $p (@{$self->{parent}}) {
 288 #                       dbg("Trying parent $p") if isdbg('routech');
 289                         next if $p eq $main::mycall; # the root
 290                         my $dxchan = DXChannel::get($p);
 291                         if ($dxchan) {
 292                                 push @dxchan, $dxchan unless grep $dxchan == $_, @dxchan;
 293                         } else {
 294                                 next if grep $p eq $_, @_;
 295                                 my $ref = Route::Node::get($p);
 296 #                               dbg("Next node $p " . ($ref ? 'Found' : 'NOT Found') if isdbg('routech') );
 297                                 push @dxchan, $ref->alldxchan($self->{call}, @_) if $ref;
 298                         }
 299                 }
 300         }
 301 #       dbg('routech', "Got dxchan: " . join(',', (map{ $_->call } @dxchan)) );
 302         return @dxchan;
 303 }
 304
 305 sub dxchan
 306 {
 307         my $self = shift;
 308
 309         # ALWAYS return the locally connected channel if present;
 310         my $dxchan = DXChannel::get($self->call);
 311         return $dxchan if $dxchan;
 312
 313         my @dxchan = $self->alldxchan;
 314         return undef unless @dxchan;
 315
 316         # determine the minimum ping channel
 317         my $minping = 99999999;
 318         foreach my $dxc (@dxchan) {
 319                 my $p = $dxc->pingave;
 320                 if (defined $p  && $p < $minping) {
 321                         $minping = $p;
 322                         $dxchan = $dxc;
 323                 }
 324         }
 325         $dxchan = shift @dxchan unless $dxchan;
 326         return $dxchan;
 327 }
 328
 329
 330
 331 #
 332 # track destruction
 333 #
 334
 335 sub DESTROY
 336 {
 337         my $self = shift;
 338         my $pkg = ref $self;
 339
 340         dbg("$pkg $self->{call} destroyed") if isdbg('routelow');
 341 }
 342
 343 no strict;
 344 #
 345 # return a list of valid elements
 346 #
 347
 348 sub fields
 349 {
 350         my $pkg = shift;
 351         $pkg = ref $pkg if ref $pkg;
 352     my $val = "${pkg}::valid";
 353         my @out = keys %$val;
 354         push @out, keys %valid;
 355         return @out;
 356 }
 357
 358 #
 359 # return a prompt for a field
 360 #
 361
 362 sub field_prompt
 363 {
 364         my ($self, $ele) = @_;
 365         my $pkg = ref $self;
 366     my $val = "${pkg}::valid";
 367         return $val->{$ele} || $valid{$ele};
 368 }
 369
 370 #
 371 # generic AUTOLOAD for accessors
 372 #
 373 sub AUTOLOAD
 374 {
 375         no strict;
 376         my $name = $AUTOLOAD;
 377         return if $name =~ /::DESTROY$/;
 378         $name =~ s/^.*:://o;
 379
 380         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 381
 382         # this clever line of code creates a subroutine which takes over from autoload
 383         # from OO Perl - Conway
 384         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 385        goto &$AUTOLOAD;
 386
 387 }
 388
 389 1;