perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   senddbg => '8,Sending Debug,yesno',
 105                   width => '0,Column Width',
 106                   disconnecting => '9,Disconnecting,yesno',
 107                   ann_talk => '0,Suppress Talk Anns,yesno',
 108                   metric => '1,Route metric',
 109                   badcount => '1,Bad Word Count',
 110                   edit => '7,Edit Function',
 111                   registered => '9,Registered?,yesno',
 112                   prompt => '0,Required Prompt',
 113                   version => '1,Node Version',
 114                   build => '1,Node Build',
 115                   verified => '9,Verified?,yesno',
 116                   newroute => '1,New Style Routing,yesno',
 117                   ve7cc => '0,VE7CC program special,yesno',
 118                   lastmsgpoll => '0,Last Msg Poll,atime',
 119                   inscript => '9,In a script,yesno',
 120                   inqueue => '9,Input Queue,parray',
 121                  );
 122
 123 use vars qw($VERSION $BRANCH);
 124 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 125 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 126 $main::build += $VERSION;
 127 $main::branch += $BRANCH;
 128
 129 # object destruction
 130 sub DESTROY
 131 {
 132         my $self = shift;
 133         for (keys %$self) {
 134                 if (ref($self->{$_})) {
 135                         delete $self->{$_};
 136                 }
 137         }
 138         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 139         $count--;
 140 }
 141
 142 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 143 sub alloc
 144 {
 145         my ($pkg, $call, $conn, $user) = @_;
 146         my $self = {};
 147
 148         die "trying to create a duplicate channel for $call" if $channels{$call};
 149         $self->{call} = $call;
 150         $self->{priv} = 0;
 151         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 152         if (defined $user) {
 153                 $self->{user} = $user;
 154                 $self->{lang} = $user->lang;
 155                 $user->new_group() if !$user->group;
 156                 $self->{group} = $user->group;
 157                 $self->{sort} = $user->sort;
 158         }
 159         $self->{startt} = $self->{t} = time;
 160         $self->{state} = 0;
 161         $self->{oldstate} = 0;
 162         $self->{lang} = $main::lang if !$self->{lang};
 163         $self->{func} = "";
 164
 165         # add in all the dxcc, itu, zone info
 166         my @dxcc = Prefix::extract($call);
 167         if (@dxcc > 0) {
 168                 $self->{dxcc} = $dxcc[1]->dxcc;
 169                 $self->{itu} = $dxcc[1]->itu;
 170                 $self->{cq} = $dxcc[1]->cq;
 171         }
 172         $self->{inqueue} = [];
 173
 174         $count++;
 175         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 176         bless $self, $pkg;
 177         return $channels{$call} = $self;
 178 }
 179
 180 sub rec
 181 {
 182         my ($self, $msg) = @_;
 183
 184         # queue the message and the channel object for later processing
 185         if (defined $msg) {
 186                 push @{$self->{inqueue}}, $msg;
 187         }
 188 }
 189
 190 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 191 sub get
 192 {
 193         my ($pkg, $call) = @_;
 194         return $channels{$call};
 195 }
 196
 197 # obtain all the channel objects
 198 sub get_all
 199 {
 200         return values(%channels);
 201 }
 202
 203 #
 204 # gimme all the ak1a nodes
 205 #
 206 sub get_all_nodes
 207 {
 208         my $ref;
 209         my @out;
 210         foreach $ref (values %channels) {
 211                 push @out, $ref if $ref->is_node;
 212         }
 213         return @out;
 214 }
 215
 216 # return a list of all users
 217 sub get_all_users
 218 {
 219         my $ref;
 220         my @out;
 221         foreach $ref (values %channels) {
 222                 push @out, $ref if $ref->is_user;
 223         }
 224         return @out;
 225 }
 226
 227 # return a list of all user callsigns
 228 sub get_all_user_calls
 229 {
 230         my $ref;
 231         my @out;
 232         foreach $ref (values %channels) {
 233                 push @out, $ref->{call} if $ref->is_user;
 234         }
 235         return @out;
 236 }
 237
 238 # obtain a channel object by searching for its connection reference
 239 sub get_by_cnum
 240 {
 241         my ($pkg, $conn) = @_;
 242         my $self;
 243
 244         foreach $self (values(%channels)) {
 245                 return $self if ($self->{conn} == $conn);
 246         }
 247         return undef;
 248 }
 249
 250 # get rid of a channel object [$obj->del()]
 251 sub del
 252 {
 253         my $self = shift;
 254
 255         $self->{group} = undef;         # belt and braces
 256         delete $channels{$self->{call}};
 257 }
 258
 259 # is it a bbs
 260 sub is_bbs
 261 {
 262         my $self = shift;
 263         return $self->{'sort'} eq 'B';
 264 }
 265
 266 sub is_node
 267 {
 268         my $self = shift;
 269         return $self->{'sort'} =~ /[ACRSXW]/;
 270 }
 271 # is it an ak1a node ?
 272 sub is_ak1a
 273 {
 274         my $self = shift;
 275         return $self->{'sort'} eq 'A';
 276 }
 277
 278 # is it a user?
 279 sub is_user
 280 {
 281         my $self = shift;
 282         return $self->{'sort'} eq 'U';
 283 }
 284
 285 # is it a clx node
 286 sub is_clx
 287 {
 288         my $self = shift;
 289         return $self->{'sort'} eq 'C';
 290 }
 291
 292 # it is Aranea
 293 sub is_aranea
 294 {
 295         my $self = shift;
 296         return $self->{'sort'} eq 'W';
 297 }
 298
 299 # is it a spider node
 300 sub is_spider
 301 {
 302         my $self = shift;
 303         return $self->{'sort'} eq 'S';
 304 }
 305
 306 # is it a DXNet node
 307 sub is_dxnet
 308 {
 309         my $self = shift;
 310         return $self->{'sort'} eq 'X';
 311 }
 312
 313 # is it a ar-cluster node
 314 sub is_arcluster
 315 {
 316         my $self = shift;
 317         return $self->{'sort'} eq 'R';
 318 }
 319
 320 # for perl 5.004's benefit
 321 sub sort
 322 {
 323         my $self = shift;
 324         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 325 }
 326
 327 # find out whether we are prepared to believe this callsign on this interface
 328 sub is_believed
 329 {
 330         my $self = shift;
 331         my $call = shift;
 332
 333         return grep $call eq $_, $self->user->believe;
 334 }
 335
 336 # handle out going messages, immediately without waiting for the select to drop
 337 # this could, in theory, block
 338 sub send_now
 339 {
 340         my $self = shift;
 341         my $conn = $self->{conn};
 342         return unless $conn;
 343         my $sort = shift;
 344         my $call = $self->{call};
 345
 346         for (@_) {
 347 #               chomp;
 348         my @lines = split /\n/;
 349                 for (@lines) {
 350                         $conn->send_now("$sort$call|$_");
 351                         dbg("-> $sort $call $_") if isdbg('chan');
 352                 }
 353         }
 354         $self->{t} = time;
 355 }
 356
 357 #
 358 # send later with letter (more control)
 359 #
 360
 361 sub send_later
 362 {
 363         my $self = shift;
 364         my $conn = $self->{conn};
 365         return unless $conn;
 366         my $sort = shift;
 367         my $call = $self->{call};
 368
 369         for (@_) {
 370 #               chomp;
 371         my @lines = split /\n/;
 372                 for (@lines) {
 373                         $conn->send_later("$sort$call|$_");
 374                         dbg("-> $sort $call $_") if isdbg('chan');
 375                 }
 376         }
 377         $self->{t} = time;
 378 }
 379
 380 #
 381 # the normal output routine
 382 #
 383 sub send                                                # this is always later and always data
 384 {
 385         my $self = shift;
 386         my $conn = $self->{conn};
 387         return unless $conn;
 388         my $call = $self->{call};
 389
 390         for (@_) {
 391 #               chomp;
 392         my @lines = split /\n/;
 393                 for (@lines) {
 394                         $conn->send_later("D$call|$_");
 395                         dbg("-> D $call $_") if isdbg('chan');
 396                 }
 397         }
 398         $self->{t} = time;
 399 }
 400
 401 # send a file (always later)
 402 sub send_file
 403 {
 404         my ($self, $fn) = @_;
 405         my $call = $self->{call};
 406         my $conn = $self->{conn};
 407         my @buf;
 408
 409         open(F, $fn) or die "can't open $fn for sending file ($!)";
 410         @buf = <F>;
 411         close(F);
 412         $self->send(@buf);
 413 }
 414
 415 # this will implement language independence (in time)
 416 sub msg
 417 {
 418         my $self = shift;
 419         return DXM::msg($self->{lang}, @_);
 420 }
 421
 422 # stick a broadcast on the delayed queue (but only up to 20 items)
 423 sub delay
 424 {
 425         my $self = shift;
 426         my $s = shift;
 427
 428         $self->{delayed} = [] unless $self->{delayed};
 429         push @{$self->{delayed}}, $s;
 430         if (@{$self->{delayed}} >= 20) {
 431                 shift @{$self->{delayed}};   # lose oldest one
 432         }
 433 }
 434
 435 # change the state of the channel - lots of scope for debugging here :-)
 436 sub state
 437 {
 438         my $self = shift;
 439         if (@_) {
 440                 $self->{oldstate} = $self->{state};
 441                 $self->{state} = shift;
 442                 $self->{func} = '' unless defined $self->{func};
 443                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 444
 445                 # if there is any queued up broadcasts then splurge them out here
 446                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 447                         $self->send (@{$self->{delayed}});
 448                         delete $self->{delayed};
 449                 }
 450         }
 451         return $self->{state};
 452 }
 453
 454 # disconnect this channel
 455 sub disconnect
 456 {
 457         my $self = shift;
 458         my $user = $self->{user};
 459
 460         $user->close() if defined $user;
 461         $self->{conn}->disconnect;
 462         $self->del();
 463 }
 464
 465 #
 466 # just close all the socket connections down without any fiddling about, cleaning, being
 467 # nice to other processes and otherwise telling them what is going on.
 468 #
 469 # This is for the benefit of forked processes to prepare for starting new programs, they
 470 # don't want or need all this baggage.
 471 #
 472
 473 sub closeall
 474 {
 475         my $ref;
 476         foreach $ref (values %channels) {
 477                 $ref->{conn}->disconnect() if $ref->{conn};
 478         }
 479 }
 480
 481 #
 482 # Tell all the users that we have come in or out (if they want to know)
 483 #
 484 sub tell_login
 485 {
 486         my ($self, $m) = @_;
 487
 488         # send info to all logged in thingies
 489         my @dxchan = get_all_users();
 490         my $dxchan;
 491         foreach $dxchan (@dxchan) {
 492                 next if $dxchan == $self;
 493                 next if $dxchan->{call} eq $main::mycall;
 494                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 495         }
 496 }
 497
 498 # various access routines
 499
 500 #
 501 # return a list of valid elements
 502 #
 503
 504 sub fields
 505 {
 506         return keys(%valid);
 507 }
 508
 509 #
 510 # return a prompt for a field
 511 #
 512
 513 sub field_prompt
 514 {
 515         my ($self, $ele) = @_;
 516         return $valid{$ele};
 517 }
 518
 519 # take a standard input message and decode it into its standard parts
 520 sub decode_input
 521 {
 522         my $dxchan = shift;
 523         my $data = shift;
 524         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 525
 526         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 527
 528         # the above regexp must work
 529         unless (defined $sort && defined $call && defined $line) {
 530 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 531                 dbg("DUFF Line on $chcall: $data");
 532                 return ();
 533         }
 534
 535         if(ref($dxchan) && $call ne $chcall) {
 536                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 537                 return();
 538         }
 539
 540         return ($sort, $call, $line);
 541 }
 542
 543 sub rspfcheck
 544 {
 545         my ($self, $flag, $node, $user) = @_;
 546         my $nref = Route::Node::get($node);
 547         my $dxchan = $nref->dxchan if $nref;
 548         if ($nref && $dxchan) {
 549             if ($dxchan == $self) {
 550                         return 1 unless $user;
 551                         return 1 if $user eq $node;
 552                         my @users = $nref->users;
 553                         return 1 if @users == 0 || grep $user eq $_, @users;
 554                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 555                 } else {
 556                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 557                 }
 558         } else {
 559                 return 1 if $flag;
 560                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 561         }
 562         return 0;
 563 }
 564
 565 # broadcast a message to all clusters taking into account isolation
 566 # [except those mentioned after buffer]
 567 sub broadcast_nodes
 568 {
 569         my $s = shift;                          # the line to be rebroadcast
 570         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 571         my @dxchan = get_all_nodes();
 572         my $dxchan;
 573
 574         # send it if it isn't the except list and isn't isolated and still has a hop count
 575         foreach $dxchan (@dxchan) {
 576                 next if grep $dxchan == $_, @except;
 577                 next if $dxchan == $main::me;
 578
 579                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 580
 581                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 582         }
 583 }
 584
 585 # broadcast a message to all clusters ignoring isolation
 586 # [except those mentioned after buffer]
 587 sub broadcast_all_nodes
 588 {
 589         my $s = shift;                          # the line to be rebroadcast
 590         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 591         my @dxchan = get_all_nodes();
 592         my $dxchan;
 593
 594         # send it if it isn't the except list and isn't isolated and still has a hop count
 595         foreach $dxchan (@dxchan) {
 596                 next if grep $dxchan == $_, @except;
 597                 next if $dxchan == $main::me;
 598
 599                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 600                 $dxchan->send($routeit);
 601         }
 602 }
 603
 604 # broadcast to all users
 605 # storing the spot or whatever until it is in a state to receive it
 606 sub broadcast_users
 607 {
 608         my $s = shift;                          # the line to be rebroadcast
 609         my $sort = shift;           # the type of transmission
 610         my $fref = shift;           # a reference to an object to filter on
 611         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 612         my @dxchan = get_all_users();
 613         my $dxchan;
 614         my @out;
 615
 616         foreach $dxchan (@dxchan) {
 617                 next if grep $dxchan == $_, @except;
 618                 push @out, $dxchan;
 619         }
 620         broadcast_list($s, $sort, $fref, @out);
 621 }
 622
 623
 624 # broadcast to a list of users
 625 sub broadcast_list
 626 {
 627         my $s = shift;
 628         my $sort = shift;
 629         my $fref = shift;
 630         my $dxchan;
 631
 632         foreach $dxchan (@_) {
 633                 my $filter = 1;
 634                 next if $dxchan == $main::me;
 635
 636                 if ($sort eq 'dx') {
 637                     next unless $dxchan->{dx};
 638                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 639                         next unless $filter;
 640                 }
 641                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 642                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 643                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 644                 next if $sort eq 'wx' && !$dxchan->{wx};
 645
 646                 $s =~ s/\a//og unless $dxchan->{beep};
 647
 648                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 649                         $dxchan->send($s);
 650                 } else {
 651                         $dxchan->delay($s);
 652                 }
 653         }
 654 }
 655
 656 sub process
 657 {
 658         foreach my $dxchan (get_all()) {
 659
 660                 while (my $data = shift @{$dxchan->{inqueue}}) {
 661                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 662                         next unless defined $sort;
 663
 664                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 665                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 666                         if ($dxchan->{disconnecting}) {
 667                                 dbg('In disconnection, ignored');
 668                                 next;
 669                         }
 670
 671                         # handle A records
 672                         my $user = $dxchan->user;
 673                         if ($sort eq 'A' || $sort eq 'O') {
 674                                 $dxchan->start($line, $sort);
 675                         } elsif ($sort eq 'I') {
 676                                 die "\$user not defined for $call" if !defined $user;
 677
 678                                 # normal input
 679                                 $dxchan->normal($line);
 680                         } elsif ($sort eq 'Z') {
 681                                 $dxchan->disconnect;
 682                         } elsif ($sort eq 'D') {
 683                                 ;                               # ignored (an echo)
 684                         } elsif ($sort eq 'G') {
 685                                 $dxchan->enhanced($line);
 686                         } else {
 687                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 688                         }
 689                 }
 690         }
 691 }
 692
 693 #no strict;
 694 sub AUTOLOAD
 695 {
 696         no strict;
 697         my $name = $AUTOLOAD;
 698         return if $name =~ /::DESTROY$/;
 699         $name =~ s/^.*:://o;
 700
 701         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 702
 703         # this clever line of code creates a subroutine which takes over from autoload
 704         # from OO Perl - Conway
 705         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 706         goto &$AUTOLOAD;
 707 }
 708
 709
 710 1;
 711 __END__;