perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33 use Carp;
  34
  35 use strict;
  36 use vars qw(%channels %valid);
  37
  38 %channels = ();
  39
  40 %valid = (
  41                   call => '0,Callsign',
  42                   conn => '9,Msg Conn ref',
  43                   user => '9,DXUser ref',
  44                   startt => '0,Start Time,atime',
  45                   t => '9,Time,atime',
  46                   pc50_t => '5,Last PC50 Time,atime',
  47                   priv => '9,Privilege',
  48                   state => '0,Current State',
  49                   oldstate => '5,Last State',
  50                   list => '9,Dep Chan List',
  51                   name => '0,User Name',
  52                   consort => '5,Connection Type',
  53                   'sort' => '5,Type of Channel',
  54                   wwv => '0,Want WWV,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   spotfilter => '5,Spot Filter',
  77                   inannfilter => '5,Input Ann Filter',
  78                   inwwvfilter => '5,Input WWV Filter',
  79                   inspotfilter => '5,Input Spot Filter',
  80                   passwd => '9,Passwd List,parray',
  81                   pingint => '9,Ping Interval ',
  82                   nopings => '9,Ping Obs Count',
  83                   lastping => '9,Ping last sent,atime',
  84                   pingtime => '9,Ping totaltime,parray',
  85                   pingave => '0,Ping ave time',
  86                  );
  87
  88 # object destruction
  89 sub DESTROY
  90 {
  91         my $self = shift;
  92         undef $self->{user};
  93         undef $self->{conn};
  94         undef $self->{loc};
  95         undef $self->{pagedata};
  96         undef $self->{group};
  97         undef $self->{delayed};
  98         undef $self->{annfilter};
  99         undef $self->{wwvfilter};
 100         undef $self->{spotfilter};
 101         undef $self->{inannfilter};
 102         undef $self->{inwwvfilter};
 103         undef $self->{inspotfilter};
 104         undef $self->{passwd};
 105 }
 106
 107 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 108 sub alloc
 109 {
 110         my ($pkg, $call, $conn, $user) = @_;
 111         my $self = {};
 112
 113         die "trying to create a duplicate channel for $call" if $channels{$call};
 114         $self->{call} = $call;
 115         $self->{priv} = 0;
 116         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 117         if (defined $user) {
 118                 $self->{user} = $user;
 119                 $self->{lang} = $user->lang;
 120                 $user->new_group() if !$user->group;
 121                 $self->{group} = $user->group;
 122         }
 123         $self->{startt} = $self->{t} = time;
 124         $self->{state} = 0;
 125         $self->{oldstate} = 0;
 126         $self->{lang} = $main::lang if !$self->{lang};
 127         $self->{func} = "";
 128
 129         # get the filters
 130         $self->{spotfilter} = Filter::read_in('spots', $call, 0);
 131         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0);
 132         $self->{annfilter} = Filter::read_in('ann', $call, 0);
 133
 134         bless $self, $pkg;
 135         return $channels{$call} = $self;
 136 }
 137
 138 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 139 sub get
 140 {
 141         my ($pkg, $call) = @_;
 142         return $channels{$call};
 143 }
 144
 145 # obtain all the channel objects
 146 sub get_all
 147 {
 148         my ($pkg) = @_;
 149         return values(%channels);
 150 }
 151
 152 # obtain a channel object by searching for its connection reference
 153 sub get_by_cnum
 154 {
 155         my ($pkg, $conn) = @_;
 156         my $self;
 157
 158         foreach $self (values(%channels)) {
 159                 return $self if ($self->{conn} == $conn);
 160         }
 161         return undef;
 162 }
 163
 164 # get rid of a channel object [$obj->del()]
 165 sub del
 166 {
 167         my $self = shift;
 168
 169         $self->{group} = undef;         # belt and braces
 170         delete $channels{$self->{call}};
 171 }
 172
 173 # is it a bbs
 174 sub is_bbs
 175 {
 176         my $self = shift;
 177         return $self->{'sort'} eq 'B';
 178 }
 179
 180 # is it an ak1a cluster ?
 181 sub is_ak1a
 182 {
 183         my $self = shift;
 184         return $self->{'sort'} eq 'A';
 185 }
 186
 187 # is it a user?
 188 sub is_user
 189 {
 190         my $self = shift;
 191         return $self->{'sort'} eq 'U';
 192 }
 193
 194 # is it a connect type
 195 sub is_connect
 196 {
 197         my $self = shift;
 198         return $self->{'sort'} eq 'C';
 199 }
 200
 201 # for perl 5.004's benefit
 202 sub sort
 203 {
 204         my $self = shift;
 205         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 206 }
 207
 208 # handle out going messages, immediately without waiting for the select to drop
 209 # this could, in theory, block
 210 sub send_now
 211 {
 212         my $self = shift;
 213         my $conn = $self->{conn};
 214         return unless $conn;
 215         my $sort = shift;
 216         my $call = $self->{call};
 217
 218         for (@_) {
 219                 chomp;
 220         my @lines = split /\n/;
 221                 for (@lines) {
 222                         $conn->send_now("$sort$call|$_");
 223                         dbg('chan', "-> $sort $call $_");
 224                 }
 225         }
 226         $self->{t} = time;
 227 }
 228
 229 #
 230 # the normal output routine
 231 #
 232 sub send                                                # this is always later and always data
 233 {
 234         my $self = shift;
 235         my $conn = $self->{conn};
 236         return unless $conn;
 237         my $call = $self->{call};
 238
 239         for (@_) {
 240                 chomp;
 241         my @lines = split /\n/;
 242                 for (@lines) {
 243                         $conn->send_later("D$call|$_");
 244                         dbg('chan', "-> D $call $_");
 245                 }
 246         }
 247         $self->{t} = time;
 248 }
 249
 250 # send a file (always later)
 251 sub send_file
 252 {
 253         my ($self, $fn) = @_;
 254         my $call = $self->{call};
 255         my $conn = $self->{conn};
 256         my @buf;
 257
 258         open(F, $fn) or die "can't open $fn for sending file ($!)";
 259         @buf = <F>;
 260         close(F);
 261         $self->send(@buf);
 262 }
 263
 264 # this will implement language independence (in time)
 265 sub msg
 266 {
 267         my $self = shift;
 268         return DXM::msg($self->{lang}, @_);
 269 }
 270
 271 # stick a broadcast on the delayed queue (but only up to 20 items)
 272 sub delay
 273 {
 274         my $self = shift;
 275         my $s = shift;
 276
 277         $self->{delayed} = [] unless $self->{delayed};
 278         push @{$self->{delayed}}, $s;
 279         if (@{$self->{delayed}} >= 20) {
 280                 shift @{$self->{delayed}};   # lose oldest one
 281         }
 282 }
 283
 284 # change the state of the channel - lots of scope for debugging here :-)
 285 sub state
 286 {
 287         my $self = shift;
 288         if (@_) {
 289                 $self->{oldstate} = $self->{state};
 290                 $self->{state} = shift;
 291                 $self->{func} = '' unless defined $self->{func};
 292                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 293
 294                 # if there is any queued up broadcasts then splurge them out here
 295                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 296                         $self->send (@{$self->{delayed}});
 297                         delete $self->{delayed};
 298                 }
 299         }
 300         return $self->{state};
 301 }
 302
 303 # disconnect this channel
 304 sub disconnect
 305 {
 306         my $self = shift;
 307         my $user = $self->{user};
 308         my $conn = $self->{conn};
 309         my $call = $self->{call};
 310
 311         $self->finish();
 312         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 313         $user->close() if defined $user;
 314         $conn->disconnect() if $conn;
 315         $self->del();
 316 }
 317
 318 #
 319 # just close all the socket connections down without any fiddling about, cleaning, being
 320 # nice to other processes and otherwise telling them what is going on.
 321 #
 322 # This is for the benefit of forked processes to prepare for starting new programs, they
 323 # don't want or need all this baggage.
 324 #
 325
 326 sub closeall
 327 {
 328         my $ref;
 329         foreach $ref (values %channels) {
 330                 $ref->{conn}->disconnect() if $ref->{conn};
 331         }
 332 }
 333
 334 # various access routines
 335
 336 #
 337 # return a list of valid elements
 338 #
 339
 340 sub fields
 341 {
 342         return keys(%valid);
 343 }
 344
 345 #
 346 # return a prompt for a field
 347 #
 348
 349 sub field_prompt
 350 {
 351         my ($self, $ele) = @_;
 352         return $valid{$ele};
 353 }
 354
 355 no strict;
 356 sub AUTOLOAD
 357 {
 358         my $self = shift;
 359         my $name = $AUTOLOAD;
 360         return if $name =~ /::DESTROY$/;
 361         $name =~ s/.*:://o;
 362
 363         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 364         @_ ? $self->{$name} = shift : $self->{$name} ;
 365 }
 366
 367 1;
 368 __END__;