perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33 use Carp;
  34
  35 use strict;
  36 use vars qw(%channels %valid);
  37
  38 %channels = ();
  39
  40 %valid = (
  41                   call => '0,Callsign',
  42                   conn => '9,Msg Conn ref',
  43                   user => '9,DXUser ref',
  44                   startt => '0,Start Time,atime',
  45                   t => '9,Time,atime',
  46                   pc50_t => '5,Last PC50 Time,atime',
  47                   priv => '9,Privilege',
  48                   state => '0,Current State',
  49                   oldstate => '5,Last State',
  50                   list => '9,Dep Chan List',
  51                   name => '0,User Name',
  52                   consort => '5,Connection Type',
  53                   'sort' => '5,Type of Channel',
  54                   wwv => '0,Want WWV,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   spotfilter => '5,Spot Filter',
  77                   inannfilter => '5,Input Ann Filter',
  78                   inwwvfilter => '5,Input WWV Filter',
  79                   inspotfilter => '5,Input Spot Filter',
  80                   passwd => '9,Passwd List,parray',
  81                   pingint => '9,Ping Interval ',
  82                   nopings => '9,Ping Obs Count',
  83                   lastping => '9,Ping last sent,atime',
  84           pingrec => '9,Pings no rec',
  85                   pingtime => '9,Ping totaltime',
  86                   pingave => '0,Ping ave time',
  87                  );
  88
  89 # object destruction
  90 sub DESTROY
  91 {
  92         my $self = shift;
  93         undef $self->{user};
  94         undef $self->{conn};
  95         undef $self->{loc};
  96         undef $self->{pagedata};
  97         undef $self->{group};
  98         undef $self->{delayed};
  99         undef $self->{annfilter};
 100         undef $self->{wwvfilter};
 101         undef $self->{spotfilter};
 102         undef $self->{inannfilter};
 103         undef $self->{inwwvfilter};
 104         undef $self->{inspotfilter};
 105         undef $self->{passwd};
 106 }
 107
 108 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 109 sub alloc
 110 {
 111         my ($pkg, $call, $conn, $user) = @_;
 112         my $self = {};
 113
 114         die "trying to create a duplicate channel for $call" if $channels{$call};
 115         $self->{call} = $call;
 116         $self->{priv} = 0;
 117         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 118         if (defined $user) {
 119                 $self->{user} = $user;
 120                 $self->{lang} = $user->lang;
 121                 $user->new_group() if !$user->group;
 122                 $self->{group} = $user->group;
 123         }
 124         $self->{startt} = $self->{t} = time;
 125         $self->{state} = 0;
 126         $self->{oldstate} = 0;
 127         $self->{lang} = $main::lang if !$self->{lang};
 128         $self->{func} = "";
 129
 130         # get the filters
 131         $self->{spotfilter} = Filter::read_in('spots', $call, 0);
 132         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0);
 133         $self->{annfilter} = Filter::read_in('ann', $call, 0);
 134
 135         bless $self, $pkg;
 136         return $channels{$call} = $self;
 137 }
 138
 139 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 140 sub get
 141 {
 142         my ($pkg, $call) = @_;
 143         return $channels{$call};
 144 }
 145
 146 # obtain all the channel objects
 147 sub get_all
 148 {
 149         my ($pkg) = @_;
 150         return values(%channels);
 151 }
 152
 153 # obtain a channel object by searching for its connection reference
 154 sub get_by_cnum
 155 {
 156         my ($pkg, $conn) = @_;
 157         my $self;
 158
 159         foreach $self (values(%channels)) {
 160                 return $self if ($self->{conn} == $conn);
 161         }
 162         return undef;
 163 }
 164
 165 # get rid of a channel object [$obj->del()]
 166 sub del
 167 {
 168         my $self = shift;
 169
 170         $self->{group} = undef;         # belt and braces
 171         delete $channels{$self->{call}};
 172 }
 173
 174 # is it a bbs
 175 sub is_bbs
 176 {
 177         my $self = shift;
 178         return $self->{sort} eq 'B';
 179 }
 180
 181 # is it an ak1a cluster ?
 182 sub is_ak1a
 183 {
 184         my $self = shift;
 185         return $self->{'sort'} eq 'A';
 186 }
 187
 188 # is it a user?
 189 sub is_user
 190 {
 191         my $self = shift;
 192         return $self->{'sort'} eq 'U';
 193 }
 194
 195 # is it a connect type
 196 sub is_connect
 197 {
 198         my $self = shift;
 199         return $self->{'sort'} eq 'C';
 200 }
 201
 202 # handle out going messages, immediately without waiting for the select to drop
 203 # this could, in theory, block
 204 sub send_now
 205 {
 206         my $self = shift;
 207         my $conn = $self->{conn};
 208         return unless $conn;
 209         my $sort = shift;
 210         my $call = $self->{call};
 211
 212         for (@_) {
 213                 chomp;
 214         my @lines = split /\n/;
 215                 for (@lines) {
 216                         $conn->send_now("$sort$call|$_");
 217                         dbg('chan', "-> $sort $call $_");
 218                 }
 219         }
 220         $self->{t} = time;
 221 }
 222
 223 #
 224 # the normal output routine
 225 #
 226 sub send                                                # this is always later and always data
 227 {
 228         my $self = shift;
 229         my $conn = $self->{conn};
 230         return unless $conn;
 231         my $call = $self->{call};
 232
 233         for (@_) {
 234                 chomp;
 235         my @lines = split /\n/;
 236                 for (@lines) {
 237                         $conn->send_later("D$call|$_");
 238                         dbg('chan', "-> D $call $_");
 239                 }
 240         }
 241         $self->{t} = time;
 242 }
 243
 244 # send a file (always later)
 245 sub send_file
 246 {
 247         my ($self, $fn) = @_;
 248         my $call = $self->{call};
 249         my $conn = $self->{conn};
 250         my @buf;
 251
 252         open(F, $fn) or die "can't open $fn for sending file ($!)";
 253         @buf = <F>;
 254         close(F);
 255         $self->send(@buf);
 256 }
 257
 258 # this will implement language independence (in time)
 259 sub msg
 260 {
 261         my $self = shift;
 262         return DXM::msg($self->{lang}, @_);
 263 }
 264
 265 # stick a broadcast on the delayed queue (but only up to 20 items)
 266 sub delay
 267 {
 268         my $self = shift;
 269         my $s = shift;
 270
 271         $self->{delayed} = [] unless $self->{delayed};
 272         push @{$self->{delayed}}, $s;
 273         if (@{$self->{delayed}} >= 20) {
 274                 shift @{$self->{delayed}};   # lose oldest one
 275         }
 276 }
 277
 278 # change the state of the channel - lots of scope for debugging here :-)
 279 sub state
 280 {
 281         my $self = shift;
 282         if (@_) {
 283                 $self->{oldstate} = $self->{state};
 284                 $self->{state} = shift;
 285                 $self->{func} = '' unless defined $self->{func};
 286                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 287
 288                 # if there is any queued up broadcasts then splurge them out here
 289                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 290                         $self->send (@{$self->{delayed}});
 291                         delete $self->{delayed};
 292                 }
 293         }
 294         return $self->{state};
 295 }
 296
 297 # disconnect this channel
 298 sub disconnect
 299 {
 300         my $self = shift;
 301         my $user = $self->{user};
 302         my $conn = $self->{conn};
 303         my $call = $self->{call};
 304
 305         $self->finish();
 306         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 307         $user->close() if defined $user;
 308         $conn->disconnect() if $conn;
 309         $self->del();
 310 }
 311
 312 #
 313 # just close all the socket connections down without any fiddling about, cleaning, being
 314 # nice to other processes and otherwise telling them what is going on.
 315 #
 316 # This is for the benefit of forked processes to prepare for starting new programs, they
 317 # don't want or need all this baggage.
 318 #
 319
 320 sub closeall
 321 {
 322         my $ref;
 323         foreach $ref (values %channels) {
 324                 $ref->{conn}->disconnect() if $ref->{conn};
 325         }
 326 }
 327
 328 # various access routines
 329
 330 #
 331 # return a list of valid elements
 332 #
 333
 334 sub fields
 335 {
 336         return keys(%valid);
 337 }
 338
 339 #
 340 # return a prompt for a field
 341 #
 342
 343 sub field_prompt
 344 {
 345         my ($self, $ele) = @_;
 346         return $valid{$ele};
 347 }
 348
 349 no strict;
 350 sub AUTOLOAD
 351 {
 352         my $self = shift;
 353         my $name = $AUTOLOAD;
 354         return if $name =~ /::DESTROY$/;
 355         $name =~ s/.*:://o;
 356
 357         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 358         @_ ? $self->{$name} = shift : $self->{$name} ;
 359 }
 360
 361 1;
 362 __END__;