perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 #
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count $maxerrors);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   pc92filter => '5,PC92 Route Filt-out',
  84                   inannfilter => '5,Ann Filt-inp',
  85                   inwwvfilter => '5,WWV Filt-inp',
  86                   inwcyfilter => '5,WCY Filt-inp',
  87                   inspotsfilter => '5,Spot Filt-inp',
  88                   inroutefilter => '5,Route Filt-inp',
  89                   inpc92filter => '5,PC92 Route Filt-inp',
  90                   passwd => '9,Passwd List,yesno',
  91                   pingint => '5,Ping Interval ',
  92                   nopings => '5,Ping Obs Count',
  93                   lastping => '5,Ping last sent,atime',
  94                   pingtime => '5,Ping totaltime,parray',
  95                   pingave => '0,Ping ave time',
  96                   logininfo => '9,Login info req,yesno',
  97                   talklist => '0,Talk List,parray',
  98                   cluster => '5,Cluster data',
  99                   isbasic => '9,Internal Connection',
 100                   errors => '9,Errors',
 101                   route => '9,Route Data',
 102                   dxcc => '0,Country Code',
 103                   itu => '0,ITU Zone',
 104                   cq => '0,CQ Zone',
 105                   enhanced => '5,Enhanced Client,yesno',
 106                   gtk => '5,Using GTK,yesno',
 107                   senddbg => '8,Sending Debug,yesno',
 108                   width => '0,Column Width',
 109                   disconnecting => '9,Disconnecting,yesno',
 110                   ann_talk => '0,Suppress Talk Anns,yesno',
 111                   metric => '1,Route metric',
 112                   badcount => '1,Bad Word Count',
 113                   edit => '7,Edit Function',
 114                   registered => '9,Registered?,yesno',
 115                   prompt => '0,Required Prompt',
 116                   version => '1,Node Version',
 117                   build => '1,Node Build',
 118                   verified => '9,Verified?,yesno',
 119                   newroute => '1,New Style Routing,yesno',
 120                   ve7cc => '0,VE7CC program special,yesno',
 121                   lastmsgpoll => '0,Last Msg Poll,atime',
 122                   inscript => '9,In a script,yesno',
 123                   handle_xml => '9,Handles XML,yesno',
 124                   do_pc9x => '9,Handles PC9x,yesno',
 125                   inqueue => '9,Input Queue,parray',
 126                   next_pc92_update => '9,Next PC92 Update,atime',
 127                   next_pc92_keepalive => '9,Next PC92 KeepAlive,atime',
 128                  );
 129
 130 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
 131
 132 # object destruction
 133 sub DESTROY
 134 {
 135         my $self = shift;
 136         for (keys %$self) {
 137                 if (ref($self->{$_})) {
 138                         delete $self->{$_};
 139                 }
 140         }
 141         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 142         $count--;
 143 }
 144
 145 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 146 sub alloc
 147 {
 148         my ($pkg, $call, $conn, $user) = @_;
 149         my $self = {};
 150
 151         die "trying to create a duplicate channel for $call" if $channels{$call};
 152         $self->{call} = $call;
 153         $self->{priv} = 0;
 154         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 155         if (defined $user) {
 156                 $self->{user} = $user;
 157                 $self->{lang} = $user->lang;
 158                 $user->new_group unless $user->group;
 159                 $user->new_buddies unless $user->buddies;
 160                 $self->{group} = $user->group;
 161                 $self->{sort} = $user->sort;
 162         }
 163         $self->{startt} = $self->{t} = time;
 164         $self->{state} = 0;
 165         $self->{oldstate} = 0;
 166         $self->{lang} = $main::lang if !$self->{lang};
 167         $self->{func} = "";
 168
 169         # add in all the dxcc, itu, zone info
 170         my @dxcc = Prefix::extract($call);
 171         if (@dxcc > 0) {
 172                 $self->{dxcc} = $dxcc[1]->dxcc;
 173                 $self->{itu} = $dxcc[1]->itu;
 174                 $self->{cq} = $dxcc[1]->cq;
 175         }
 176         $self->{inqueue} = [];
 177
 178         $count++;
 179         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 180         bless $self, $pkg;
 181         return $channels{$call} = $self;
 182 }
 183
 184 # count errors and disconnect if too many
 185 # this has to be here because it can come from rcmd (DXProt) as
 186 # well as DXCommandmode.
 187 sub _error_out
 188 {
 189         my $self = shift;
 190         my $e = shift;
 191         if (++$self->{errors} > $maxerrors) {
 192                 $self->send($self->msg('e26'));
 193                 $self->disconnect;
 194                 return ();
 195         } else {
 196                 return ($self->msg($e));
 197         }
 198 }
 199
 200 # rebless this channel as something else
 201 sub rebless
 202 {
 203         my $self = shift;
 204         my $class = shift;
 205         return $channels{$self->{call}} = bless $self, $class;
 206 }
 207
 208 sub rec
 209 {
 210         my ($self, $msg) = @_;
 211
 212         # queue the message and the channel object for later processing
 213         if (defined $msg) {
 214                 push @{$self->{inqueue}}, $msg;
 215         }
 216 }
 217
 218 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 219 sub get
 220 {
 221         my $call = shift;
 222         return $channels{$call};
 223 }
 224
 225 # obtain all the channel objects
 226 sub get_all
 227 {
 228         return values(%channels);
 229 }
 230
 231 #
 232 # gimme all the ak1a nodes
 233 #
 234 sub get_all_nodes
 235 {
 236         my $ref;
 237         my @out;
 238         foreach $ref (values %channels) {
 239                 push @out, $ref if $ref->is_node;
 240         }
 241         return @out;
 242 }
 243
 244 # return a list of node calls
 245 sub get_all_node_calls
 246 {
 247         my $ref;
 248         my @out;
 249         foreach $ref (values %channels) {
 250                 push @out, $ref->{call} if $ref->is_node;
 251         }
 252         return @out;
 253 }
 254
 255 # return a list of all users
 256 sub get_all_users
 257 {
 258         my $ref;
 259         my @out;
 260         foreach $ref (values %channels) {
 261                 push @out, $ref if $ref->is_user;
 262         }
 263         return @out;
 264 }
 265
 266 # return a list of all user callsigns
 267 sub get_all_user_calls
 268 {
 269         my $ref;
 270         my @out;
 271         foreach $ref (values %channels) {
 272                 push @out, $ref->{call} if $ref->is_user;
 273         }
 274         return @out;
 275 }
 276
 277 # obtain a channel object by searching for its connection reference
 278 sub get_by_cnum
 279 {
 280         my ($pkg, $conn) = @_;
 281         my $self;
 282
 283         foreach $self (values(%channels)) {
 284                 return $self if ($self->{conn} == $conn);
 285         }
 286         return undef;
 287 }
 288
 289 # get rid of a channel object [$obj->del()]
 290 sub del
 291 {
 292         my $self = shift;
 293
 294         $self->{group} = undef;         # belt and braces
 295         delete $channels{$self->{call}};
 296 }
 297
 298 # is it a bbs
 299 sub is_bbs
 300 {
 301         my $self = shift;
 302         return $self->{'sort'} eq 'B';
 303 }
 304
 305 sub is_node
 306 {
 307         my $self = shift;
 308         return $self->{'sort'} =~ /[ACRSXW]/;
 309 }
 310 # is it an ak1a node ?
 311 sub is_ak1a
 312 {
 313         my $self = shift;
 314         return $self->{'sort'} eq 'A';
 315 }
 316
 317 # is it a user?
 318 sub is_user
 319 {
 320         my $self = shift;
 321         return $self->{'sort'} eq 'U';
 322 }
 323
 324 # is it a clx node
 325 sub is_clx
 326 {
 327         my $self = shift;
 328         return $self->{'sort'} eq 'C';
 329 }
 330
 331 # it is Aranea
 332 sub is_aranea
 333 {
 334         my $self = shift;
 335         return $self->{'sort'} eq 'W';
 336 }
 337
 338 # is it a spider node
 339 sub is_spider
 340 {
 341         my $self = shift;
 342         return $self->{'sort'} eq 'S';
 343 }
 344
 345 # is it a DXNet node
 346 sub is_dxnet
 347 {
 348         my $self = shift;
 349         return $self->{'sort'} eq 'X';
 350 }
 351
 352 # is it a ar-cluster node
 353 sub is_arcluster
 354 {
 355         my $self = shift;
 356         return $self->{'sort'} eq 'R';
 357 }
 358
 359 # for perl 5.004's benefit
 360 sub sort
 361 {
 362         my $self = shift;
 363         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 364 }
 365
 366 # find out whether we are prepared to believe this callsign on this interface
 367 sub is_believed
 368 {
 369         my $self = shift;
 370         my $call = shift;
 371
 372         return grep $call eq $_, $self->user->believe;
 373 }
 374
 375 # handle out going messages, immediately without waiting for the select to drop
 376 # this could, in theory, block
 377 sub send_now
 378 {
 379         my $self = shift;
 380         my $conn = $self->{conn};
 381         return unless $conn;
 382         my $sort = shift;
 383         my $call = $self->{call};
 384
 385         for (@_) {
 386 #               chomp;
 387         my @lines = split /\n/;
 388                 for (@lines) {
 389                         $conn->send_now("$sort$call|$_");
 390                         # debug log it, but not if it is a log message
 391                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 392                 }
 393         }
 394         $self->{t} = time;
 395 }
 396
 397 #
 398 # send later with letter (more control)
 399 #
 400
 401 sub send_later
 402 {
 403         my $self = shift;
 404         my $conn = $self->{conn};
 405         return unless $conn;
 406         my $sort = shift;
 407         my $call = $self->{call};
 408
 409         for (@_) {
 410 #               chomp;
 411         my @lines = split /\n/;
 412                 for (@lines) {
 413                         $conn->send_later("$sort$call|$_");
 414                         # debug log it, but not if it is a log message
 415                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 416                 }
 417         }
 418         $self->{t} = time;
 419 }
 420
 421 #
 422 # the normal output routine
 423 #
 424 sub send                                                # this is always later and always data
 425 {
 426         my $self = shift;
 427         my $conn = $self->{conn};
 428         return unless $conn;
 429         my $call = $self->{call};
 430
 431         foreach my $l (@_) {
 432                 for (ref $l ? @$l : $l) {
 433                         my @lines = split /\n/;
 434                         for (@lines) {
 435                                 $conn->send_later("D$call|$_");
 436                                 dbg("-> D $call $_") if isdbg('chan');
 437                         }
 438                 }
 439         }
 440         $self->{t} = $main::systime;
 441 }
 442
 443 # send a file (always later)
 444 sub send_file
 445 {
 446         my ($self, $fn) = @_;
 447         my $call = $self->{call};
 448         my $conn = $self->{conn};
 449         my @buf;
 450
 451         open(F, $fn) or die "can't open $fn for sending file ($!)";
 452         @buf = <F>;
 453         close(F);
 454         $self->send(@buf);
 455 }
 456
 457 # this will implement language independence (in time)
 458 sub msg
 459 {
 460         my $self = shift;
 461         return DXM::msg($self->{lang}, @_);
 462 }
 463
 464 # stick a broadcast on the delayed queue (but only up to 20 items)
 465 sub delay
 466 {
 467         my $self = shift;
 468         my $s = shift;
 469
 470         $self->{delayed} = [] unless $self->{delayed};
 471         push @{$self->{delayed}}, $s;
 472         if (@{$self->{delayed}} >= 20) {
 473                 shift @{$self->{delayed}};   # lose oldest one
 474         }
 475 }
 476
 477 # change the state of the channel - lots of scope for debugging here :-)
 478 sub state
 479 {
 480         my $self = shift;
 481         if (@_) {
 482                 $self->{oldstate} = $self->{state};
 483                 $self->{state} = shift;
 484                 $self->{func} = '' unless defined $self->{func};
 485                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 486
 487                 # if there is any queued up broadcasts then splurge them out here
 488                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 489                         $self->send (@{$self->{delayed}});
 490                         delete $self->{delayed};
 491                 }
 492         }
 493         return $self->{state};
 494 }
 495
 496 # disconnect this channel
 497 sub disconnect
 498 {
 499         my $self = shift;
 500         my $user = $self->{user};
 501
 502         $user->close() if defined $user;
 503         $self->{conn}->disconnect if $self->{conn};
 504         $self->del();
 505 }
 506
 507 #
 508 # just close all the socket connections down without any fiddling about, cleaning, being
 509 # nice to other processes and otherwise telling them what is going on.
 510 #
 511 # This is for the benefit of forked processes to prepare for starting new programs, they
 512 # don't want or need all this baggage.
 513 #
 514
 515 sub closeall
 516 {
 517         my $ref;
 518         foreach $ref (values %channels) {
 519                 $ref->{conn}->disconnect() if $ref->{conn};
 520         }
 521 }
 522
 523 #
 524 # Tell all the users that we have come in or out (if they want to know)
 525 #
 526 sub tell_login
 527 {
 528         my ($self, $m, $call) = @_;
 529
 530         $call ||= $self->{call};
 531
 532         # send info to all logged in thingies
 533         my @dxchan = get_all_users();
 534         my $dxchan;
 535         foreach $dxchan (@dxchan) {
 536                 next if $dxchan == $self;
 537                 next if $dxchan->{call} eq $main::mycall;
 538                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 539         }
 540 }
 541
 542 #
 543 # Tell all the users if a buddy is logged or out
 544 #
 545 sub tell_buddies
 546 {
 547         my ($self, $m, $call, $node) = @_;
 548
 549         $call ||= $self->{call};
 550         $call =~ s/-\d+$//;
 551         $m .= 'n' if $node;
 552
 553         # send info to all logged in thingies
 554         my @dxchan = get_all_users();
 555         my $dxchan;
 556         foreach $dxchan (@dxchan) {
 557                 next if $dxchan == $self;
 558                 next if $dxchan->{call} eq $main::mycall;
 559                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 560         }
 561 }
 562
 563 # various access routines
 564
 565 #
 566 # return a list of valid elements
 567 #
 568
 569 sub fields
 570 {
 571         return keys(%valid);
 572 }
 573
 574 #
 575 # return a prompt for a field
 576 #
 577
 578 sub field_prompt
 579 {
 580         my ($self, $ele) = @_;
 581         return $valid{$ele};
 582 }
 583
 584 # take a standard input message and decode it into its standard parts
 585 sub decode_input
 586 {
 587         my $dxchan = shift;
 588         my $data = shift;
 589         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 590
 591         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 592
 593         # the above regexp must work
 594         unless (defined $sort && defined $call && defined $line) {
 595 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 596                 dbg("DUFF Line on $chcall: $data");
 597                 return ();
 598         }
 599
 600         if(ref($dxchan) && $call ne $chcall) {
 601                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 602                 return();
 603         }
 604
 605         return ($sort, $call, $line);
 606 }
 607
 608 # broadcast a message to all clusters taking into account isolation
 609 # [except those mentioned after buffer]
 610 sub broadcast_nodes
 611 {
 612         my $s = shift;                          # the line to be rebroadcast
 613         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 614         my @dxchan = get_all_nodes();
 615         my $dxchan;
 616
 617         # send it if it isn't the except list and isn't isolated and still has a hop count
 618         foreach $dxchan (@dxchan) {
 619                 next if grep $dxchan == $_, @except;
 620                 next if $dxchan == $main::me;
 621
 622                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 623
 624                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 625         }
 626 }
 627
 628 # broadcast a message to all clusters ignoring isolation
 629 # [except those mentioned after buffer]
 630 sub broadcast_all_nodes
 631 {
 632         my $s = shift;                          # the line to be rebroadcast
 633         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 634         my @dxchan = get_all_nodes();
 635         my $dxchan;
 636
 637         # send it if it isn't the except list and isn't isolated and still has a hop count
 638         foreach $dxchan (@dxchan) {
 639                 next if grep $dxchan == $_, @except;
 640                 next if $dxchan == $main::me;
 641
 642                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 643                 $dxchan->send($routeit);
 644         }
 645 }
 646
 647 # broadcast to all users
 648 # storing the spot or whatever until it is in a state to receive it
 649 sub broadcast_users
 650 {
 651         my $s = shift;                          # the line to be rebroadcast
 652         my $sort = shift;           # the type of transmission
 653         my $fref = shift;           # a reference to an object to filter on
 654         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 655         my @dxchan = get_all_users();
 656         my $dxchan;
 657         my @out;
 658
 659         foreach $dxchan (@dxchan) {
 660                 next if grep $dxchan == $_, @except;
 661                 push @out, $dxchan;
 662         }
 663         broadcast_list($s, $sort, $fref, @out);
 664 }
 665
 666
 667 # broadcast to a list of users
 668 sub broadcast_list
 669 {
 670         my $s = shift;
 671         my $sort = shift;
 672         my $fref = shift;
 673         my $dxchan;
 674
 675         foreach $dxchan (@_) {
 676                 my $filter = 1;
 677                 next if $dxchan == $main::me;
 678
 679                 if ($sort eq 'dx') {
 680                     next unless $dxchan->{dx};
 681                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 682                         next unless $filter;
 683                 }
 684                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 685                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 686                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 687                 next if $sort eq 'wx' && !$dxchan->{wx};
 688
 689                 $s =~ s/\a//og unless $dxchan->{beep};
 690
 691                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 692                         $dxchan->send($s);
 693                 } else {
 694                         $dxchan->delay($s);
 695                 }
 696         }
 697 }
 698
 699 sub process
 700 {
 701         foreach my $dxchan (get_all()) {
 702
 703                 while (my $data = shift @{$dxchan->{inqueue}}) {
 704                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 705                         next unless defined $sort;
 706
 707                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 708                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 709                         if ($dxchan->{disconnecting}) {
 710                                 dbg('In disconnection, ignored');
 711                                 next;
 712                         }
 713
 714                         # handle A records
 715                         my $user = $dxchan->user;
 716                         if ($sort eq 'A' || $sort eq 'O') {
 717                                 $dxchan->start($line, $sort);
 718                         } elsif ($sort eq 'I') {
 719                                 die "\$user not defined for $call" if !defined $user;
 720
 721                                 # normal input
 722                                 $dxchan->normal($line);
 723                         } elsif ($sort eq 'Z') {
 724                                 $dxchan->disconnect;
 725                         } elsif ($sort eq 'D') {
 726                                 ;                               # ignored (an echo)
 727                         } elsif ($sort eq 'G') {
 728                                 $dxchan->enhanced($line);
 729                         } else {
 730                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 731                         }
 732                 }
 733         }
 734 }
 735
 736 sub handle_xml
 737 {
 738         my $self = shift;
 739         my $r = 0;
 740
 741         if (DXXml::available()) {
 742                 $r = $self->{handle_xml} || 0;
 743         } else {
 744                 delete $self->{handle_xml} if exists $self->{handle_xml};
 745         }
 746         return $r;
 747 }
 748
 749 #no strict;
 750 sub AUTOLOAD
 751 {
 752         no strict;
 753         my $name = $AUTOLOAD;
 754         return if $name =~ /::DESTROY$/;
 755         $name =~ s/^.*:://o;
 756
 757         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 758
 759         # this clever line of code creates a subroutine which takes over from autoload
 760         # from OO Perl - Conway
 761         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 762         goto &$AUTOLOAD;
 763 }
 764
 765
 766 1;
 767 __END__;