perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Carp;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '9,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '9,Connection Type',
  52                   'sort' => '9,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   wx => '0,Want WX,yesno',
  55                   talk => '0,Want Talk,yesno',
  56                   ann => '0,Want Announce,yesno',
  57                   here => '0,Here?,yesno',
  58                   confmode => '0,In Conference?,yesno',
  59                   dx => '0,DX Spots,yesno',
  60                   redirect => '0,Redirect messages to',
  61                   lang => '0,Language',
  62                   func => '9,Function',
  63                   loc => '9,Local Vars', # used by func to store local variables in
  64                   beep => '0,Want Beeps,yesno',
  65                   lastread => '9,Last Msg Read',
  66                   outbound => '9,outbound?,yesno',
  67                   remotecmd => '9,doing rcmd,yesno',
  68                   pagelth => '0,Page Length',
  69                   pagedata => '9,Page Data Store',
  70                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  71                   isolate => '9,Isolate network,yesno',
  72                   delayed => '9,Delayed messages,parray',
  73                   annfilter => '9,Announce Filter',
  74                   wwvfilter => '9,WWV Filter',
  75                   spotfilter => '9,Spot Filter',
  76                   passwd => '9,Passwd List,parray',
  77                  );
  78
  79 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
  80 sub alloc
  81 {
  82         my ($pkg, $call, $conn, $user) = @_;
  83         my $self = {};
  84
  85         die "trying to create a duplicate channel for $call" if $channels{$call};
  86         $self->{call} = $call;
  87         $self->{priv} = 0;
  88         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
  89         if (defined $user) {
  90                 $self->{user} = $user;
  91                 $self->{lang} = $user->lang;
  92                 $user->new_group() if !$user->group;
  93                 $self->{group} = $user->group;
  94         }
  95         $self->{startt} = $self->{t} = time;
  96         $self->{state} = 0;
  97         $self->{oldstate} = 0;
  98         $self->{lang} = $main::lang if !$self->{lang};
  99         $self->{func} = "";
 100         bless $self, $pkg;
 101         return $channels{$call} = $self;
 102 }
 103
 104 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 105 sub get
 106 {
 107         my ($pkg, $call) = @_;
 108         return $channels{$call};
 109 }
 110
 111 # obtain all the channel objects
 112 sub get_all
 113 {
 114         my ($pkg) = @_;
 115         return values(%channels);
 116 }
 117
 118 # obtain a channel object by searching for its connection reference
 119 sub get_by_cnum
 120 {
 121         my ($pkg, $conn) = @_;
 122         my $self;
 123
 124         foreach $self (values(%channels)) {
 125                 return $self if ($self->{conn} == $conn);
 126         }
 127         return undef;
 128 }
 129
 130 # get rid of a channel object [$obj->del()]
 131 sub del
 132 {
 133         my $self = shift;
 134
 135         $self->{group} = undef;         # belt and braces
 136         delete $channels{$self->{call}};
 137 }
 138
 139 # is it an ak1a cluster ?
 140 sub is_ak1a
 141 {
 142         my $self = shift;
 143         return $self->{'sort'} eq 'A';
 144 }
 145
 146 # is it a user?
 147 sub is_user
 148 {
 149         my $self = shift;
 150         return $self->{'sort'} eq 'U';
 151 }
 152
 153 # is it a connect type
 154 sub is_connect
 155 {
 156         my $self = shift;
 157         return $self->{'sort'} eq 'C';
 158 }
 159
 160 # handle out going messages, immediately without waiting for the select to drop
 161 # this could, in theory, block
 162 sub send_now
 163 {
 164         my $self = shift;
 165         my $conn = $self->{conn};
 166         my $sort = shift;
 167         my $call = $self->{call};
 168
 169         for (@_) {
 170                 chomp;
 171                 $conn->send_now("$sort$call|$_") if $conn;
 172                 dbg('chan', "-> $sort $call $_") if $conn;
 173         }
 174         $self->{t} = time;
 175 }
 176
 177 #
 178 # the normal output routine
 179 #
 180 sub send                                                # this is always later and always data
 181 {
 182         my $self = shift;
 183         my $conn = $self->{conn};
 184         my $call = $self->{call};
 185
 186         for (@_) {
 187                 chomp;
 188                 $conn->send_later("D$call|$_") if $conn;
 189                 dbg('chan', "-> D $call $_") if $conn;
 190         }
 191         $self->{t} = time;
 192 }
 193
 194 # send a file (always later)
 195 sub send_file
 196 {
 197         my ($self, $fn) = @_;
 198         my $call = $self->{call};
 199         my $conn = $self->{conn};
 200         my @buf;
 201
 202         open(F, $fn) or die "can't open $fn for sending file ($!)";
 203         @buf = <F>;
 204         close(F);
 205         $self->send(@buf);
 206 }
 207
 208 # this will implement language independence (in time)
 209 sub msg
 210 {
 211         my $self = shift;
 212         return DXM::msg($self->{lang}, @_);
 213 }
 214
 215 # stick a broadcast on the delayed queue (but only up to 20 items)
 216 sub delay
 217 {
 218         my $self = shift;
 219         my $s = shift;
 220
 221         $self->{delayed} = [] unless $self->{delayed};
 222         push @{$self->{delayed}}, $s;
 223         if (@{$self->{delayed}} >= 20) {
 224                 shift @{$self->{delayed}};   # lose oldest one
 225         }
 226 }
 227
 228 # change the state of the channel - lots of scope for debugging here :-)
 229 sub state
 230 {
 231         my $self = shift;
 232         if (@_) {
 233                 $self->{oldstate} = $self->{state};
 234                 $self->{state} = shift;
 235                 $self->{func} = '' unless defined $self->{func};
 236                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 237
 238                 # if there is any queued up broadcasts then splurge them out here
 239                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 240                         $self->send (@{$self->{delayed}});
 241                         delete $self->{delayed};
 242                 }
 243         }
 244         return $self->{state};
 245 }
 246
 247 # disconnect this channel
 248 sub disconnect
 249 {
 250         my $self = shift;
 251         my $user = $self->{user};
 252         my $conn = $self->{conn};
 253         my $call = $self->{call};
 254
 255         $self->finish();
 256         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 257         $user->close() if defined $user;
 258         $conn->disconnect() if $conn;
 259         $self->del();
 260 }
 261
 262 #
 263 # just close all the socket connections down without any fiddling about, cleaning, being
 264 # nice to other processes and otherwise telling them what is going on.
 265 #
 266 # This is for the benefit of forked processes to prepare for starting new programs, they
 267 # don't want or need all this baggage.
 268 #
 269
 270 sub closeall
 271 {
 272         my $ref;
 273         foreach $ref (values %channels) {
 274                 $ref->{conn}->disconnect() if $ref->{conn};
 275         }
 276 }
 277
 278 # various access routines
 279
 280 #
 281 # return a list of valid elements
 282 #
 283
 284 sub fields
 285 {
 286         return keys(%valid);
 287 }
 288
 289 #
 290 # return a prompt for a field
 291 #
 292
 293 sub field_prompt
 294 {
 295         my ($self, $ele) = @_;
 296         return $valid{$ele};
 297 }
 298
 299 no strict;
 300 sub AUTOLOAD
 301 {
 302         my $self = shift;
 303         my $name = $AUTOLOAD;
 304         return if $name =~ /::DESTROY$/;
 305         $name =~ s/.*:://o;
 306
 307         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 308         @_ ? $self->{$name} = shift : $self->{$name} ;
 309 }
 310
 311 1;
 312 __END__;