#
# DX database control routines
#
# This manages the on-line cluster user 'database'
#
# This should all be pretty trees and things, but for now I
# just can't be bothered. If it becomes an issue I shall
# address it.
#
# Copyright (c) 1998 - Dirk Koopman G1TLH
#
# $Id$
#

package DXCluster;

use DXDebug;
use DXUtil;

use strict;
use vars qw(%cluster %valid);

%cluster = ();					# this is where we store the dxcluster database

%valid = (
		  mynode => '0,Parent Node,DXCluster::showcall',
		  call => '0,Callsign',
		  confmode => '0,Conference Mode,yesno',
		  here => '0,Here?,yesno',
		  dxchan => '5,Channel ref,DXCluster::showcall',
		  pcversion => '5,Node Version',
		  list => '5,User List,DXCluster::dolist',
		  users => '0,No of Users',
		 );

sub alloc
{
	my ($pkg, $dxchan, $call, $confmode, $here) = @_;
	die "$call is already alloced" if $cluster{$call};
	my $self = {};
	$self->{call} = $call;
	$self->{confmode} = $confmode;
	$self->{here} = $here;
	$self->{dxchan} = $dxchan;

	$cluster{$call} = bless $self, $pkg;
	return $self;
}

# get an entry exactly as it is
sub get_exact
{
	my ($pkg, $call) = @_;

	# belt and braces
	$call = uc $call;
  
	# search for 'as is' only
	return $cluster{$call}; 
}

#
# search for a call in the cluster
# taking into account SSIDs
#
sub get
{
	my ($pkg, $call) = @_;

	# belt and braces
	$call = uc $call;
  
	# search for 'as is'
	my $ref = $cluster{$call}; 
	return $ref if $ref;

	# search for the unSSIDed one
	$call =~ s/-\d+$//o;
	$ref = $cluster{$call};
	return $ref if $ref;
  
	# search for the SSIDed one
	my $i;
	for ($i = 1; $i < 17; $i++) {
		$ref = $cluster{"$call-$i"};
		return $ref if $ref;
	}
	return undef;
}

# get all 
sub get_all
{
	return values(%cluster);
}

# return a prompt for a field
sub field_prompt
{ 
	my ($self, $ele) = @_;
	return $valid{$ele};
}
#
# return a list of valid elements 
# 

sub fields
{
	return keys(%valid);
}

# this expects a reference to a list in a node NOT a ref to a node 
sub dolist
{
	my $self = shift;
	my $out;
	my $ref;
  
	foreach my $call (keys %{$self}) {
		$ref = $$self{$call};
		my $s = $ref->{call};
		$s = "($s)" if !$ref->{here};
		$out .= "$s ";
	}
	chop $out;
	return $out;
}

# this expects a reference to a node 
sub showcall
{
	my $self = shift;
	return $self->{call};
}

# the answer required by show/cluster
sub cluster
{
	my $users = DXCommandmode::get_all();
	my $uptime = main::uptime();
	my $tot = $DXNode::users;
		
	return " $DXNode::nodes nodes, $users local / $tot total users  Max users $DXNode::maxusers  Uptime $uptime";
}

no strict;
sub AUTOLOAD
{
	my $self = shift;
	my $name = $AUTOLOAD;
  
	return if $name =~ /::DESTROY$/;
	$name =~ s/.*:://o;
  
	confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
	# this clever line of code creates a subroutine which takes over from autoload
	# from OO Perl - Conway
	*{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}} ;
	@_ ? $self->{$name} = shift : $self->{$name} ;
}

#
# USER special routines
#

package DXNodeuser;

@ISA = qw(DXCluster);

use DXDebug;

use strict;

sub new 
{
	my ($pkg, $dxchan, $node, $call, $confmode, $here) = @_;

	die "tried to add $call when it already exists" if DXCluster->get_exact($call);
  
	my $self = $pkg->alloc($dxchan, $call, $confmode, $here);
	$self->{mynode} = $node;
	$node->add_user($call, $self);
	dbg('cluster', "allocating user $call to $node->{call} in cluster\n");
	return $self;
}

sub del
{
	my $self = shift;
	my $call = $self->{call};
	my $node = $self->{mynode};

	$node->del_user($call);
	dbg('cluster', "deleting user $call from $node->{call} in cluster\n");
}

sub count
{
	return $DXNode::users;		# + 1 for ME (naf eh!)
}

no strict;

#
# NODE special routines
#

package DXNode;

@ISA = qw(DXCluster);

use DXDebug;

use strict;
use vars qw($nodes $users $maxusers);

$nodes = 0;
$users = 0;
$maxusers = 0;


sub new 
{
	my ($pkg, $dxchan, $call, $confmode, $here, $pcversion) = @_;
	my $self = $pkg->alloc($dxchan, $call, $confmode, $here);
	$self->{pcversion} = $pcversion;
	$self->{list} = { } ;
	$self->{mynode} = $self;	# for sh/station
	$self->{users} = 0;
	$nodes++;
	dbg('cluster', "allocating node $call to cluster\n");
	return $self;
}

# get all the nodes
sub get_all
{
	my $list;
	my @out;
	foreach $list (values(%DXCluster::cluster)) {
		push @out, $list if $list->{pcversion};
	}
	return @out;
}

sub del
{
	my $self = shift;
	my $call = $self->{call};
	my $ref;

	# delete all the listed calls
	foreach $ref (values %{$self->{list}}) {
		$ref->del();			# this also takes them out of this list
	}
	delete $DXCluster::cluster{$call}; # remove me from the cluster table
	dbg('cluster', "deleting node $call from cluster\n"); 
	$users -= $self->{users};    # it may be PC50 updated only therefore > 0
	$users = 0 if $users < 0;
	$nodes--;
	$nodes = 0 if $nodes < 0;
}

sub add_user
{
	my $self = shift;
	my $call = shift;
	my $ref = shift;
	
	$self->{list}->{$call} = $ref; # add this user to the list on this node
	$self->{users} = keys %{$self->{list}};
	$users++;
	$maxusers = $users+$nodes if $users+$nodes > $maxusers;
}

sub del_user
{
	my $self = shift;
	my $call = shift;

	delete $self->{list}->{$call};
	delete $DXCluster::cluster{$call}; # remove me from the cluster table
	$self->{users} = keys %{$self->{list}};
	$users--;
	$users = 0, warn "\$users gone neg, reset" if $users < 0;
	$maxusers = $users+$nodes if $users+$nodes > $maxusers;
}

sub update_users
{
	my $self = shift;
	my $count = shift;
	$count = 0 unless $count;
	
	$users -= $self->{users};
	$self->{users} = $count unless keys %{$self->{list}};
	$users += $self->{users};
	$maxusers = $users+$nodes if $users+$nodes > $maxusers;
}

sub count
{
	return $nodes;				# + 1 for ME!
}

sub dolist
{

}

sub DESTROY
{
	my $self = shift;
	undef $self->{list} if $self->{list};
}


1;
__END__
