perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '5,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '5,Connection Type',
  52                   'sort' => '5,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   wcy => '0,Want WCY,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   wcyfilter => '5,WCY Filter',
  77                   spotfilter => '5,Spot Filter',
  78                   inannfilter => '5,Input Ann Filter',
  79                   inwwvfilter => '5,Input WWV Filter',
  80                   inwcyfilter => '5,Input WCY Filter',
  81                   inspotfilter => '5,Input Spot Filter',
  82                   passwd => '9,Passwd List,parray',
  83                   pingint => '5,Ping Interval ',
  84                   nopings => '5,Ping Obs Count',
  85                   lastping => '5,Ping last sent,atime',
  86                   pingtime => '5,Ping totaltime,parray',
  87                   pingave => '0,Ping ave time',
  88                   logininfo => '9,Login info req,yesno',
  89                   talklist => '0,Talk List,parray',
  90                   cluster => '5,Cluster data',
  91                  );
  92
  93 # object destruction
  94 sub DESTROY
  95 {
  96         my $self = shift;
  97         undef $self->{user};
  98         undef $self->{conn};
  99         undef $self->{loc};
 100         undef $self->{pagedata};
 101         undef $self->{group};
 102         undef $self->{delayed};
 103         undef $self->{annfilter};
 104         undef $self->{wwvfilter};
 105         undef $self->{spotfilter};
 106         undef $self->{inannfilter};
 107         undef $self->{inwwvfilter};
 108         undef $self->{inspotfilter};
 109         undef $self->{passwd};
 110         undef $self->{node};
 111 }
 112
 113 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 114 sub alloc
 115 {
 116         my ($pkg, $call, $conn, $user) = @_;
 117         my $self = {};
 118
 119         die "trying to create a duplicate channel for $call" if $channels{$call};
 120         $self->{call} = $call;
 121         $self->{priv} = 0;
 122         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 123         if (defined $user) {
 124                 $self->{user} = $user;
 125                 $self->{lang} = $user->lang;
 126                 $user->new_group() if !$user->group;
 127                 $self->{group} = $user->group;
 128                 $self->{sort} = $user->sort;
 129         }
 130         $self->{startt} = $self->{t} = time;
 131         $self->{state} = 0;
 132         $self->{oldstate} = 0;
 133         $self->{lang} = $main::lang if !$self->{lang};
 134         $self->{func} = "";
 135
 136         bless $self, $pkg;
 137         return $channels{$call} = $self;
 138 }
 139
 140 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 141 sub get
 142 {
 143         my ($pkg, $call) = @_;
 144         return $channels{$call};
 145 }
 146
 147 # obtain all the channel objects
 148 sub get_all
 149 {
 150         my ($pkg) = @_;
 151         return values(%channels);
 152 }
 153
 154 #
 155 # gimme all the ak1a nodes
 156 #
 157 sub get_all_nodes
 158 {
 159         my $ref;
 160         my @out;
 161         foreach $ref (values %channels) {
 162                 push @out, $ref if $ref->is_node;
 163         }
 164         return @out;
 165 }
 166
 167 # return a list of all users
 168 sub get_all_users
 169 {
 170         my $ref;
 171         my @out;
 172         foreach $ref (values %channels) {
 173                 push @out, $ref if $ref->is_user;
 174         }
 175         return @out;
 176 }
 177
 178 # return a list of all user callsigns
 179 sub get_all_user_calls
 180 {
 181         my $ref;
 182         my @out;
 183         foreach $ref (values %channels) {
 184                 push @out, $ref->{call} if $ref->is_user;
 185         }
 186         return @out;
 187 }
 188
 189 # obtain a channel object by searching for its connection reference
 190 sub get_by_cnum
 191 {
 192         my ($pkg, $conn) = @_;
 193         my $self;
 194
 195         foreach $self (values(%channels)) {
 196                 return $self if ($self->{conn} == $conn);
 197         }
 198         return undef;
 199 }
 200
 201 # get rid of a channel object [$obj->del()]
 202 sub del
 203 {
 204         my $self = shift;
 205
 206         $self->{group} = undef;         # belt and braces
 207         delete $channels{$self->{call}};
 208 }
 209
 210 # is it a bbs
 211 sub is_bbs
 212 {
 213         my $self = shift;
 214         return $self->{'sort'} eq 'B';
 215 }
 216
 217 sub is_node
 218 {
 219         my $self = shift;
 220         return $self->{'sort'} =~ /[ACRSX]/;
 221 }
 222 # is it an ak1a node ?
 223 sub is_ak1a
 224 {
 225         my $self = shift;
 226         return $self->{'sort'} eq 'A';
 227 }
 228
 229 # is it a user?
 230 sub is_user
 231 {
 232         my $self = shift;
 233         return $self->{'sort'} eq 'U';
 234 }
 235
 236 # is it a clx node
 237 sub is_clx
 238 {
 239         my $self = shift;
 240         return $self->{'sort'} eq 'C';
 241 }
 242
 243 # is it a spider node
 244 sub is_spider
 245 {
 246         my $self = shift;
 247         return $self->{'sort'} eq 'S';
 248 }
 249
 250 # is it a DXNet node
 251 sub is_dxnet
 252 {
 253         my $self = shift;
 254         return $self->{'sort'} eq 'X';
 255 }
 256
 257 # is it a ar-cluster node
 258 sub is_arcluster
 259 {
 260         my $self = shift;
 261         return $self->{'sort'} eq 'R';
 262 }
 263
 264 # for perl 5.004's benefit
 265 sub sort
 266 {
 267         my $self = shift;
 268         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 269 }
 270
 271 # handle out going messages, immediately without waiting for the select to drop
 272 # this could, in theory, block
 273 sub send_now
 274 {
 275         my $self = shift;
 276         my $conn = $self->{conn};
 277         return unless $conn;
 278         my $sort = shift;
 279         my $call = $self->{call};
 280
 281         for (@_) {
 282 #               chomp;
 283         my @lines = split /\n/;
 284                 for (@lines) {
 285                         $conn->send_now("$sort$call|$_");
 286                         dbg('chan', "-> $sort $call $_");
 287                 }
 288         }
 289         $self->{t} = time;
 290 }
 291
 292 #
 293 # the normal output routine
 294 #
 295 sub send                                                # this is always later and always data
 296 {
 297         my $self = shift;
 298         my $conn = $self->{conn};
 299         return unless $conn;
 300         my $call = $self->{call};
 301
 302         for (@_) {
 303 #               chomp;
 304         my @lines = split /\n/;
 305                 for (@lines) {
 306                         $conn->send_later("D$call|$_");
 307                         dbg('chan', "-> D $call $_");
 308                 }
 309         }
 310         $self->{t} = time;
 311 }
 312
 313 # send a file (always later)
 314 sub send_file
 315 {
 316         my ($self, $fn) = @_;
 317         my $call = $self->{call};
 318         my $conn = $self->{conn};
 319         my @buf;
 320
 321         open(F, $fn) or die "can't open $fn for sending file ($!)";
 322         @buf = <F>;
 323         close(F);
 324         $self->send(@buf);
 325 }
 326
 327 # this will implement language independence (in time)
 328 sub msg
 329 {
 330         my $self = shift;
 331         return DXM::msg($self->{lang}, @_);
 332 }
 333
 334 # stick a broadcast on the delayed queue (but only up to 20 items)
 335 sub delay
 336 {
 337         my $self = shift;
 338         my $s = shift;
 339
 340         $self->{delayed} = [] unless $self->{delayed};
 341         push @{$self->{delayed}}, $s;
 342         if (@{$self->{delayed}} >= 20) {
 343                 shift @{$self->{delayed}};   # lose oldest one
 344         }
 345 }
 346
 347 # change the state of the channel - lots of scope for debugging here :-)
 348 sub state
 349 {
 350         my $self = shift;
 351         if (@_) {
 352                 $self->{oldstate} = $self->{state};
 353                 $self->{state} = shift;
 354                 $self->{func} = '' unless defined $self->{func};
 355                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 356
 357                 # if there is any queued up broadcasts then splurge them out here
 358                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 359                         $self->send (@{$self->{delayed}});
 360                         delete $self->{delayed};
 361                 }
 362         }
 363         return $self->{state};
 364 }
 365
 366 # disconnect this channel
 367 sub disconnect
 368 {
 369         my $self = shift;
 370         my $user = $self->{user};
 371         my $conn = $self->{conn};
 372         my $call = $self->{call};
 373
 374         $self->finish($conn);
 375         $user->close() if defined $user;
 376         $conn->disconnect() if $conn;
 377         $self->del();
 378 }
 379
 380 #
 381 # just close all the socket connections down without any fiddling about, cleaning, being
 382 # nice to other processes and otherwise telling them what is going on.
 383 #
 384 # This is for the benefit of forked processes to prepare for starting new programs, they
 385 # don't want or need all this baggage.
 386 #
 387
 388 sub closeall
 389 {
 390         my $ref;
 391         foreach $ref (values %channels) {
 392                 $ref->{conn}->disconnect() if $ref->{conn};
 393         }
 394 }
 395
 396 #
 397 # Tell all the users that we have come in or out (if they want to know)
 398 #
 399 sub tell_login
 400 {
 401         my ($self, $m) = @_;
 402
 403         # send info to all logged in thingies
 404         my @dxchan = get_all_users();
 405         my $dxchan;
 406         foreach $dxchan (@dxchan) {
 407                 next if $dxchan == $self;
 408                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 409         }
 410 }
 411
 412 # various access routines
 413
 414 #
 415 # return a list of valid elements
 416 #
 417
 418 sub fields
 419 {
 420         return keys(%valid);
 421 }
 422
 423 #
 424 # return a prompt for a field
 425 #
 426
 427 sub field_prompt
 428 {
 429         my ($self, $ele) = @_;
 430         return $valid{$ele};
 431 }
 432
 433 # take a standard input message and decode it into its standard parts
 434 sub decode_input
 435 {
 436         my $dxchan = shift;
 437         my $data = shift;
 438         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 439
 440         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 441
 442         # the above regexp must work
 443         if (!defined $sort || !defined $call || !defined  $line ||
 444                    (ref $dxchan && $call ne $chcall)) {
 445                 $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 446                 dbg('chan', "DUFF Line from $chcall: $data");
 447                 return ();
 448         }
 449
 450         return ($sort, $call, $line);
 451 }
 452
 453 no strict;
 454 sub AUTOLOAD
 455 {
 456         my $self = shift;
 457         my $name = $AUTOLOAD;
 458         return if $name =~ /::DESTROY$/;
 459         $name =~ s/.*:://o;
 460
 461         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 462
 463         # this clever line of code creates a subroutine which takes over from autoload
 464         # from OO Perl - Conway
 465         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}} ;
 466     @_ ? $self->{$name} = shift : $self->{$name} ;
 467 }
 468
 469
 470 1;
 471 __END__;