perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33 use Carp;
  34
  35 use strict;
  36 use vars qw(%channels %valid);
  37
  38 %channels = ();
  39
  40 %valid = (
  41                   call => '0,Callsign',
  42                   conn => '9,Msg Conn ref',
  43                   user => '9,DXUser ref',
  44                   startt => '0,Start Time,atime',
  45                   t => '9,Time,atime',
  46                   pc50_t => '5,Last PC50 Time,atime',
  47                   priv => '9,Privilege',
  48                   state => '0,Current State',
  49                   oldstate => '5,Last State',
  50                   list => '9,Dep Chan List',
  51                   name => '0,User Name',
  52                   consort => '5,Connection Type',
  53                   'sort' => '5,Type of Channel',
  54                   wwv => '0,Want WWV,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   spotfilter => '5,Spot Filter',
  77                   inannfilter => '5,Input Ann Filter',
  78                   inwwvfilter => '5,Input WWV Filter',
  79                   inspotfilter => '5,Input Spot Filter',
  80                   passwd => '9,Passwd List,parray',
  81                  );
  82
  83 # object destruction
  84 sub DESTROY
  85 {
  86         my $self = shift;
  87         undef $self->{user};
  88         undef $self->{conn};
  89         undef $self->{loc};
  90         undef $self->{pagedata};
  91         undef $self->{group};
  92         undef $self->{delayed};
  93         undef $self->{annfilter};
  94         undef $self->{wwvfilter};
  95         undef $self->{spotfilter};
  96         undef $self->{inannfilter};
  97         undef $self->{inwwvfilter};
  98         undef $self->{inspotfilter};
  99         undef $self->{passwd};
 100 }
 101
 102 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 103 sub alloc
 104 {
 105         my ($pkg, $call, $conn, $user) = @_;
 106         my $self = {};
 107
 108         die "trying to create a duplicate channel for $call" if $channels{$call};
 109         $self->{call} = $call;
 110         $self->{priv} = 0;
 111         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 112         if (defined $user) {
 113                 $self->{user} = $user;
 114                 $self->{lang} = $user->lang;
 115                 $user->new_group() if !$user->group;
 116                 $self->{group} = $user->group;
 117         }
 118         $self->{startt} = $self->{t} = time;
 119         $self->{state} = 0;
 120         $self->{oldstate} = 0;
 121         $self->{lang} = $main::lang if !$self->{lang};
 122         $self->{func} = "";
 123
 124         # get the filters
 125         $self->{spotfilter} = Filter::read_in('spots', $call, 0);
 126         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0);
 127         $self->{annfilter} = Filter::read_in('ann', $call, 0);
 128
 129         bless $self, $pkg;
 130         return $channels{$call} = $self;
 131 }
 132
 133 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 134 sub get
 135 {
 136         my ($pkg, $call) = @_;
 137         return $channels{$call};
 138 }
 139
 140 # obtain all the channel objects
 141 sub get_all
 142 {
 143         my ($pkg) = @_;
 144         return values(%channels);
 145 }
 146
 147 # obtain a channel object by searching for its connection reference
 148 sub get_by_cnum
 149 {
 150         my ($pkg, $conn) = @_;
 151         my $self;
 152
 153         foreach $self (values(%channels)) {
 154                 return $self if ($self->{conn} == $conn);
 155         }
 156         return undef;
 157 }
 158
 159 # get rid of a channel object [$obj->del()]
 160 sub del
 161 {
 162         my $self = shift;
 163
 164         $self->{group} = undef;         # belt and braces
 165         delete $channels{$self->{call}};
 166 }
 167
 168 # is it a bbs
 169 sub is_bbs
 170 {
 171         my $self = shift;
 172         return $self->{sort} eq 'B';
 173 }
 174
 175 # is it an ak1a cluster ?
 176 sub is_ak1a
 177 {
 178         my $self = shift;
 179         return $self->{'sort'} eq 'A';
 180 }
 181
 182 # is it a user?
 183 sub is_user
 184 {
 185         my $self = shift;
 186         return $self->{'sort'} eq 'U';
 187 }
 188
 189 # is it a connect type
 190 sub is_connect
 191 {
 192         my $self = shift;
 193         return $self->{'sort'} eq 'C';
 194 }
 195
 196 # handle out going messages, immediately without waiting for the select to drop
 197 # this could, in theory, block
 198 sub send_now
 199 {
 200         my $self = shift;
 201         my $conn = $self->{conn};
 202         my $sort = shift;
 203         my $call = $self->{call};
 204
 205         for (@_) {
 206                 chomp;
 207                 $conn->send_now("$sort$call|$_") if $conn;
 208                 dbg('chan', "-> $sort $call $_") if $conn;
 209         }
 210         $self->{t} = time;
 211 }
 212
 213 #
 214 # the normal output routine
 215 #
 216 sub send                                                # this is always later and always data
 217 {
 218         my $self = shift;
 219         my $conn = $self->{conn};
 220         my $call = $self->{call};
 221
 222         for (@_) {
 223                 chomp;
 224                 $conn->send_later("D$call|$_") if $conn;
 225                 dbg('chan', "-> D $call $_") if $conn;
 226         }
 227         $self->{t} = time;
 228 }
 229
 230 # send a file (always later)
 231 sub send_file
 232 {
 233         my ($self, $fn) = @_;
 234         my $call = $self->{call};
 235         my $conn = $self->{conn};
 236         my @buf;
 237
 238         open(F, $fn) or die "can't open $fn for sending file ($!)";
 239         @buf = <F>;
 240         close(F);
 241         $self->send(@buf);
 242 }
 243
 244 # this will implement language independence (in time)
 245 sub msg
 246 {
 247         my $self = shift;
 248         return DXM::msg($self->{lang}, @_);
 249 }
 250
 251 # stick a broadcast on the delayed queue (but only up to 20 items)
 252 sub delay
 253 {
 254         my $self = shift;
 255         my $s = shift;
 256
 257         $self->{delayed} = [] unless $self->{delayed};
 258         push @{$self->{delayed}}, $s;
 259         if (@{$self->{delayed}} >= 20) {
 260                 shift @{$self->{delayed}};   # lose oldest one
 261         }
 262 }
 263
 264 # change the state of the channel - lots of scope for debugging here :-)
 265 sub state
 266 {
 267         my $self = shift;
 268         if (@_) {
 269                 $self->{oldstate} = $self->{state};
 270                 $self->{state} = shift;
 271                 $self->{func} = '' unless defined $self->{func};
 272                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 273
 274                 # if there is any queued up broadcasts then splurge them out here
 275                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 276                         $self->send (@{$self->{delayed}});
 277                         delete $self->{delayed};
 278                 }
 279         }
 280         return $self->{state};
 281 }
 282
 283 # disconnect this channel
 284 sub disconnect
 285 {
 286         my $self = shift;
 287         my $user = $self->{user};
 288         my $conn = $self->{conn};
 289         my $call = $self->{call};
 290
 291         $self->finish();
 292         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 293         $user->close() if defined $user;
 294         $conn->disconnect() if $conn;
 295         $self->del();
 296 }
 297
 298 #
 299 # just close all the socket connections down without any fiddling about, cleaning, being
 300 # nice to other processes and otherwise telling them what is going on.
 301 #
 302 # This is for the benefit of forked processes to prepare for starting new programs, they
 303 # don't want or need all this baggage.
 304 #
 305
 306 sub closeall
 307 {
 308         my $ref;
 309         foreach $ref (values %channels) {
 310                 $ref->{conn}->disconnect() if $ref->{conn};
 311         }
 312 }
 313
 314 # various access routines
 315
 316 #
 317 # return a list of valid elements
 318 #
 319
 320 sub fields
 321 {
 322         return keys(%valid);
 323 }
 324
 325 #
 326 # return a prompt for a field
 327 #
 328
 329 sub field_prompt
 330 {
 331         my ($self, $ele) = @_;
 332         return $valid{$ele};
 333 }
 334
 335 no strict;
 336 sub AUTOLOAD
 337 {
 338         my $self = shift;
 339         my $name = $AUTOLOAD;
 340         return if $name =~ /::DESTROY$/;
 341         $name =~ s/.*:://o;
 342
 343         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 344         @_ ? $self->{$name} = shift : $self->{$name} ;
 345 }
 346
 347 1;
 348 __END__;