perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   senddbg => '8,Sending Debug,yesno',
 105                   width => '0,Column Width',
 106                   disconnecting => '9,Disconnecting,yesno',
 107                   ann_talk => '0,Suppress Talk Anns,yesno',
 108                   metric => '1,Route metric',
 109                   badcount => '1,Bad Word Count',
 110                   edit => '7,Edit Function',
 111                   registered => '9,Registered?,yesno',
 112                   prompt => '0,Required Prompt',
 113                   version => '1,Node Version',
 114                   build => '1,Node Build',
 115                   verified => '9,Verified?,yesno',
 116                   newroute => '1,New Style Routing,yesno',
 117                   ve7cc => '0,VE7CC program special,yesno',
 118                   lastmsgpoll => '0,Last Msg Poll,atime',
 119                   inscript => '9,In a script,yesno',
 120                  );
 121
 122 use vars qw($VERSION $BRANCH);
 123 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 124 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 125 $main::build += $VERSION;
 126 $main::branch += $BRANCH;
 127
 128 # object destruction
 129 sub DESTROY
 130 {
 131         my $self = shift;
 132         for (keys %$self) {
 133                 if (ref($self->{$_})) {
 134                         delete $self->{$_};
 135                 }
 136         }
 137         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 138         $count--;
 139 }
 140
 141 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 142 sub alloc
 143 {
 144         my ($pkg, $call, $conn, $user) = @_;
 145         my $self = {};
 146
 147         die "trying to create a duplicate channel for $call" if $channels{$call};
 148         $self->{call} = $call;
 149         $self->{priv} = 0;
 150         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 151         if (defined $user) {
 152                 $self->{user} = $user;
 153                 $self->{lang} = $user->lang;
 154                 $user->new_group() if !$user->group;
 155                 $self->{group} = $user->group;
 156                 $self->{sort} = $user->sort;
 157         }
 158         $self->{startt} = $self->{t} = time;
 159         $self->{state} = 0;
 160         $self->{oldstate} = 0;
 161         $self->{lang} = $main::lang if !$self->{lang};
 162         $self->{func} = "";
 163
 164         # add in all the dxcc, itu, zone info
 165         my @dxcc = Prefix::extract($call);
 166         if (@dxcc > 0) {
 167                 $self->{dxcc} = $dxcc[1]->dxcc;
 168                 $self->{itu} = $dxcc[1]->itu;
 169                 $self->{cq} = $dxcc[1]->cq;
 170         }
 171
 172         $count++;
 173         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 174         bless $self, $pkg;
 175         return $channels{$call} = $self;
 176 }
 177
 178 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 179 sub get
 180 {
 181         my ($pkg, $call) = @_;
 182         return $channels{$call};
 183 }
 184
 185 # obtain all the channel objects
 186 sub get_all
 187 {
 188         my ($pkg) = @_;
 189         return values(%channels);
 190 }
 191
 192 #
 193 # gimme all the ak1a nodes
 194 #
 195 sub get_all_nodes
 196 {
 197         my $ref;
 198         my @out;
 199         foreach $ref (values %channels) {
 200                 push @out, $ref if $ref->is_node;
 201         }
 202         return @out;
 203 }
 204
 205 # return a list of all users
 206 sub get_all_users
 207 {
 208         my $ref;
 209         my @out;
 210         foreach $ref (values %channels) {
 211                 push @out, $ref if $ref->is_user;
 212         }
 213         return @out;
 214 }
 215
 216 # return a list of all user callsigns
 217 sub get_all_user_calls
 218 {
 219         my $ref;
 220         my @out;
 221         foreach $ref (values %channels) {
 222                 push @out, $ref->{call} if $ref->is_user;
 223         }
 224         return @out;
 225 }
 226
 227 # obtain a channel object by searching for its connection reference
 228 sub get_by_cnum
 229 {
 230         my ($pkg, $conn) = @_;
 231         my $self;
 232
 233         foreach $self (values(%channels)) {
 234                 return $self if ($self->{conn} == $conn);
 235         }
 236         return undef;
 237 }
 238
 239 # get rid of a channel object [$obj->del()]
 240 sub del
 241 {
 242         my $self = shift;
 243
 244         $self->{group} = undef;         # belt and braces
 245         delete $channels{$self->{call}};
 246 }
 247
 248 # is it a bbs
 249 sub is_bbs
 250 {
 251         my $self = shift;
 252         return $self->{'sort'} eq 'B';
 253 }
 254
 255 sub is_node
 256 {
 257         my $self = shift;
 258         return $self->{'sort'} =~ /[ACRSX]/;
 259 }
 260 # is it an ak1a node ?
 261 sub is_ak1a
 262 {
 263         my $self = shift;
 264         return $self->{'sort'} eq 'A';
 265 }
 266
 267 # is it a user?
 268 sub is_user
 269 {
 270         my $self = shift;
 271         return $self->{'sort'} eq 'U';
 272 }
 273
 274 # is it a clx node
 275 sub is_clx
 276 {
 277         my $self = shift;
 278         return $self->{'sort'} eq 'C';
 279 }
 280
 281 # is it a spider node
 282 sub is_spider
 283 {
 284         my $self = shift;
 285         return $self->{'sort'} eq 'S';
 286 }
 287
 288 # is it a DXNet node
 289 sub is_dxnet
 290 {
 291         my $self = shift;
 292         return $self->{'sort'} eq 'X';
 293 }
 294
 295 # is it a ar-cluster node
 296 sub is_arcluster
 297 {
 298         my $self = shift;
 299         return $self->{'sort'} eq 'R';
 300 }
 301
 302 # for perl 5.004's benefit
 303 sub sort
 304 {
 305         my $self = shift;
 306         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 307 }
 308
 309 # find out whether we are prepared to believe this callsign on this interface
 310 sub is_believed
 311 {
 312         my $self = shift;
 313         my $call = shift;
 314
 315         return grep $call eq $_, $self->user->believe;
 316 }
 317
 318 # handle out going messages, immediately without waiting for the select to drop
 319 # this could, in theory, block
 320 sub send_now
 321 {
 322         my $self = shift;
 323         my $conn = $self->{conn};
 324         return unless $conn;
 325         my $sort = shift;
 326         my $call = $self->{call};
 327
 328         for (@_) {
 329 #               chomp;
 330         my @lines = split /\n/;
 331                 for (@lines) {
 332                         $conn->send_now("$sort$call|$_");
 333                         dbg("-> $sort $call $_") if isdbg('chan');
 334                 }
 335         }
 336         $self->{t} = time;
 337 }
 338
 339 #
 340 # send later with letter (more control)
 341 #
 342
 343 sub send_later
 344 {
 345         my $self = shift;
 346         my $conn = $self->{conn};
 347         return unless $conn;
 348         my $sort = shift;
 349         my $call = $self->{call};
 350
 351         for (@_) {
 352 #               chomp;
 353         my @lines = split /\n/;
 354                 for (@lines) {
 355                         $conn->send_later("$sort$call|$_");
 356                         dbg("-> $sort $call $_") if isdbg('chan');
 357                 }
 358         }
 359         $self->{t} = time;
 360 }
 361
 362 #
 363 # the normal output routine
 364 #
 365 sub send                                                # this is always later and always data
 366 {
 367         my $self = shift;
 368         my $conn = $self->{conn};
 369         return unless $conn;
 370         my $call = $self->{call};
 371
 372         for (@_) {
 373 #               chomp;
 374         my @lines = split /\n/;
 375                 for (@lines) {
 376                         $conn->send_later("D$call|$_");
 377                         dbg("-> D $call $_") if isdbg('chan');
 378                 }
 379         }
 380         $self->{t} = time;
 381 }
 382
 383 # send a file (always later)
 384 sub send_file
 385 {
 386         my ($self, $fn) = @_;
 387         my $call = $self->{call};
 388         my $conn = $self->{conn};
 389         my @buf;
 390
 391         open(F, $fn) or die "can't open $fn for sending file ($!)";
 392         @buf = <F>;
 393         close(F);
 394         $self->send(@buf);
 395 }
 396
 397 # this will implement language independence (in time)
 398 sub msg
 399 {
 400         my $self = shift;
 401         return DXM::msg($self->{lang}, @_);
 402 }
 403
 404 # stick a broadcast on the delayed queue (but only up to 20 items)
 405 sub delay
 406 {
 407         my $self = shift;
 408         my $s = shift;
 409
 410         $self->{delayed} = [] unless $self->{delayed};
 411         push @{$self->{delayed}}, $s;
 412         if (@{$self->{delayed}} >= 20) {
 413                 shift @{$self->{delayed}};   # lose oldest one
 414         }
 415 }
 416
 417 # change the state of the channel - lots of scope for debugging here :-)
 418 sub state
 419 {
 420         my $self = shift;
 421         if (@_) {
 422                 $self->{oldstate} = $self->{state};
 423                 $self->{state} = shift;
 424                 $self->{func} = '' unless defined $self->{func};
 425                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 426
 427                 # if there is any queued up broadcasts then splurge them out here
 428                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 429                         $self->send (@{$self->{delayed}});
 430                         delete $self->{delayed};
 431                 }
 432         }
 433         return $self->{state};
 434 }
 435
 436 # disconnect this channel
 437 sub disconnect
 438 {
 439         my $self = shift;
 440         my $user = $self->{user};
 441
 442         main::clean_inqueue($self);          # clear out any remaining incoming frames
 443         $user->close() if defined $user;
 444         $self->{conn}->disconnect;
 445         $self->del();
 446 }
 447
 448 #
 449 # just close all the socket connections down without any fiddling about, cleaning, being
 450 # nice to other processes and otherwise telling them what is going on.
 451 #
 452 # This is for the benefit of forked processes to prepare for starting new programs, they
 453 # don't want or need all this baggage.
 454 #
 455
 456 sub closeall
 457 {
 458         my $ref;
 459         foreach $ref (values %channels) {
 460                 $ref->{conn}->disconnect() if $ref->{conn};
 461         }
 462 }
 463
 464 #
 465 # Tell all the users that we have come in or out (if they want to know)
 466 #
 467 sub tell_login
 468 {
 469         my ($self, $m) = @_;
 470
 471         # send info to all logged in thingies
 472         my @dxchan = get_all_users();
 473         my $dxchan;
 474         foreach $dxchan (@dxchan) {
 475                 next if $dxchan == $self;
 476                 next if $dxchan->{call} eq $main::mycall;
 477                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 478         }
 479 }
 480
 481 # various access routines
 482
 483 #
 484 # return a list of valid elements
 485 #
 486
 487 sub fields
 488 {
 489         return keys(%valid);
 490 }
 491
 492 #
 493 # return a prompt for a field
 494 #
 495
 496 sub field_prompt
 497 {
 498         my ($self, $ele) = @_;
 499         return $valid{$ele};
 500 }
 501
 502 # take a standard input message and decode it into its standard parts
 503 sub decode_input
 504 {
 505         my $dxchan = shift;
 506         my $data = shift;
 507         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 508
 509         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 510
 511         # the above regexp must work
 512         unless (defined $sort && defined $call && defined $line) {
 513 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 514                 dbg("DUFF Line on $chcall: $data");
 515                 return ();
 516         }
 517
 518         if(ref($dxchan) && $call ne $chcall) {
 519                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 520                 return();
 521         }
 522
 523         return ($sort, $call, $line);
 524 }
 525
 526 sub rspfcheck
 527 {
 528         my ($self, $flag, $node, $user) = @_;
 529         my $nref = Route::Node::get($node);
 530         my $dxchan = $nref->dxchan if $nref;
 531         if ($nref && $dxchan) {
 532             if ($dxchan == $self) {
 533                         return 1 unless $user;
 534                         return 1 if $user eq $node;
 535                         my @users = $nref->users;
 536                         return 1 if @users == 0 || grep $user eq $_, @users;
 537                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 538                 } else {
 539                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 540                 }
 541         } else {
 542                 return 1 if $flag;
 543                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 544         }
 545         return 0;
 546 }
 547
 548 # broadcast a message to all clusters taking into account isolation
 549 # [except those mentioned after buffer]
 550 sub broadcast_nodes
 551 {
 552         my $s = shift;                          # the line to be rebroadcast
 553         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 554         my @dxchan = DXChannel::get_all_nodes();
 555         my $dxchan;
 556
 557         # send it if it isn't the except list and isn't isolated and still has a hop count
 558         foreach $dxchan (@dxchan) {
 559                 next if grep $dxchan == $_, @except;
 560                 next if $dxchan == $main::me;
 561
 562                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 563
 564                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 565         }
 566 }
 567
 568 # broadcast a message to all clusters ignoring isolation
 569 # [except those mentioned after buffer]
 570 sub broadcast_all_nodes
 571 {
 572         my $s = shift;                          # the line to be rebroadcast
 573         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 574         my @dxchan = DXChannel::get_all_nodes();
 575         my $dxchan;
 576
 577         # send it if it isn't the except list and isn't isolated and still has a hop count
 578         foreach $dxchan (@dxchan) {
 579                 next if grep $dxchan == $_, @except;
 580                 next if $dxchan == $main::me;
 581
 582                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 583                 $dxchan->send($routeit);
 584         }
 585 }
 586
 587 # broadcast to all users
 588 # storing the spot or whatever until it is in a state to receive it
 589 sub broadcast_users
 590 {
 591         my $s = shift;                          # the line to be rebroadcast
 592         my $sort = shift;           # the type of transmission
 593         my $fref = shift;           # a reference to an object to filter on
 594         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 595         my @dxchan = DXChannel::get_all_users();
 596         my $dxchan;
 597         my @out;
 598
 599         foreach $dxchan (@dxchan) {
 600                 next if grep $dxchan == $_, @except;
 601                 push @out, $dxchan;
 602         }
 603         broadcast_list($s, $sort, $fref, @out);
 604 }
 605
 606
 607 # broadcast to a list of users
 608 sub broadcast_list
 609 {
 610         my $s = shift;
 611         my $sort = shift;
 612         my $fref = shift;
 613         my $dxchan;
 614
 615         foreach $dxchan (@_) {
 616                 my $filter = 1;
 617                 next if $dxchan == $main::me;
 618
 619                 if ($sort eq 'dx') {
 620                     next unless $dxchan->{dx};
 621                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 622                         next unless $filter;
 623                 }
 624                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 625                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 626                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 627                 next if $sort eq 'wx' && !$dxchan->{wx};
 628
 629                 $s =~ s/\a//og unless $dxchan->{beep};
 630
 631                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 632                         $dxchan->send($s);
 633                 } else {
 634                         $dxchan->delay($s);
 635                 }
 636         }
 637 }
 638
 639
 640 #no strict;
 641 sub AUTOLOAD
 642 {
 643         no strict;
 644         my $name = $AUTOLOAD;
 645         return if $name =~ /::DESTROY$/;
 646         $name =~ s/^.*:://o;
 647
 648         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 649
 650         # this clever line of code creates a subroutine which takes over from autoload
 651         # from OO Perl - Conway
 652         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 653         goto &$AUTOLOAD;
 654 }
 655
 656
 657 1;
 658 __END__;