perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   senddbg => '8,Sending Debug,yesno',
 105                   width => '0,Column Width',
 106                   disconnecting => '9,Disconnecting,yesno',
 107                   ann_talk => '0,Suppress Talk Anns,yesno',
 108                   metric => '1,Route metric',
 109                   badcount => '1,Bad Word Count',
 110                   edit => '7,Edit Function',
 111                   registered => '9,Registered?,yesno',
 112                   prompt => '0,Required Prompt',
 113                   version => '1,Node Version',
 114                   build => '1,Node Build',
 115                   verified => '9,Verified?,yesno',
 116                   newroute => '1,New Style Routing,yesno',
 117                   ve7cc => '0,VE7CC program special,yesno',
 118                   lastmsgpoll => '0,Last Msg Poll,atime',
 119                   inscript => '9,In a script,yesno',
 120                   handle_xml => '9,Handles XML,yesno',
 121                   inqueue => '9,Input Queue,parray',
 122                  );
 123
 124 use vars qw($VERSION $BRANCH);
 125 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 126 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 127 $main::build += $VERSION;
 128 $main::branch += $BRANCH;
 129
 130 # object destruction
 131 sub DESTROY
 132 {
 133         my $self = shift;
 134         for (keys %$self) {
 135                 if (ref($self->{$_})) {
 136                         delete $self->{$_};
 137                 }
 138         }
 139         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 140         $count--;
 141 }
 142
 143 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 144 sub alloc
 145 {
 146         my ($pkg, $call, $conn, $user) = @_;
 147         my $self = {};
 148
 149         die "trying to create a duplicate channel for $call" if $channels{$call};
 150         $self->{call} = $call;
 151         $self->{priv} = 0;
 152         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 153         if (defined $user) {
 154                 $self->{user} = $user;
 155                 $self->{lang} = $user->lang;
 156                 $user->new_group() if !$user->group;
 157                 $self->{group} = $user->group;
 158                 $self->{sort} = $user->sort;
 159         }
 160         $self->{startt} = $self->{t} = time;
 161         $self->{state} = 0;
 162         $self->{oldstate} = 0;
 163         $self->{lang} = $main::lang if !$self->{lang};
 164         $self->{func} = "";
 165
 166         # add in all the dxcc, itu, zone info
 167         my @dxcc = Prefix::extract($call);
 168         if (@dxcc > 0) {
 169                 $self->{dxcc} = $dxcc[1]->dxcc;
 170                 $self->{itu} = $dxcc[1]->itu;
 171                 $self->{cq} = $dxcc[1]->cq;
 172         }
 173         $self->{inqueue} = [];
 174
 175         $count++;
 176         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 177         bless $self, $pkg;
 178         return $channels{$call} = $self;
 179 }
 180
 181 sub rec
 182 {
 183         my ($self, $msg) = @_;
 184
 185         # queue the message and the channel object for later processing
 186         if (defined $msg) {
 187                 push @{$self->{inqueue}}, $msg;
 188         }
 189 }
 190
 191 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 192 sub get
 193 {
 194         my $call = shift;
 195         return $channels{$call};
 196 }
 197
 198 # obtain all the channel objects
 199 sub get_all
 200 {
 201         return values(%channels);
 202 }
 203
 204 #
 205 # gimme all the ak1a nodes
 206 #
 207 sub get_all_nodes
 208 {
 209         my $ref;
 210         my @out;
 211         foreach $ref (values %channels) {
 212                 push @out, $ref if $ref->is_node;
 213         }
 214         return @out;
 215 }
 216
 217 # return a list of all users
 218 sub get_all_users
 219 {
 220         my $ref;
 221         my @out;
 222         foreach $ref (values %channels) {
 223                 push @out, $ref if $ref->is_user;
 224         }
 225         return @out;
 226 }
 227
 228 # return a list of all user callsigns
 229 sub get_all_user_calls
 230 {
 231         my $ref;
 232         my @out;
 233         foreach $ref (values %channels) {
 234                 push @out, $ref->{call} if $ref->is_user;
 235         }
 236         return @out;
 237 }
 238
 239 # obtain a channel object by searching for its connection reference
 240 sub get_by_cnum
 241 {
 242         my ($pkg, $conn) = @_;
 243         my $self;
 244
 245         foreach $self (values(%channels)) {
 246                 return $self if ($self->{conn} == $conn);
 247         }
 248         return undef;
 249 }
 250
 251 # get rid of a channel object [$obj->del()]
 252 sub del
 253 {
 254         my $self = shift;
 255
 256         $self->{group} = undef;         # belt and braces
 257         delete $channels{$self->{call}};
 258 }
 259
 260 # is it a bbs
 261 sub is_bbs
 262 {
 263         my $self = shift;
 264         return $self->{'sort'} eq 'B';
 265 }
 266
 267 sub is_node
 268 {
 269         my $self = shift;
 270         return $self->{'sort'} =~ /[ACRSXW]/;
 271 }
 272 # is it an ak1a node ?
 273 sub is_ak1a
 274 {
 275         my $self = shift;
 276         return $self->{'sort'} eq 'A';
 277 }
 278
 279 # is it a user?
 280 sub is_user
 281 {
 282         my $self = shift;
 283         return $self->{'sort'} eq 'U';
 284 }
 285
 286 # is it a clx node
 287 sub is_clx
 288 {
 289         my $self = shift;
 290         return $self->{'sort'} eq 'C';
 291 }
 292
 293 # it is Aranea
 294 sub is_aranea
 295 {
 296         my $self = shift;
 297         return $self->{'sort'} eq 'W';
 298 }
 299
 300 # is it a spider node
 301 sub is_spider
 302 {
 303         my $self = shift;
 304         return $self->{'sort'} eq 'S';
 305 }
 306
 307 # is it a DXNet node
 308 sub is_dxnet
 309 {
 310         my $self = shift;
 311         return $self->{'sort'} eq 'X';
 312 }
 313
 314 # is it a ar-cluster node
 315 sub is_arcluster
 316 {
 317         my $self = shift;
 318         return $self->{'sort'} eq 'R';
 319 }
 320
 321 # for perl 5.004's benefit
 322 sub sort
 323 {
 324         my $self = shift;
 325         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 326 }
 327
 328 # find out whether we are prepared to believe this callsign on this interface
 329 sub is_believed
 330 {
 331         my $self = shift;
 332         my $call = shift;
 333
 334         return grep $call eq $_, $self->user->believe;
 335 }
 336
 337 # handle out going messages, immediately without waiting for the select to drop
 338 # this could, in theory, block
 339 sub send_now
 340 {
 341         my $self = shift;
 342         my $conn = $self->{conn};
 343         return unless $conn;
 344         my $sort = shift;
 345         my $call = $self->{call};
 346
 347         for (@_) {
 348 #               chomp;
 349         my @lines = split /\n/;
 350                 for (@lines) {
 351                         $conn->send_now("$sort$call|$_");
 352                         dbg("-> $sort $call $_") if isdbg('chan');
 353                 }
 354         }
 355         $self->{t} = time;
 356 }
 357
 358 #
 359 # send later with letter (more control)
 360 #
 361
 362 sub send_later
 363 {
 364         my $self = shift;
 365         my $conn = $self->{conn};
 366         return unless $conn;
 367         my $sort = shift;
 368         my $call = $self->{call};
 369
 370         for (@_) {
 371 #               chomp;
 372         my @lines = split /\n/;
 373                 for (@lines) {
 374                         $conn->send_later("$sort$call|$_");
 375                         dbg("-> $sort $call $_") if isdbg('chan');
 376                 }
 377         }
 378         $self->{t} = time;
 379 }
 380
 381 #
 382 # the normal output routine
 383 #
 384 sub send                                                # this is always later and always data
 385 {
 386         my $self = shift;
 387         my $conn = $self->{conn};
 388         return unless $conn;
 389         my $call = $self->{call};
 390
 391         for (@_) {
 392 #               chomp;
 393         my @lines = split /\n/;
 394                 for (@lines) {
 395                         $conn->send_later("D$call|$_");
 396                         dbg("-> D $call $_") if isdbg('chan');
 397                 }
 398         }
 399         $self->{t} = time;
 400 }
 401
 402 # send a file (always later)
 403 sub send_file
 404 {
 405         my ($self, $fn) = @_;
 406         my $call = $self->{call};
 407         my $conn = $self->{conn};
 408         my @buf;
 409
 410         open(F, $fn) or die "can't open $fn for sending file ($!)";
 411         @buf = <F>;
 412         close(F);
 413         $self->send(@buf);
 414 }
 415
 416 # this will implement language independence (in time)
 417 sub msg
 418 {
 419         my $self = shift;
 420         return DXM::msg($self->{lang}, @_);
 421 }
 422
 423 # stick a broadcast on the delayed queue (but only up to 20 items)
 424 sub delay
 425 {
 426         my $self = shift;
 427         my $s = shift;
 428
 429         $self->{delayed} = [] unless $self->{delayed};
 430         push @{$self->{delayed}}, $s;
 431         if (@{$self->{delayed}} >= 20) {
 432                 shift @{$self->{delayed}};   # lose oldest one
 433         }
 434 }
 435
 436 # change the state of the channel - lots of scope for debugging here :-)
 437 sub state
 438 {
 439         my $self = shift;
 440         if (@_) {
 441                 $self->{oldstate} = $self->{state};
 442                 $self->{state} = shift;
 443                 $self->{func} = '' unless defined $self->{func};
 444                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 445
 446                 # if there is any queued up broadcasts then splurge them out here
 447                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 448                         $self->send (@{$self->{delayed}});
 449                         delete $self->{delayed};
 450                 }
 451         }
 452         return $self->{state};
 453 }
 454
 455 # disconnect this channel
 456 sub disconnect
 457 {
 458         my $self = shift;
 459         my $user = $self->{user};
 460
 461         $user->close() if defined $user;
 462         $self->{conn}->disconnect;
 463         $self->del();
 464 }
 465
 466 #
 467 # just close all the socket connections down without any fiddling about, cleaning, being
 468 # nice to other processes and otherwise telling them what is going on.
 469 #
 470 # This is for the benefit of forked processes to prepare for starting new programs, they
 471 # don't want or need all this baggage.
 472 #
 473
 474 sub closeall
 475 {
 476         my $ref;
 477         foreach $ref (values %channels) {
 478                 $ref->{conn}->disconnect() if $ref->{conn};
 479         }
 480 }
 481
 482 #
 483 # Tell all the users that we have come in or out (if they want to know)
 484 #
 485 sub tell_login
 486 {
 487         my ($self, $m) = @_;
 488
 489         # send info to all logged in thingies
 490         my @dxchan = get_all_users();
 491         my $dxchan;
 492         foreach $dxchan (@dxchan) {
 493                 next if $dxchan == $self;
 494                 next if $dxchan->{call} eq $main::mycall;
 495                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 496         }
 497 }
 498
 499 # various access routines
 500
 501 #
 502 # return a list of valid elements
 503 #
 504
 505 sub fields
 506 {
 507         return keys(%valid);
 508 }
 509
 510 #
 511 # return a prompt for a field
 512 #
 513
 514 sub field_prompt
 515 {
 516         my ($self, $ele) = @_;
 517         return $valid{$ele};
 518 }
 519
 520 # take a standard input message and decode it into its standard parts
 521 sub decode_input
 522 {
 523         my $dxchan = shift;
 524         my $data = shift;
 525         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 526
 527         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 528
 529         # the above regexp must work
 530         unless (defined $sort && defined $call && defined $line) {
 531 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 532                 dbg("DUFF Line on $chcall: $data");
 533                 return ();
 534         }
 535
 536         if(ref($dxchan) && $call ne $chcall) {
 537                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 538                 return();
 539         }
 540
 541         return ($sort, $call, $line);
 542 }
 543
 544 sub rspfcheck
 545 {
 546         my ($self, $flag, $node, $user) = @_;
 547         my $nref = Route::Node::get($node);
 548         my $dxchan = $nref->dxchan if $nref;
 549         if ($nref && $dxchan) {
 550             if ($dxchan == $self) {
 551                         return 1 unless $user;
 552                         return 1 if $user eq $node;
 553                         my @users = $nref->users;
 554                         return 1 if @users == 0 || grep $user eq $_, @users;
 555                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 556                 } else {
 557                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 558                 }
 559         } else {
 560                 return 1 if $flag;
 561                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 562         }
 563         return 0;
 564 }
 565
 566 # broadcast a message to all clusters taking into account isolation
 567 # [except those mentioned after buffer]
 568 sub broadcast_nodes
 569 {
 570         my $s = shift;                          # the line to be rebroadcast
 571         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 572         my @dxchan = get_all_nodes();
 573         my $dxchan;
 574
 575         # send it if it isn't the except list and isn't isolated and still has a hop count
 576         foreach $dxchan (@dxchan) {
 577                 next if grep $dxchan == $_, @except;
 578                 next if $dxchan == $main::me;
 579
 580                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 581
 582                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 583         }
 584 }
 585
 586 # broadcast a message to all clusters ignoring isolation
 587 # [except those mentioned after buffer]
 588 sub broadcast_all_nodes
 589 {
 590         my $s = shift;                          # the line to be rebroadcast
 591         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 592         my @dxchan = get_all_nodes();
 593         my $dxchan;
 594
 595         # send it if it isn't the except list and isn't isolated and still has a hop count
 596         foreach $dxchan (@dxchan) {
 597                 next if grep $dxchan == $_, @except;
 598                 next if $dxchan == $main::me;
 599
 600                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 601                 $dxchan->send($routeit);
 602         }
 603 }
 604
 605 # broadcast to all users
 606 # storing the spot or whatever until it is in a state to receive it
 607 sub broadcast_users
 608 {
 609         my $s = shift;                          # the line to be rebroadcast
 610         my $sort = shift;           # the type of transmission
 611         my $fref = shift;           # a reference to an object to filter on
 612         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 613         my @dxchan = get_all_users();
 614         my $dxchan;
 615         my @out;
 616
 617         foreach $dxchan (@dxchan) {
 618                 next if grep $dxchan == $_, @except;
 619                 push @out, $dxchan;
 620         }
 621         broadcast_list($s, $sort, $fref, @out);
 622 }
 623
 624
 625 # broadcast to a list of users
 626 sub broadcast_list
 627 {
 628         my $s = shift;
 629         my $sort = shift;
 630         my $fref = shift;
 631         my $dxchan;
 632
 633         foreach $dxchan (@_) {
 634                 my $filter = 1;
 635                 next if $dxchan == $main::me;
 636
 637                 if ($sort eq 'dx') {
 638                     next unless $dxchan->{dx};
 639                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 640                         next unless $filter;
 641                 }
 642                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 643                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 644                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 645                 next if $sort eq 'wx' && !$dxchan->{wx};
 646
 647                 $s =~ s/\a//og unless $dxchan->{beep};
 648
 649                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 650                         $dxchan->send($s);
 651                 } else {
 652                         $dxchan->delay($s);
 653                 }
 654         }
 655 }
 656
 657 sub process
 658 {
 659         foreach my $dxchan (get_all()) {
 660
 661                 while (my $data = shift @{$dxchan->{inqueue}}) {
 662                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 663                         next unless defined $sort;
 664
 665                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 666                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 667                         if ($dxchan->{disconnecting}) {
 668                                 dbg('In disconnection, ignored');
 669                                 next;
 670                         }
 671
 672                         # handle A records
 673                         my $user = $dxchan->user;
 674                         if ($sort eq 'A' || $sort eq 'O') {
 675                                 $dxchan->start($line, $sort);
 676                         } elsif ($sort eq 'I') {
 677                                 die "\$user not defined for $call" if !defined $user;
 678
 679                                 # normal input
 680                                 $dxchan->normal($line);
 681                         } elsif ($sort eq 'Z') {
 682                                 $dxchan->disconnect;
 683                         } elsif ($sort eq 'D') {
 684                                 ;                               # ignored (an echo)
 685                         } elsif ($sort eq 'G') {
 686                                 $dxchan->enhanced($line);
 687                         } else {
 688                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 689                         }
 690                 }
 691         }
 692 }
 693
 694 #no strict;
 695 sub AUTOLOAD
 696 {
 697         no strict;
 698         my $name = $AUTOLOAD;
 699         return if $name =~ /::DESTROY$/;
 700         $name =~ s/^.*:://o;
 701
 702         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 703
 704         # this clever line of code creates a subroutine which takes over from autoload
 705         # from OO Perl - Conway
 706         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 707         goto &$AUTOLOAD;
 708 }
 709
 710
 711 1;
 712 __END__;