perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '5,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '5,Connection Type',
  52                   'sort' => '5,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   wcy => '0,Want WCY,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   wcyfilter => '5,WCY Filter',
  77                   spotfilter => '5,Spot Filter',
  78                   inannfilter => '5,Input Ann Filter',
  79                   inwwvfilter => '5,Input WWV Filter',
  80                   inwcyfilter => '5,Input WCY Filter',
  81                   inspotfilter => '5,Input Spot Filter',
  82                   passwd => '9,Passwd List,parray',
  83                   pingint => '5,Ping Interval ',
  84                   nopings => '5,Ping Obs Count',
  85                   lastping => '5,Ping last sent,atime',
  86                   pingtime => '5,Ping totaltime,parray',
  87                   pingave => '0,Ping ave time',
  88                   logininfo => '9,Login info req,yesno',
  89                   talklist => '0,Talk List,parray',
  90                   node => '5,Node data',
  91                  );
  92
  93 # object destruction
  94 sub DESTROY
  95 {
  96         my $self = shift;
  97         undef $self->{user};
  98         undef $self->{conn};
  99         undef $self->{loc};
 100         undef $self->{pagedata};
 101         undef $self->{group};
 102         undef $self->{delayed};
 103         undef $self->{annfilter};
 104         undef $self->{wwvfilter};
 105         undef $self->{spotfilter};
 106         undef $self->{inannfilter};
 107         undef $self->{inwwvfilter};
 108         undef $self->{inspotfilter};
 109         undef $self->{passwd};
 110         undef $self->{node};
 111 }
 112
 113 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 114 sub alloc
 115 {
 116         my ($pkg, $call, $conn, $user) = @_;
 117         my $self = {};
 118
 119         die "trying to create a duplicate channel for $call" if $channels{$call};
 120         $self->{call} = $call;
 121         $self->{priv} = 0;
 122         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 123         if (defined $user) {
 124                 $self->{user} = $user;
 125                 $self->{lang} = $user->lang;
 126                 $user->new_group() if !$user->group;
 127                 $self->{group} = $user->group;
 128                 $self->{sort} = $user->sort;
 129         }
 130         $self->{startt} = $self->{t} = time;
 131         $self->{state} = 0;
 132         $self->{oldstate} = 0;
 133         $self->{lang} = $main::lang if !$self->{lang};
 134         $self->{func} = "";
 135
 136         # get the filters
 137         $self->{spotfilter} = Filter::read_in('spots', $call, 0);
 138         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0);
 139         $self->{wcyfilter} = Filter::read_in('wcy', $call, 0);
 140         $self->{annfilter} = Filter::read_in('ann', $call, 0);
 141
 142         bless $self, $pkg;
 143         return $channels{$call} = $self;
 144 }
 145
 146 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 147 sub get
 148 {
 149         my ($pkg, $call) = @_;
 150         return $channels{$call};
 151 }
 152
 153 # obtain all the channel objects
 154 sub get_all
 155 {
 156         my ($pkg) = @_;
 157         return values(%channels);
 158 }
 159
 160 #
 161 # gimme all the ak1a nodes
 162 #
 163 sub get_all_nodes
 164 {
 165         my $ref;
 166         my @out;
 167         foreach $ref (values %channels) {
 168                 push @out, $ref if $ref->is_node;
 169         }
 170         return @out;
 171 }
 172
 173 # return a list of all users
 174 sub get_all_users
 175 {
 176         my $ref;
 177         my @out;
 178         foreach $ref (values %channels) {
 179                 push @out, $ref if $ref->is_user;
 180         }
 181         return @out;
 182 }
 183
 184 # return a list of all user callsigns
 185 sub get_all_user_calls
 186 {
 187         my $ref;
 188         my @out;
 189         foreach $ref (values %channels) {
 190                 push @out, $ref->{call} if $ref->is_user;
 191         }
 192         return @out;
 193 }
 194
 195 # obtain a channel object by searching for its connection reference
 196 sub get_by_cnum
 197 {
 198         my ($pkg, $conn) = @_;
 199         my $self;
 200
 201         foreach $self (values(%channels)) {
 202                 return $self if ($self->{conn} == $conn);
 203         }
 204         return undef;
 205 }
 206
 207 # get rid of a channel object [$obj->del()]
 208 sub del
 209 {
 210         my $self = shift;
 211
 212         $self->{group} = undef;         # belt and braces
 213         delete $channels{$self->{call}};
 214 }
 215
 216 # is it a bbs
 217 sub is_bbs
 218 {
 219         my $self = shift;
 220         return $self->{'sort'} eq 'B';
 221 }
 222
 223 sub is_node
 224 {
 225         my $self = shift;
 226         return $self->{'sort'} =~ /[ACRSX]/;
 227 }
 228 # is it an ak1a node ?
 229 sub is_ak1a
 230 {
 231         my $self = shift;
 232         return $self->{'sort'} eq 'A';
 233 }
 234
 235 # is it a user?
 236 sub is_user
 237 {
 238         my $self = shift;
 239         return $self->{'sort'} eq 'U';
 240 }
 241
 242 # is it a clx node
 243 sub is_clx
 244 {
 245         my $self = shift;
 246         return $self->{'sort'} eq 'C';
 247 }
 248
 249 # is it a spider node
 250 sub is_spider
 251 {
 252         my $self = shift;
 253         return $self->{'sort'} eq 'S';
 254 }
 255
 256 # is it a DXNet node
 257 sub is_dxnet
 258 {
 259         my $self = shift;
 260         return $self->{'sort'} eq 'X';
 261 }
 262
 263 # is it a ar-cluster node
 264 sub is_arcluster
 265 {
 266         my $self = shift;
 267         return $self->{'sort'} eq 'R';
 268 }
 269
 270 # for perl 5.004's benefit
 271 sub sort
 272 {
 273         my $self = shift;
 274         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 275 }
 276
 277 # handle out going messages, immediately without waiting for the select to drop
 278 # this could, in theory, block
 279 sub send_now
 280 {
 281         my $self = shift;
 282         my $conn = $self->{conn};
 283         return unless $conn;
 284         my $sort = shift;
 285         my $call = $self->{call};
 286
 287         for (@_) {
 288 #               chomp;
 289         my @lines = split /\n/;
 290                 for (@lines) {
 291                         $conn->send_now("$sort$call|$_");
 292                         dbg('chan', "-> $sort $call $_");
 293                 }
 294         }
 295         $self->{t} = time;
 296 }
 297
 298 #
 299 # the normal output routine
 300 #
 301 sub send                                                # this is always later and always data
 302 {
 303         my $self = shift;
 304         my $conn = $self->{conn};
 305         return unless $conn;
 306         my $call = $self->{call};
 307
 308         for (@_) {
 309 #               chomp;
 310         my @lines = split /\n/;
 311                 for (@lines) {
 312                         $conn->send_later("D$call|$_");
 313                         dbg('chan', "-> D $call $_");
 314                 }
 315         }
 316         $self->{t} = time;
 317 }
 318
 319 # send a file (always later)
 320 sub send_file
 321 {
 322         my ($self, $fn) = @_;
 323         my $call = $self->{call};
 324         my $conn = $self->{conn};
 325         my @buf;
 326
 327         open(F, $fn) or die "can't open $fn for sending file ($!)";
 328         @buf = <F>;
 329         close(F);
 330         $self->send(@buf);
 331 }
 332
 333 # this will implement language independence (in time)
 334 sub msg
 335 {
 336         my $self = shift;
 337         return DXM::msg($self->{lang}, @_);
 338 }
 339
 340 # stick a broadcast on the delayed queue (but only up to 20 items)
 341 sub delay
 342 {
 343         my $self = shift;
 344         my $s = shift;
 345
 346         $self->{delayed} = [] unless $self->{delayed};
 347         push @{$self->{delayed}}, $s;
 348         if (@{$self->{delayed}} >= 20) {
 349                 shift @{$self->{delayed}};   # lose oldest one
 350         }
 351 }
 352
 353 # change the state of the channel - lots of scope for debugging here :-)
 354 sub state
 355 {
 356         my $self = shift;
 357         if (@_) {
 358                 $self->{oldstate} = $self->{state};
 359                 $self->{state} = shift;
 360                 $self->{func} = '' unless defined $self->{func};
 361                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 362
 363                 # if there is any queued up broadcasts then splurge them out here
 364                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 365                         $self->send (@{$self->{delayed}});
 366                         delete $self->{delayed};
 367                 }
 368         }
 369         return $self->{state};
 370 }
 371
 372 # disconnect this channel
 373 sub disconnect
 374 {
 375         my $self = shift;
 376         my $user = $self->{user};
 377         my $conn = $self->{conn};
 378         my $call = $self->{call};
 379
 380         $self->finish($conn);
 381         $user->close() if defined $user;
 382         $conn->disconnect() if $conn;
 383         $self->del();
 384 }
 385
 386 #
 387 # just close all the socket connections down without any fiddling about, cleaning, being
 388 # nice to other processes and otherwise telling them what is going on.
 389 #
 390 # This is for the benefit of forked processes to prepare for starting new programs, they
 391 # don't want or need all this baggage.
 392 #
 393
 394 sub closeall
 395 {
 396         my $ref;
 397         foreach $ref (values %channels) {
 398                 $ref->{conn}->disconnect() if $ref->{conn};
 399         }
 400 }
 401
 402 #
 403 # Tell all the users that we have come in or out (if they want to know)
 404 #
 405 sub tell_login
 406 {
 407         my ($self, $m) = @_;
 408
 409         # send info to all logged in thingies
 410         my @dxchan = get_all_users();
 411         my $dxchan;
 412         foreach $dxchan (@dxchan) {
 413                 next if $dxchan == $self;
 414                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 415         }
 416 }
 417
 418 # various access routines
 419
 420 #
 421 # return a list of valid elements
 422 #
 423
 424 sub fields
 425 {
 426         return keys(%valid);
 427 }
 428
 429 #
 430 # return a prompt for a field
 431 #
 432
 433 sub field_prompt
 434 {
 435         my ($self, $ele) = @_;
 436         return $valid{$ele};
 437 }
 438
 439 # take a standard input message and decode it into its standard parts
 440 sub decode_input
 441 {
 442         my $dxchan = shift;
 443         my $data = shift;
 444         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 445
 446         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 447
 448         # the above regexp must work
 449         if (!defined $sort || !defined $call || !defined  $line ||
 450                    (ref $dxchan && $call ne $chcall)) {
 451                 $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 452                 dbg('chan', "DUFF Line from $chcall: $data");
 453                 return ();
 454         }
 455
 456         return ($sort, $call, $line);
 457 }
 458
 459 no strict;
 460 sub AUTOLOAD
 461 {
 462         my $self = shift;
 463         my $name = $AUTOLOAD;
 464         return if $name =~ /::DESTROY$/;
 465         $name =~ s/.*:://o;
 466
 467         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 468
 469         # this clever line of code creates a subroutine which takes over from autoload
 470         # from OO Perl - Conway
 471         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}} ;
 472     @_ ? $self->{$name} = shift : $self->{$name} ;
 473 }
 474
 475
 476 1;
 477 __END__;