perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   gtk => '5,Using GTK,yesno',
 105                   senddbg => '8,Sending Debug,yesno',
 106                   width => '0,Column Width',
 107                   disconnecting => '9,Disconnecting,yesno',
 108                   ann_talk => '0,Suppress Talk Anns,yesno',
 109                   metric => '1,Route metric',
 110                   badcount => '1,Bad Word Count',
 111                   edit => '7,Edit Function',
 112                   registered => '9,Registered?,yesno',
 113                   prompt => '0,Required Prompt',
 114                   version => '1,Node Version',
 115                   build => '1,Node Build',
 116                   verified => '9,Verified?,yesno',
 117                   newroute => '1,New Style Routing,yesno',
 118                   ve7cc => '0,VE7CC program special,yesno',
 119                   lastmsgpoll => '0,Last Msg Poll,atime',
 120                   inscript => '9,In a script,yesno',
 121                   handle_xml => '9,Handles XML,yesno',
 122                   do_pc92 => '9,Handles PC92,yesno',
 123                   send_pc92 => '9,Send PC92,atime',
 124                   inqueue => '9,Input Queue,parray',
 125                  );
 126
 127 use vars qw($VERSION $BRANCH);
 128 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 129 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 130 $main::build += $VERSION;
 131 $main::branch += $BRANCH;
 132
 133 # object destruction
 134 sub DESTROY
 135 {
 136         my $self = shift;
 137         for (keys %$self) {
 138                 if (ref($self->{$_})) {
 139                         delete $self->{$_};
 140                 }
 141         }
 142         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 143         $count--;
 144 }
 145
 146 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 147 sub alloc
 148 {
 149         my ($pkg, $call, $conn, $user) = @_;
 150         my $self = {};
 151
 152         die "trying to create a duplicate channel for $call" if $channels{$call};
 153         $self->{call} = $call;
 154         $self->{priv} = 0;
 155         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 156         if (defined $user) {
 157                 $self->{user} = $user;
 158                 $self->{lang} = $user->lang;
 159                 $user->new_group unless $user->group;
 160                 $user->new_buddies unless $user->buddies;
 161                 $self->{group} = $user->group;
 162                 $self->{sort} = $user->sort;
 163         }
 164         $self->{startt} = $self->{t} = time;
 165         $self->{state} = 0;
 166         $self->{oldstate} = 0;
 167         $self->{lang} = $main::lang if !$self->{lang};
 168         $self->{func} = "";
 169
 170         # add in all the dxcc, itu, zone info
 171         my @dxcc = Prefix::extract($call);
 172         if (@dxcc > 0) {
 173                 $self->{dxcc} = $dxcc[1]->dxcc;
 174                 $self->{itu} = $dxcc[1]->itu;
 175                 $self->{cq} = $dxcc[1]->cq;
 176         }
 177         $self->{inqueue} = [];
 178
 179         $count++;
 180         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 181         bless $self, $pkg;
 182         return $channels{$call} = $self;
 183 }
 184
 185 # rebless this channel as something else
 186 sub rebless
 187 {
 188         my $self = shift;
 189         my $class = shift;
 190         return $channels{$self->{call}} = bless $self, $class;
 191 }
 192
 193 sub rec
 194 {
 195         my ($self, $msg) = @_;
 196
 197         # queue the message and the channel object for later processing
 198         if (defined $msg) {
 199                 push @{$self->{inqueue}}, $msg;
 200         }
 201 }
 202
 203 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 204 sub get
 205 {
 206         my $call = shift;
 207         return $channels{$call};
 208 }
 209
 210 # obtain all the channel objects
 211 sub get_all
 212 {
 213         return values(%channels);
 214 }
 215
 216 #
 217 # gimme all the ak1a nodes
 218 #
 219 sub get_all_nodes
 220 {
 221         my $ref;
 222         my @out;
 223         foreach $ref (values %channels) {
 224                 push @out, $ref if $ref->is_node;
 225         }
 226         return @out;
 227 }
 228
 229 # return a list of all users
 230 sub get_all_users
 231 {
 232         my $ref;
 233         my @out;
 234         foreach $ref (values %channels) {
 235                 push @out, $ref if $ref->is_user;
 236         }
 237         return @out;
 238 }
 239
 240 # return a list of all user callsigns
 241 sub get_all_user_calls
 242 {
 243         my $ref;
 244         my @out;
 245         foreach $ref (values %channels) {
 246                 push @out, $ref->{call} if $ref->is_user;
 247         }
 248         return @out;
 249 }
 250
 251 # obtain a channel object by searching for its connection reference
 252 sub get_by_cnum
 253 {
 254         my ($pkg, $conn) = @_;
 255         my $self;
 256
 257         foreach $self (values(%channels)) {
 258                 return $self if ($self->{conn} == $conn);
 259         }
 260         return undef;
 261 }
 262
 263 # get rid of a channel object [$obj->del()]
 264 sub del
 265 {
 266         my $self = shift;
 267
 268         $self->{group} = undef;         # belt and braces
 269         delete $channels{$self->{call}};
 270 }
 271
 272 # is it a bbs
 273 sub is_bbs
 274 {
 275         my $self = shift;
 276         return $self->{'sort'} eq 'B';
 277 }
 278
 279 sub is_node
 280 {
 281         my $self = shift;
 282         return $self->{'sort'} =~ /[ACRSXW]/;
 283 }
 284 # is it an ak1a node ?
 285 sub is_ak1a
 286 {
 287         my $self = shift;
 288         return $self->{'sort'} eq 'A';
 289 }
 290
 291 # is it a user?
 292 sub is_user
 293 {
 294         my $self = shift;
 295         return $self->{'sort'} eq 'U';
 296 }
 297
 298 # is it a clx node
 299 sub is_clx
 300 {
 301         my $self = shift;
 302         return $self->{'sort'} eq 'C';
 303 }
 304
 305 # it is Aranea
 306 sub is_aranea
 307 {
 308         my $self = shift;
 309         return $self->{'sort'} eq 'W';
 310 }
 311
 312 # is it a spider node
 313 sub is_spider
 314 {
 315         my $self = shift;
 316         return $self->{'sort'} eq 'S';
 317 }
 318
 319 # is it a DXNet node
 320 sub is_dxnet
 321 {
 322         my $self = shift;
 323         return $self->{'sort'} eq 'X';
 324 }
 325
 326 # is it a ar-cluster node
 327 sub is_arcluster
 328 {
 329         my $self = shift;
 330         return $self->{'sort'} eq 'R';
 331 }
 332
 333 # for perl 5.004's benefit
 334 sub sort
 335 {
 336         my $self = shift;
 337         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 338 }
 339
 340 # find out whether we are prepared to believe this callsign on this interface
 341 sub is_believed
 342 {
 343         my $self = shift;
 344         my $call = shift;
 345
 346         return grep $call eq $_, $self->user->believe;
 347 }
 348
 349 # handle out going messages, immediately without waiting for the select to drop
 350 # this could, in theory, block
 351 sub send_now
 352 {
 353         my $self = shift;
 354         my $conn = $self->{conn};
 355         return unless $conn;
 356         my $sort = shift;
 357         my $call = $self->{call};
 358
 359         for (@_) {
 360 #               chomp;
 361         my @lines = split /\n/;
 362                 for (@lines) {
 363                         $conn->send_now("$sort$call|$_");
 364                         # debug log it, but not if it is a log message
 365                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 366                 }
 367         }
 368         $self->{t} = time;
 369 }
 370
 371 #
 372 # send later with letter (more control)
 373 #
 374
 375 sub send_later
 376 {
 377         my $self = shift;
 378         my $conn = $self->{conn};
 379         return unless $conn;
 380         my $sort = shift;
 381         my $call = $self->{call};
 382
 383         for (@_) {
 384 #               chomp;
 385         my @lines = split /\n/;
 386                 for (@lines) {
 387                         $conn->send_later("$sort$call|$_");
 388                         # debug log it, but not if it is a log message
 389                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 390                 }
 391         }
 392         $self->{t} = time;
 393 }
 394
 395 #
 396 # the normal output routine
 397 #
 398 sub send                                                # this is always later and always data
 399 {
 400         my $self = shift;
 401         my $conn = $self->{conn};
 402         return unless $conn;
 403         my $call = $self->{call};
 404
 405         foreach my $l (@_) {
 406                 for (ref $l ? @$l : $l) {
 407                         my @lines = split /\n/;
 408                         for (@lines) {
 409                                 $conn->send_later("D$call|$_");
 410                                 dbg("-> D $call $_") if isdbg('chan');
 411                         }
 412                 }
 413         }
 414         $self->{t} = $main::systime;
 415 }
 416
 417 # send a file (always later)
 418 sub send_file
 419 {
 420         my ($self, $fn) = @_;
 421         my $call = $self->{call};
 422         my $conn = $self->{conn};
 423         my @buf;
 424
 425         open(F, $fn) or die "can't open $fn for sending file ($!)";
 426         @buf = <F>;
 427         close(F);
 428         $self->send(@buf);
 429 }
 430
 431 # this will implement language independence (in time)
 432 sub msg
 433 {
 434         my $self = shift;
 435         return DXM::msg($self->{lang}, @_);
 436 }
 437
 438 # stick a broadcast on the delayed queue (but only up to 20 items)
 439 sub delay
 440 {
 441         my $self = shift;
 442         my $s = shift;
 443
 444         $self->{delayed} = [] unless $self->{delayed};
 445         push @{$self->{delayed}}, $s;
 446         if (@{$self->{delayed}} >= 20) {
 447                 shift @{$self->{delayed}};   # lose oldest one
 448         }
 449 }
 450
 451 # change the state of the channel - lots of scope for debugging here :-)
 452 sub state
 453 {
 454         my $self = shift;
 455         if (@_) {
 456                 $self->{oldstate} = $self->{state};
 457                 $self->{state} = shift;
 458                 $self->{func} = '' unless defined $self->{func};
 459                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 460
 461                 # if there is any queued up broadcasts then splurge them out here
 462                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 463                         $self->send (@{$self->{delayed}});
 464                         delete $self->{delayed};
 465                 }
 466         }
 467         return $self->{state};
 468 }
 469
 470 # disconnect this channel
 471 sub disconnect
 472 {
 473         my $self = shift;
 474         my $user = $self->{user};
 475
 476         $user->close() if defined $user;
 477         $self->{conn}->disconnect;
 478         $self->del();
 479 }
 480
 481 #
 482 # just close all the socket connections down without any fiddling about, cleaning, being
 483 # nice to other processes and otherwise telling them what is going on.
 484 #
 485 # This is for the benefit of forked processes to prepare for starting new programs, they
 486 # don't want or need all this baggage.
 487 #
 488
 489 sub closeall
 490 {
 491         my $ref;
 492         foreach $ref (values %channels) {
 493                 $ref->{conn}->disconnect() if $ref->{conn};
 494         }
 495 }
 496
 497 #
 498 # Tell all the users that we have come in or out (if they want to know)
 499 #
 500 sub tell_login
 501 {
 502         my ($self, $m, $call) = @_;
 503
 504         $call ||= $self->{call};
 505
 506         # send info to all logged in thingies
 507         my @dxchan = get_all_users();
 508         my $dxchan;
 509         foreach $dxchan (@dxchan) {
 510                 next if $dxchan == $self;
 511                 next if $dxchan->{call} eq $main::mycall;
 512                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 513         }
 514 }
 515
 516 #
 517 # Tell all the users if a buddy is logged or out
 518 #
 519 sub tell_buddies
 520 {
 521         my ($self, $m, $call, $node) = @_;
 522
 523         $call ||= $self->{call};
 524         $call =~ s/-\d+$//;
 525         $m .= 'n' if $node;
 526
 527         # send info to all logged in thingies
 528         my @dxchan = get_all_users();
 529         my $dxchan;
 530         foreach $dxchan (@dxchan) {
 531                 next if $dxchan == $self;
 532                 next if $dxchan->{call} eq $main::mycall;
 533                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 534         }
 535 }
 536
 537 # various access routines
 538
 539 #
 540 # return a list of valid elements
 541 #
 542
 543 sub fields
 544 {
 545         return keys(%valid);
 546 }
 547
 548 #
 549 # return a prompt for a field
 550 #
 551
 552 sub field_prompt
 553 {
 554         my ($self, $ele) = @_;
 555         return $valid{$ele};
 556 }
 557
 558 # take a standard input message and decode it into its standard parts
 559 sub decode_input
 560 {
 561         my $dxchan = shift;
 562         my $data = shift;
 563         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 564
 565         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 566
 567         # the above regexp must work
 568         unless (defined $sort && defined $call && defined $line) {
 569 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 570                 dbg("DUFF Line on $chcall: $data");
 571                 return ();
 572         }
 573
 574         if(ref($dxchan) && $call ne $chcall) {
 575                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 576                 return();
 577         }
 578
 579         return ($sort, $call, $line);
 580 }
 581
 582 sub rspfcheck
 583 {
 584         my ($self, $flag, $node, $user) = @_;
 585         my $nref = Route::Node::get($node);
 586         my $dxchan = $nref->dxchan if $nref;
 587         if ($nref && $dxchan) {
 588             if ($dxchan == $self) {
 589                         return 1 unless $user;
 590                         return 1 if $user eq $node;
 591                         my @users = $nref->users;
 592                         return 1 if @users == 0 || grep $user eq $_, @users;
 593                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 594                 } else {
 595                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 596                 }
 597         } else {
 598                 return 1 if $flag;
 599                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 600         }
 601         return 0;
 602 }
 603
 604 # broadcast a message to all clusters taking into account isolation
 605 # [except those mentioned after buffer]
 606 sub broadcast_nodes
 607 {
 608         my $s = shift;                          # the line to be rebroadcast
 609         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 610         my @dxchan = get_all_nodes();
 611         my $dxchan;
 612
 613         # send it if it isn't the except list and isn't isolated and still has a hop count
 614         foreach $dxchan (@dxchan) {
 615                 next if grep $dxchan == $_, @except;
 616                 next if $dxchan == $main::me;
 617
 618                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 619
 620                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 621         }
 622 }
 623
 624 # broadcast a message to all clusters ignoring isolation
 625 # [except those mentioned after buffer]
 626 sub broadcast_all_nodes
 627 {
 628         my $s = shift;                          # the line to be rebroadcast
 629         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 630         my @dxchan = get_all_nodes();
 631         my $dxchan;
 632
 633         # send it if it isn't the except list and isn't isolated and still has a hop count
 634         foreach $dxchan (@dxchan) {
 635                 next if grep $dxchan == $_, @except;
 636                 next if $dxchan == $main::me;
 637
 638                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 639                 $dxchan->send($routeit);
 640         }
 641 }
 642
 643 # broadcast to all users
 644 # storing the spot or whatever until it is in a state to receive it
 645 sub broadcast_users
 646 {
 647         my $s = shift;                          # the line to be rebroadcast
 648         my $sort = shift;           # the type of transmission
 649         my $fref = shift;           # a reference to an object to filter on
 650         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 651         my @dxchan = get_all_users();
 652         my $dxchan;
 653         my @out;
 654
 655         foreach $dxchan (@dxchan) {
 656                 next if grep $dxchan == $_, @except;
 657                 push @out, $dxchan;
 658         }
 659         broadcast_list($s, $sort, $fref, @out);
 660 }
 661
 662
 663 # broadcast to a list of users
 664 sub broadcast_list
 665 {
 666         my $s = shift;
 667         my $sort = shift;
 668         my $fref = shift;
 669         my $dxchan;
 670
 671         foreach $dxchan (@_) {
 672                 my $filter = 1;
 673                 next if $dxchan == $main::me;
 674
 675                 if ($sort eq 'dx') {
 676                     next unless $dxchan->{dx};
 677                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 678                         next unless $filter;
 679                 }
 680                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 681                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 682                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 683                 next if $sort eq 'wx' && !$dxchan->{wx};
 684
 685                 $s =~ s/\a//og unless $dxchan->{beep};
 686
 687                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 688                         $dxchan->send($s);
 689                 } else {
 690                         $dxchan->delay($s);
 691                 }
 692         }
 693 }
 694
 695 sub process
 696 {
 697         foreach my $dxchan (get_all()) {
 698
 699                 while (my $data = shift @{$dxchan->{inqueue}}) {
 700                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 701                         next unless defined $sort;
 702
 703                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 704                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 705                         if ($dxchan->{disconnecting}) {
 706                                 dbg('In disconnection, ignored');
 707                                 next;
 708                         }
 709
 710                         # handle A records
 711                         my $user = $dxchan->user;
 712                         if ($sort eq 'A' || $sort eq 'O') {
 713                                 $dxchan->start($line, $sort);
 714                         } elsif ($sort eq 'I') {
 715                                 die "\$user not defined for $call" if !defined $user;
 716
 717                                 # normal input
 718                                 $dxchan->normal($line);
 719                         } elsif ($sort eq 'Z') {
 720                                 $dxchan->disconnect;
 721                         } elsif ($sort eq 'D') {
 722                                 ;                               # ignored (an echo)
 723                         } elsif ($sort eq 'G') {
 724                                 $dxchan->enhanced($line);
 725                         } else {
 726                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 727                         }
 728                 }
 729         }
 730 }
 731
 732 sub handle_xml
 733 {
 734         my $self = shift;
 735         my $r = 0;
 736
 737         if (DXXml::available()) {
 738                 $r = $self->{handle_xml} || 0;
 739         } else {
 740                 delete $self->{handle_xml} if exists $self->{handle_xml};
 741         }
 742         return $r;
 743 }
 744
 745 #no strict;
 746 sub AUTOLOAD
 747 {
 748         no strict;
 749         my $name = $AUTOLOAD;
 750         return if $name =~ /::DESTROY$/;
 751         $name =~ s/^.*:://o;
 752
 753         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 754
 755         # this clever line of code creates a subroutine which takes over from autoload
 756         # from OO Perl - Conway
 757         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 758         goto &$AUTOLOAD;
 759 }
 760
 761
 762 1;
 763 __END__;