perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2006 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35 use RouteDB;
  36
  37
  38 use strict;
  39
  40 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  41                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  42                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  43                         $investigation_int $pc19_version $myprot_version
  44                         %nodehops $baddx $badspotter $badnode $censorpc
  45                         $allowzero $decode_dk0wcy $send_opernam @checklist
  46                         $eph_pc15_restime $pc9x_past_age $pc9x_future_age
  47                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  48                    );
  49
  50 $pc9x_past_age = 62*60;                 # maximum age in the past of a px9x (a config record might be the only
  51                                                                 # thing a node might send - once an hour)
  52 $pc9x_future_age = 5*60;                # maximum age in the future ditto
  53 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  54 $pc92_slug_changes = 60;                # slug any changes going outward for this long
  55 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  56
  57 # incoming talk commands
  58 sub handle_10
  59 {
  60         my $self = shift;
  61         my $pcno = shift;
  62         my $line = shift;
  63         my $origin = shift;
  64
  65         # this is to catch loops caused by bad software ...
  66         if (eph_dup($line, $pc10_dupe_age)) {
  67                 return;
  68         }
  69
  70         # will we allow it at all?
  71         if ($censorpc) {
  72                 my @bad;
  73                 if (@bad = BadWords::check($_[3])) {
  74                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
  75                         return;
  76                 }
  77         }
  78
  79         # is it for me or one of mine?
  80         my ($from, $to, $via, $call, $dxchan);
  81         $from = $_[1];
  82         if ($_[5] gt ' ') {
  83                 $via = $_[2];
  84                 $to = $_[5];
  85         } else {
  86                 $to = $_[2];
  87         }
  88
  89         # if this is a 'nodx' node then ignore it
  90         if ($badnode->in($_[6]) || ($via && $badnode->in($via))) {
  91                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
  92                 return;
  93         }
  94
  95         # if this is a 'bad spotter' user then ignore it
  96         my $nossid = $from;
  97         $nossid =~ s/-\d+$//;
  98         if ($badspotter->in($nossid)) {
  99                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 100                 return;
 101         }
 102
 103         # if we are converting announces to talk is it a dup?
 104         if ($ann_to_talk) {
 105                 if (AnnTalk::is_talk_candidate($from, $_[3]) && AnnTalk::dup($from, $to, $_[3])) {
 106                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 107                         return;
 108                 }
 109         }
 110
 111         # remember a route to this node and also the node on which this user is
 112         RouteDB::update($_[6], $self->{call});
 113 #       RouteDB::update($to, $_[6]);
 114
 115         # convert this to a PC93, coming from mycall with origin set and process it as such
 116         $main::me->normal(pc93($to, $from, $via, $_[3], $_[6]));
 117 }
 118
 119 # DX Spot handling
 120 sub handle_11
 121 {
 122         my $self = shift;
 123         my $pcno = shift;
 124         my $line = shift;
 125         my $origin = shift;
 126
 127         # route 'foreign' pc26s
 128         if ($pcno == 26) {
 129                 if ($_[7] ne $main::mycall) {
 130                         $self->route($_[7], $line);
 131                         return;
 132                 }
 133         }
 134
 135         # is the spotted callsign blank? This should really be trapped earlier but it
 136         # could break other protocol sentences. Also check for lower case characters.
 137         if ($_[2] =~ /^\s*$/) {
 138                 dbg("PCPROT: blank callsign, dropped") if isdbg('chanerr');
 139                 return;
 140         }
 141         if ($_[2] =~ /[a-z]/) {
 142                 dbg("PCPROT: lowercase characters, dropped") if isdbg('chanerr');
 143                 return;
 144         }
 145
 146
 147         # if this is a 'nodx' node then ignore it
 148         if ($badnode->in($_[7])) {
 149                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 150                 return;
 151         }
 152
 153         # if this is a 'bad spotter' user then ignore it
 154         my $nossid = $_[6];
 155         $nossid =~ s/-\d+$//;
 156         if ($badspotter->in($nossid)) {
 157                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 158                 return;
 159         }
 160
 161         # convert the date to a unix date
 162         my $d = cltounix($_[3], $_[4]);
 163         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 164         if (!$d || ($pcno == 11 && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 165                 dbg("PCPROT: Spot ignored, invalid date or out of range ($_[3] $_[4])\n") if isdbg('chanerr');
 166                 return;
 167         }
 168
 169         # is it 'baddx'
 170         if ($baddx->in($_[2]) || BadWords::check($_[2]) || $_[2] =~ /COCK/) {
 171                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 172                 return;
 173         }
 174
 175         # do some de-duping
 176         $_[5] =~ s/^\s+//;                      # take any leading blanks off
 177         $_[2] = unpad($_[2]);           # take off leading and trailing blanks from spotted callsign
 178         if ($_[2] =~ /BUST\w*$/) {
 179                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 180                 return;
 181         }
 182         if ($censorpc) {
 183                 my @bad;
 184                 if (@bad = BadWords::check($_[5])) {
 185                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 186                         return;
 187                 }
 188         }
 189
 190         # remember a route
 191 #       RouteDB::update($_[7], $self->{call});
 192 #       RouteDB::update($_[6], $_[7]);
 193
 194         my @spot = Spot::prepare($_[1], $_[2], $d, $_[5], $nossid, $_[7]);
 195         # global spot filtering on INPUT
 196         if ($self->{inspotsfilter}) {
 197                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 198                 unless ($filter) {
 199                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 200                         return;
 201                 }
 202         }
 203
 204         # this goes after the input filtering, but before the add
 205         # so that if it is input filtered, it isn't added to the dup
 206         # list. This allows it to come in from a "legitimate" source
 207         if (Spot::dup(@spot[0..4,5])) {
 208                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 209                 return;
 210         }
 211
 212         # add it
 213         Spot::add(@spot);
 214
 215         #
 216         # @spot at this point contains:-
 217         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 218         # then  spotted itu, spotted cq, spotters itu, spotters cq
 219         # you should be able to route on any of these
 220         #
 221
 222         # fix up qra locators of known users
 223         my $user = DXUser->get_current($spot[4]);
 224         if ($user) {
 225                 my $qra = $user->qra;
 226                 unless ($qra && is_qra($qra)) {
 227                         my $lat = $user->lat;
 228                         my $long = $user->long;
 229                         if (defined $lat && defined $long) {
 230                                 $user->qra(DXBearing::lltoqra($lat, $long));
 231                                 $user->put;
 232                         }
 233                 }
 234
 235                 # send a remote command to a distant cluster if it is visible and there is no
 236                 # qra locator and we havn't done it for a month.
 237
 238                 unless ($user->qra) {
 239                         my $node;
 240                         my $to = $user->homenode;
 241                         my $last = $user->lastoper || 0;
 242                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 243                                 my $cmd = "forward/opernam $spot[4]";
 244                                 # send the rcmd but we aren't interested in the replies...
 245                                 my $dxchan = $node->dxchan;
 246                                 if ($dxchan && $dxchan->is_clx) {
 247                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 248                                 } else {
 249                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 250                                 }
 251                                 if ($to ne $_[7]) {
 252                                         $to = $_[7];
 253                                         $node = Route::Node::get($to);
 254                                         if ($node) {
 255                                                 $dxchan = $node->dxchan;
 256                                                 if ($dxchan && $dxchan->is_clx) {
 257                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 258                                                 } else {
 259                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 260                                                 }
 261                                         }
 262                                 }
 263                                 $user->lastoper($main::systime);
 264                                 $user->put;
 265                         }
 266                 }
 267         }
 268
 269         # local processing
 270         my $r;
 271         eval {
 272                 $r = Local::spot($self, @spot);
 273         };
 274         #                       dbg("Local::spot1 error $@") if isdbg('local') if $@;
 275         return if $r;
 276
 277         # DON'T be silly and send on PC26s!
 278         return if $pcno == 26;
 279
 280         # send out the filtered spots
 281         send_dx_spot($self, $line, @spot) if @spot;
 282 }
 283
 284 # announces
 285 sub handle_12
 286 {
 287         my $self = shift;
 288         my $pcno = shift;
 289         my $line = shift;
 290         my $origin = shift;
 291
 292         # announce duplicate checking
 293         $_[3] =~ s/^\s+//;                      # remove leading blanks
 294
 295         if ($censorpc) {
 296                 my @bad;
 297                 if (@bad = BadWords::check($_[3])) {
 298                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 299                         return;
 300                 }
 301         }
 302
 303         # if this is a 'nodx' node then ignore it
 304         if ($badnode->in($_[5])) {
 305                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 306                 return;
 307         }
 308
 309         # if this is a 'bad spotter' user then ignore it
 310         my $nossid = $_[1];
 311         $nossid =~ s/-\d+$//;
 312         if ($badspotter->in($nossid)) {
 313                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 314                 return;
 315         }
 316
 317
 318         my $dxchan;
 319
 320         if ((($dxchan = DXChannel::get($_[2])) && $dxchan->is_user) || $_[4] =~ /^[\#\w.]+$/){
 321                 $self->send_chat(0, $line, @_[1..6]);
 322         } elsif ($_[2] eq '*' || $_[2] eq $main::mycall) {
 323
 324                 # remember a route
 325 #               RouteDB::update($_[5], $self->{call});
 326 #               RouteDB::update($_[1], $_[5]);
 327
 328                 # ignore something that looks like a chat line coming in with sysop
 329                 # flag - this is a kludge...
 330                 if ($_[3] =~ /^\#\d+ / && $_[4] eq '*') {
 331                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 332                         return;
 333                 }
 334
 335                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 336                 # or one saying 'to <call>' to a talk if we can route to the recipient
 337                 if ($ann_to_talk) {
 338                         my $call = AnnTalk::is_talk_candidate($_[1], $_[3]);
 339                         if ($call) {
 340                                 my $ref = Route::get($call);
 341                                 if ($ref) {
 342                                         $dxchan = $ref->dxchan;
 343                                         $dxchan->talk($_[1], $call, undef, $_[3], $_[5]) if $dxchan != $self;
 344                                         return;
 345                                 }
 346                         }
 347                 }
 348
 349                 # send it
 350                 $self->send_announce(0, $line, @_[1..6]);
 351         } else {
 352                 $self->route($_[2], $line);
 353         }
 354 }
 355
 356 sub handle_15
 357 {
 358         my $self = shift;
 359         my $pcno = shift;
 360         my $line = shift;
 361         my $origin = shift;
 362
 363         if (eph_dup($line, $eph_pc15_restime)) {
 364                 return;
 365         } else {
 366                 unless ($self->{isolate}) {
 367                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 368                 }
 369         }
 370 }
 371
 372 # incoming user
 373 sub handle_16
 374 {
 375         my $self = shift;
 376         my $pcno = shift;
 377         my $line = shift;
 378         my $origin = shift;
 379
 380         # general checks
 381         my $dxchan;
 382         my $ncall = $_[1];
 383         my $newline = "PC16^";
 384
 385         # dos I want users from this channel?
 386         unless ($self->user->wantpc16) {
 387                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 388                 return;
 389         }
 390
 391         # is it me?
 392         if ($ncall eq $main::mycall) {
 393                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 394                 return;
 395         }
 396
 397         my $h;
 398         $h = 1 if DXChannel::get($ncall);
 399         RouteDB::update($ncall, $self->{call}, $h);
 400         if ($h && $self->{call} ne $ncall) {
 401                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 402                 return;
 403         }
 404
 405         if (eph_dup($line)) {
 406                 return;
 407         }
 408
 409         # isolate now means only accept stuff from this call only
 410         if ($self->{isolate} && $ncall ne $self->{call}) {
 411                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 412                 return;
 413         }
 414
 415         my $parent = Route::Node::get($ncall);
 416
 417         if ($parent) {
 418                 $dxchan = $parent->dxchan;
 419                 if ($dxchan && $dxchan ne $self) {
 420                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 421                         return;
 422                 }
 423
 424                 # input filter if required
 425                 return unless $self->in_filter_route($parent);
 426         } else {
 427                 $parent = Route::Node->new($ncall);
 428         }
 429
 430         unless ($h) {
 431                 if ($parent->via_pc92) {
 432                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 433                         return;
 434                 }
 435         }
 436
 437         my $i;
 438         my @rout;
 439         for ($i = 2; $i < $#_; $i++) {
 440                 my ($call, $conf, $here) = $_[$i] =~ /^(\S+) (\S) (\d)/o;
 441                 next unless $call && $conf && defined $here && is_callsign($call);
 442                 next if $call eq $main::mycall;
 443
 444                 eph_del_regex("^PC17\\^$call\\^$ncall");
 445
 446                 $conf = $conf eq '*';
 447
 448                 # reject this if we think it is a node already
 449                 my $r = Route::Node::get($call);
 450                 my $u = DXUser->get_current($call) unless $r;
 451                 if ($r || ($u && $u->is_node)) {
 452                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 453                         next;
 454                 }
 455
 456                 $r = Route::User::get($call);
 457                 my $flags = Route::here($here)|Route::conf($conf);
 458
 459                 if ($r) {
 460                         my $au = $r->addparent($parent);
 461                         if ($r->flags != $flags) {
 462                                 $r->flags($flags);
 463                                 $au = $r;
 464                         }
 465                         push @rout, $r if $h && $au;
 466                 } else {
 467                         my @ans = $parent->add_user($call, $flags);
 468                         push @rout, @ans if $h && @ans;
 469                 }
 470
 471                 # add this station to the user database, if required
 472                 my $user = DXUser->get_current($ncall);
 473                 $user = DXUser->new($call) unless $user;
 474                 $user->homenode($parent->call) if !$user->homenode;
 475                 $user->node($parent->call);
 476                 $user->lastin($main::systime) unless DXChannel::get($call);
 477                 $user->put;
 478
 479                 # send info to all logged in thingies
 480                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 481                 $self->tell_buddies('loginb', $call, $ncall);
 482         }
 483         if (@rout) {
 484                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 485 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 486         }
 487 }
 488
 489 # remove a user
 490 sub handle_17
 491 {
 492         my $self = shift;
 493         my $pcno = shift;
 494         my $line = shift;
 495         my $origin = shift;
 496         my $dxchan;
 497         my $ncall = $_[2];
 498         my $ucall = $_[1];
 499
 500         eph_del_regex("^PC16\\^$ncall.*$ucall");
 501
 502         # do I want users from this channel?
 503         unless ($self->user->wantpc16) {
 504                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 505                 return;
 506         }
 507
 508         if ($ncall eq $main::mycall) {
 509                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 510                 return;
 511         }
 512
 513         # isolate now means only accept stuff from this call only
 514         if ($self->{isolate} && $ncall ne $self->{call}) {
 515                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 516                 return;
 517         }
 518
 519         RouteDB::delete($ncall, $self->{call});
 520
 521         my $uref = Route::User::get($ucall);
 522         unless ($uref) {
 523                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 524                 return;
 525         }
 526         my $parent = Route::Node::get($ncall);
 527         unless ($parent) {
 528                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 529                 return;
 530         }
 531
 532         $dxchan = DXChannel::get($ncall);
 533         if ($dxchan && $dxchan ne $self) {
 534                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 535                 return;
 536         }
 537
 538         unless ($dxchan) {
 539                 if ($parent->via_pc92) {
 540                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 541                         return;
 542                 }
 543         }
 544
 545         if (DXChannel::get($ucall)) {
 546                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 547                 return;
 548         }
 549
 550         # input filter if required and then remove user if present
 551 #               return unless $self->in_filter_route($parent);
 552         $parent->del_user($uref);
 553
 554         # send info to all logged in thingies
 555         my $user = DXUser->get_current($ncall);
 556         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 557         $self->tell_buddies('logoutb', $ucall, $ncall);
 558
 559         if (eph_dup($line)) {
 560                 return;
 561         }
 562
 563         $self->route_pc17($origin, $line, $parent, $uref);
 564 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 565 }
 566
 567 # link request
 568 sub handle_18
 569 {
 570         my $self = shift;
 571         my $pcno = shift;
 572         my $line = shift;
 573         my $origin = shift;
 574         $self->state('init');
 575
 576         my $parent = Route::Node::get($self->{call});
 577
 578         # record the type and version offered
 579         if (my ($version) = $_[1] =~ /DXSpider Version: (\d+\.\d+)/) {
 580                 $self->{version} = 53 + $version;
 581                 $self->user->version(53 + $version);
 582                 $parent->version(0 + $version);
 583                 my ($build) = $_[1] =~ /Build: (\d+(?:\.\d+)?)/;
 584                 $self->{build} = 0 + $build;
 585                 $self->user->build(0 + $build);
 586                 $parent->build(0 + $build);
 587                 dbg("DXSpider version $version build $build");
 588                 unless ($self->is_spider) {
 589                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 590                         $self->user->sort('S');
 591                         $self->user->put;
 592                         $self->sort('S');
 593                 }
 594 #               $self->{handle_xml}++ if DXXml::available() && $_[1] =~ /\bxml/;
 595         } else {
 596                 dbg("Unknown software");
 597                 $self->version(50.0);
 598                 $self->version($_[2] / 100) if $_[2] && $_[2] =~ /^\d+$/;
 599                 $self->user->version($self->version);
 600         }
 601
 602         if ($_[1] =~ /\bpc9x/) {
 603                 if ($self->{isolate}) {
 604                         dbg("pc9x recognised, but $self->{call} is isolated, using old protocol");
 605                 } elsif (!$self->user->wantpc9x) {
 606                         dbg("pc9x explicitly switched off on $self->{call}, using old protocol");
 607                 } else {
 608                         $self->{do_pc9x} = 1;
 609                         dbg("Do px9x set on $self->{call}");
 610                 }
 611         }
 612
 613         # first clear out any nodes on this dxchannel
 614         my @rout = $parent->del_nodes;
 615         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 616         $self->send_local_config();
 617         $self->send(pc20());
 618 }
 619
 620 sub check_add_node
 621 {
 622         my $call = shift;
 623
 624         # add this station to the user database, if required (don't remove SSID from nodes)
 625         my $user = DXUser->get_current($call);
 626         if (!$user) {
 627                 $user = DXUser->new($call);
 628                 $user->priv(1);         # I have relented and defaulted nodes
 629                 $user->lockout(1);
 630                 $user->homenode($call);
 631                 $user->node($call);
 632         }
 633         $user->sort('A') unless $user->is_node;
 634         return $user;
 635 }
 636
 637 # incoming cluster list
 638 sub handle_19
 639 {
 640         my $self = shift;
 641         my $pcno = shift;
 642         my $line = shift;
 643         my $origin = shift;
 644
 645         my $i;
 646         my $newline = "PC19^";
 647
 648         # new routing list
 649         my (@rout, @pc92out);
 650
 651         # first get the INTERFACE node
 652         my $parent = Route::Node::get($self->{call});
 653         unless ($parent) {
 654                 dbg("PCPROT: my parent $self->{call} has disappeared");
 655                 $self->disconnect;
 656                 return;
 657         }
 658
 659         my $h;
 660
 661         # parse the PC19
 662         #
 663         # We are making a major change from now on. We are only going to accept
 664         # PC19s from directly connected nodes.  This means that we are probably
 665         # going to throw away most of the data that we are being sent.
 666         #
 667         # The justification for this is that most of it is wrong or out of date
 668         # anyway.
 669         #
 670         # From now on we are only going to believe PC92 data and locally connected
 671         # non-pc92 nodes.
 672         #
 673         for ($i = 1; $i < $#_-1; $i += 4) {
 674                 my $here = $_[$i];
 675                 my $call = uc $_[$i+1];
 676                 my $conf = $_[$i+2];
 677                 my $ver = $_[$i+3];
 678                 next unless defined $here && defined $conf && is_callsign($call);
 679
 680                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
 681
 682                 # check for sane parameters
 683                 #                               $ver = 5000 if $ver eq '0000';
 684                 next unless $ver && $ver =~ /^\d+$/;
 685                 next if $ver < 5000;    # only works with version 5 software
 686                 next if length $call < 3; # min 3 letter callsigns
 687                 next if $call eq $main::mycall;
 688
 689                 # check that this PC19 isn't trying to alter the wrong dxchan
 690                 $h = 0;
 691                 my $dxchan = DXChannel::get($call);
 692                 if ($dxchan) {
 693                         if ($dxchan == $self) {
 694                                 $h = 1;
 695                         } else {
 696                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 697                                 next;
 698                         }
 699                 }
 700
 701                 # isolate now means only accept stuff from this call only
 702                 if ($self->{isolate} && $call ne $self->{call}) {
 703                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
 704                         next;
 705                 }
 706
 707                 my $user = check_add_node($call);
 708
 709 #               if (eph_dup($genline)) {
 710 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
 711 #                       next;
 712 #               }
 713
 714                 RouteDB::update($call, $self->{call}, $dxchan ? 1 : undef);
 715
 716                 unless ($h) {
 717                         if ($parent->via_pc92) {
 718                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 719                                 next;
 720                         }
 721                 }
 722
 723                 my $r = Route::Node::get($call);
 724                 my $flags = Route::here($here)|Route::conf($conf);
 725
 726                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
 727                 if ($r) {
 728                         my $ar;
 729                         if ($call ne $parent->call) {
 730                                 if ($self->in_filter_route($r)) {
 731                                         $ar = $parent->add($call, $ver, $flags);
 732 #                                       push @rout, $ar if $ar;
 733                                 } else {
 734                                         next;
 735                                 }
 736                         }
 737                         if ($r->version ne $ver || $r->flags != $flags) {
 738                                 $r->version($ver);
 739                                 $r->flags($flags);
 740                         }
 741                         push @rout, $r;
 742                 } else {
 743                         if ($call eq $self->{call} || $user->wantroutepc19) {
 744                                 my $new = Route->new($call); # throw away
 745                                 if ($self->in_filter_route($new)) {
 746                                         my $ar = $parent->add($call, $ver, $flags);
 747                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
 748                                         push @rout, $ar if $ar;
 749                                         push @pc92out, $r if $h;
 750                                 } else {
 751                                         next;
 752                                 }
 753                         }
 754                 }
 755
 756                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 757                 my $mref = DXMsg::get_busy($call);
 758                 $mref->stop_msg($call) if $mref;
 759
 760                 $user->lastin($main::systime) unless DXChannel::get($call);
 761                 $user->put;
 762         }
 763
 764         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
 765         # but remember there will only be one (pair) these because any extras will be
 766         # thrown away.
 767         if (@rout) {
 768 #               $self->route_pc21($self->{call}, $line, @rout);
 769                 $self->route_pc19($self->{call}, $line, @rout);
 770         }
 771         if (@pc92out && !$pc92_slug_changes) {
 772                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
 773         }
 774 }
 775
 776 # send local configuration
 777 sub handle_20
 778 {
 779         my $self = shift;
 780         my $pcno = shift;
 781         my $line = shift;
 782         my $origin = shift;
 783
 784         if ($self->{do_pc9x} && $self->{state} ne 'init92') {
 785                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 786                 $self->{do_pc9x} = 0;
 787         }
 788         $self->send_local_config;
 789         $self->send(pc22());
 790         $self->state('normal');
 791         $self->{lastping} = 0;
 792         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 793 }
 794
 795 # delete a cluster from the list
 796 #
 797 # This should never occur for directly connected nodes.
 798 #
 799 sub handle_21
 800 {
 801         my $self = shift;
 802         my $pcno = shift;
 803         my $line = shift;
 804         my $origin = shift;
 805         my $call = uc $_[1];
 806
 807         eph_del_regex("^PC1[679].*$call");
 808
 809         # if I get a PC21 from the same callsign as self then ignore it
 810         if ($call eq $self->{call}) {
 811                 dbg("PCPROT: self referencing PC21 from $self->{call}");
 812                 return;
 813         }
 814
 815         # for the above reason and also because of the check for PC21s coming
 816         # in for self->call from outside being ignored further down
 817         # we don't need any isolation code here, because we will never
 818         # act on a PC21 with self->call in it.
 819
 820         RouteDB::delete($call, $self->{call});
 821
 822         my $parent = Route::Node::get($self->{call});
 823         unless ($parent) {
 824                 dbg("PCPROT: my parent $self->{call} has disappeared");
 825                 $self->disconnect;
 826                 return;
 827         }
 828
 829         my @rout;
 830
 831         if ($call ne $main::mycall) { # don't allow malicious buggers to disconnect me!
 832                 my $node = Route::Node::get($call);
 833                 if ($node) {
 834
 835                         if ($node->via_pc92) {
 836                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
 837                                 return;
 838                         }
 839
 840                         my $dxchan = DXChannel::get($call);
 841                         if ($dxchan && $dxchan != $self) {
 842                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chanerr');
 843                                 return;
 844                         }
 845
 846                         # input filter it
 847                         return unless $self->in_filter_route($node);
 848
 849                         # routing objects, force a PC21 if it is local
 850                         push @rout, $node->del($parent);
 851                         push @rout, $call if $dxchan && @rout == 0;
 852                 }
 853         } else {
 854                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chanerr');
 855                 return;
 856         }
 857
 858         if (eph_dup($line)) {
 859                 return;
 860         }
 861
 862         if (@rout) {
 863                 $self->route_pc21($origin, $line, @rout);
 864 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
 865         }
 866 }
 867
 868
 869 sub handle_22
 870 {
 871         my $self = shift;
 872         my $pcno = shift;
 873         my $line = shift;
 874         my $origin = shift;
 875
 876         if ($self->{do_pc9x}) {
 877                 if ($self->{state} ne 'init92') {
 878                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 879                         $self->{do_pc9x} = 0;
 880                 }
 881         }
 882         $self->{lastping} = 0;
 883         $self->state('normal');
 884         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 885 }
 886
 887 # WWV info
 888 sub handle_23
 889 {
 890         my $self = shift;
 891         my $pcno = shift;
 892         my $line = shift;
 893         my $origin = shift;
 894
 895         # route foreign' pc27s
 896         if ($pcno == 27) {
 897                 if ($_[8] ne $main::mycall) {
 898                         $self->route($_[8], $line);
 899                         return;
 900                 }
 901         }
 902
 903
 904         # do some de-duping
 905         my $d = cltounix($_[1], sprintf("%02d18Z", $_[2]));
 906         my $sfi = unpad($_[3]);
 907         my $k = unpad($_[4]);
 908         my $i = unpad($_[5]);
 909         my ($r) = $_[6] =~ /R=(\d+)/;
 910         $r = 0 unless $r;
 911         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $_[2] < 0 || $_[2] > 23) {
 912                 dbg("PCPROT: WWV Date ($_[1] $_[2]) out of range") if isdbg('chanerr');
 913                 return;
 914         }
 915
 916         # global wwv filtering on INPUT
 917         my @dxcc = ((Prefix::cty_data($_[7]))[0..2], (Prefix::cty_data($_[8]))[0..2]);
 918         if ($self->{inwwvfilter}) {
 919                 my ($filter, $hops) = $self->{inwwvfilter}->it(@_[7,8], $origin, @dxcc);
 920                 unless ($filter) {
 921                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
 922                         return;
 923                 }
 924         }
 925         $_[7] =~ s/-\d+$//o;            # remove spotter's ssid
 926         if (Geomag::dup($d,$sfi,$k,$i,$_[6],$_[7])) {
 927                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 928                 return;
 929         }
 930
 931         # note this only takes the first one it gets
 932         Geomag::update($d, $_[2], $sfi, $k, $i, @_[6..8], $r);
 933
 934         my $rep;
 935         eval {
 936                 $rep = Local::wwv($self, $_[1], $_[2], $sfi, $k, $i, @_[6..8], $r);
 937         };
 938         #                       dbg("Local::wwv2 error $@") if isdbg('local') if $@;
 939         return if $rep;
 940
 941         # DON'T be silly and send on PC27s!
 942         return if $pcno == 27;
 943
 944         # broadcast to the eager world
 945         send_wwv_spot($self, $line, $d, $_[2], $sfi, $k, $i, @_[6..8]);
 946 }
 947
 948 # set here status
 949 sub handle_24
 950 {
 951         my $self = shift;
 952         my $pcno = shift;
 953         my $line = shift;
 954         my $origin = shift;
 955         my $call = uc $_[1];
 956         my ($nref, $uref);
 957         $nref = Route::Node::get($call);
 958         $uref = Route::User::get($call);
 959         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
 960
 961         if (eph_dup($line)) {
 962                 return;
 963         }
 964
 965         $nref->here($_[2]) if $nref;
 966         $uref->here($_[2]) if $uref;
 967         my $ref = $nref || $uref;
 968         return unless $self->in_filter_route($ref);
 969
 970         $self->route_pc24($origin, $line, $ref, $_[3]);
 971 }
 972
 973 # merge request
 974 sub handle_25
 975 {
 976         my $self = shift;
 977         my $pcno = shift;
 978         my $line = shift;
 979         my $origin = shift;
 980         if ($_[1] ne $main::mycall) {
 981                 $self->route($_[1], $line);
 982                 return;
 983         }
 984         if ($_[2] eq $main::mycall) {
 985                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chanerr');
 986                 return;
 987         }
 988
 989         Log('DXProt', "Merge request for $_[3] spots and $_[4] WWV from $_[2]");
 990
 991         # spots
 992         if ($_[3] > 0) {
 993                 my @in = reverse Spot::search(1, undef, undef, 0, $_[3]);
 994                 my $in;
 995                 foreach $in (@in) {
 996                         $self->send(pc26(@{$in}[0..4], $_[2]));
 997                 }
 998         }
 999
1000         # wwv
1001         if ($_[4] > 0) {
1002                 my @in = reverse Geomag::search(0, $_[4], time, 1);
1003                 my $in;
1004                 foreach $in (@in) {
1005                         $self->send(pc27(@{$in}[0..5], $_[2]));
1006                 }
1007         }
1008 }
1009
1010 sub handle_26 {goto &handle_11}
1011 sub handle_27 {goto &handle_23}
1012
1013 # mail/file handling
1014 sub handle_28
1015 {
1016         my $self = shift;
1017         my $pcno = shift;
1018         my $line = shift;
1019         my $origin = shift;
1020         if ($_[1] eq $main::mycall) {
1021                 no strict 'refs';
1022                 my $sub = "DXMsg::handle_$pcno";
1023                 &$sub($self, @_);
1024         } else {
1025                 $self->route($_[1], $line) unless $self->is_clx;
1026         }
1027 }
1028
1029 sub handle_29 {goto &handle_28}
1030 sub handle_30 {goto &handle_28}
1031 sub handle_31 {goto &handle_28}
1032 sub handle_32 {goto &handle_28}
1033 sub handle_33 {goto &handle_28}
1034
1035 sub handle_34
1036 {
1037         my $self = shift;
1038         my $pcno = shift;
1039         my $line = shift;
1040         my $origin = shift;
1041         if (eph_dup($line, $eph_pc34_restime)) {
1042                 return;
1043         } else {
1044                 $self->process_rcmd($_[1], $_[2], $_[2], $_[3]);
1045         }
1046 }
1047
1048 # remote command replies
1049 sub handle_35
1050 {
1051         my $self = shift;
1052         my $pcno = shift;
1053         my $line = shift;
1054         my $origin = shift;
1055         eph_del_regex("^PC35\\^$_[2]\\^$_[1]\\^");
1056         $self->process_rcmd_reply($_[1], $_[2], $_[1], $_[3]);
1057 }
1058
1059 sub handle_36 {goto &handle_34}
1060
1061 # database stuff
1062 sub handle_37
1063 {
1064         my $self = shift;
1065         my $pcno = shift;
1066         my $line = shift;
1067         my $origin = shift;
1068         if ($_[1] eq $main::mycall) {
1069                 no strict 'refs';
1070                 my $sub = "DXDb::handle_$pcno";
1071                 &$sub($self, @_);
1072         } else {
1073                 $self->route($_[1], $line) unless $self->is_clx;
1074         }
1075 }
1076
1077 # node connected list from neighbour
1078 sub handle_38
1079 {
1080         my $self = shift;
1081         my $pcno = shift;
1082         my $line = shift;
1083         my $origin = shift;
1084 }
1085
1086 # incoming disconnect
1087 sub handle_39
1088 {
1089         my $self = shift;
1090         my $pcno = shift;
1091         my $line = shift;
1092         my $origin = shift;
1093         if ($_[1] eq $self->{call}) {
1094                 $self->disconnect(1);
1095         } else {
1096                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1097         }
1098 }
1099
1100 sub handle_40 {goto &handle_28}
1101
1102 # user info
1103 sub handle_41
1104 {
1105         my $self = shift;
1106         my $pcno = shift;
1107         my $line = shift;
1108         my $origin = shift;
1109         my $call = $_[1];
1110         my $sort = $_[2];
1111         my $val = $_[3];
1112
1113         my $l = "PC41^$call^$sort";
1114         if (eph_dup($l, $eph_info_restime)) {
1115                 return;
1116         }
1117
1118         # input filter if required
1119         #                       my $ref = Route::get($call) || Route->new($call);
1120         #                       return unless $self->in_filter_route($ref);
1121
1122         if ($val eq $sort || $val =~ /^\s*$/) {
1123                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1124                 return;
1125         }
1126
1127         # add this station to the user database, if required
1128         my $user = DXUser->get_current($call);
1129         $user = DXUser->new($call) unless $user;
1130
1131         if ($sort == 1) {
1132                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1133                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1134                         if ($main::mycall eq 'GB7DJK' || $main::mycall eq 'GB7BAA' || $main::mycall eq 'WR3D') {
1135                                 DXChannel::broadcast_nodes(pc41($_[1], 1, $user->name)); # send it to everyone including me
1136                         }
1137                         return;
1138                 }
1139                 $user->name($val);
1140         } elsif ($sort == 2) {
1141                 $user->qth($val);
1142         } elsif ($sort == 3) {
1143                 if (is_latlong($val)) {
1144                         my ($lat, $long) = DXBearing::stoll($val);
1145                         $user->lat($lat) if $lat;
1146                         $user->long($long) if $long;
1147                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1148                 } else {
1149                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1150                         return;
1151                 }
1152         } elsif ($sort == 4) {
1153                 $user->homenode($val);
1154         } elsif ($sort == 5) {
1155                 if (is_qra(uc $val)) {
1156                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1157                         $user->lat($lat) if $lat && !$user->lat;
1158                         $user->long($long) if $long && !$user->long;
1159                         $user->qra(uc $val);
1160                 } else {
1161                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1162                         return;
1163                 }
1164         }
1165         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1166         $user->put;
1167
1168         unless ($self->{isolate}) {
1169                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1170         }
1171
1172         #  perhaps this IS what we want after all
1173         #                       $self->route_pc41($ref, $call, $sort, $val, $_[4]);
1174 }
1175
1176 sub handle_42 {goto &handle_28}
1177
1178
1179 # database
1180 sub handle_44 {goto &handle_37}
1181 sub handle_45 {goto &handle_37}
1182 sub handle_46 {goto &handle_37}
1183 sub handle_47 {goto &handle_37}
1184 sub handle_48 {goto &handle_37}
1185
1186 # message and database
1187 sub handle_49
1188 {
1189         my $self = shift;
1190         my $pcno = shift;
1191         my $line = shift;
1192         my $origin = shift;
1193
1194         if (eph_dup($line)) {
1195                 return;
1196         }
1197
1198         if ($_[1] eq $main::mycall) {
1199                 DXMsg::handle_49($self, @_);
1200         } else {
1201                 $self->route($_[1], $line) unless $self->is_clx;
1202         }
1203 }
1204
1205 # keep alive/user list
1206 sub handle_50
1207 {
1208         my $self = shift;
1209         my $pcno = shift;
1210         my $line = shift;
1211         my $origin = shift;
1212
1213         my $call = $_[1];
1214
1215         RouteDB::update($call, $self->{call});
1216
1217         my $node = Route::Node::get($call);
1218         if ($node) {
1219                 return unless $node->call eq $self->{call};
1220                 $node->usercount($_[2]);
1221
1222                 # input filter if required
1223                 return unless $self->in_filter_route($node);
1224
1225                 $self->route_pc50($origin, $line, $node, $_[2], $_[3]) unless eph_dup($line);
1226         }
1227 }
1228
1229 # incoming ping requests/answers
1230 sub handle_51
1231 {
1232         my $self = shift;
1233         my $pcno = shift;
1234         my $line = shift;
1235         my $origin = shift;
1236         my $to = $_[1];
1237         my $from = $_[2];
1238         my $flag = $_[3];
1239
1240
1241         # is it for us?
1242         if ($to eq $main::mycall) {
1243                 if ($flag == 1) {
1244                         $self->send(pc51($from, $to, '0'));
1245                 } else {
1246                         DXXml::Ping::handle_ping_reply($self, $from);
1247                 }
1248         } else {
1249
1250                 RouteDB::update($from, $self->{call});
1251
1252                 if (eph_dup($line)) {
1253                         return;
1254                 }
1255                 # route down an appropriate thingy
1256                 $self->route($to, $line);
1257         }
1258 }
1259
1260 # dunno but route it
1261 sub handle_75
1262 {
1263         my $self = shift;
1264         my $pcno = shift;
1265         my $line = shift;
1266         my $origin = shift;
1267         my $call = $_[1];
1268         if ($call ne $main::mycall) {
1269                 $self->route($call, $line);
1270         }
1271 }
1272
1273 # WCY broadcasts
1274 sub handle_73
1275 {
1276         my $self = shift;
1277         my $pcno = shift;
1278         my $line = shift;
1279         my $origin = shift;
1280         my $call = $_[1];
1281
1282         # do some de-duping
1283         my $d = cltounix($call, sprintf("%02d18Z", $_[2]));
1284         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $_[2] < 0 || $_[2] > 23) {
1285                 dbg("PCPROT: WCY Date ($call $_[2]) out of range") if isdbg('chanerr');
1286                 return;
1287         }
1288         @_ = map { unpad($_) } @_;
1289         if (WCY::dup($d)) {
1290                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1291                 return;
1292         }
1293
1294         my $wcy = WCY::update($d, @_[2..12]);
1295
1296         my $rep;
1297         eval {
1298                 $rep = Local::wcy($self, @_[1..12]);
1299         };
1300         # dbg("Local::wcy error $@") if isdbg('local') if $@;
1301         return if $rep;
1302
1303         # broadcast to the eager world
1304         send_wcy_spot($self, $line, $d, @_[2..12]);
1305 }
1306
1307 # remote commands (incoming)
1308 sub handle_84
1309 {
1310         my $self = shift;
1311         my $pcno = shift;
1312         my $line = shift;
1313         my $origin = shift;
1314         $self->process_rcmd($_[1], $_[2], $_[3], $_[4]);
1315 }
1316
1317 # remote command replies
1318 sub handle_85
1319 {
1320         my $self = shift;
1321         my $pcno = shift;
1322         my $line = shift;
1323         my $origin = shift;
1324         $self->process_rcmd_reply($_[1], $_[2], $_[3], $_[4]);
1325 }
1326
1327 # decode a pc92 call: flag call : version : build
1328 sub _decode_pc92_call
1329 {
1330         my $icall = shift;
1331         my @part = split /:/, $icall;
1332         my ($flag, $call) = unpack "A A*", $part[0];
1333         unless (defined $flag && $flag ge '0' && $flag le '7') {
1334                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1335                 return ();
1336         }
1337         unless ($call && is_callsign($call)) {
1338                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1339                 return ();
1340         }
1341         my $is_node = $flag & 4;
1342         my $is_extnode = $flag & 2;
1343         my $here = $flag & 1;
1344         return ($call, $is_node, $is_extnode, $here, $part[1], $part[2]);
1345 }
1346
1347 # decode a pc92 call: flag call : version : build
1348 sub _encode_pc92_call
1349 {
1350         my $ref = shift;
1351
1352         # plain call or value
1353         return $ref unless ref $ref;
1354
1355         my $ext = shift;
1356         my $flag = 0;
1357         my $call = $ref->call;
1358         my $extra = '';
1359         $flag |= $ref->here ? 1 : 0;
1360         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1361                 $flag |= 4;
1362                 my $dxchan = DXChannel::get($call);
1363                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1364                 if ($ext) {
1365                         if ($ref->version) {
1366                                 my $version = $ref->version || 1.0;
1367                                 $version =  $version * 100 + 5300 if $version < 50;
1368                                 $extra .= ":" . $version;
1369                         }
1370                 }
1371         }
1372         return "$flag$call$extra";
1373 }
1374
1375 my %things_add;
1376 my %things_del;
1377
1378 sub _add_thingy
1379 {
1380         my $parent = shift;
1381         my $s = shift;
1382         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1383         my @rout;
1384
1385         if ($call) {
1386                 if ($is_node) {
1387                         dbg("ROUTE: added node $call to " . $parent->call) if isdbg('routelow');
1388                         @rout = $parent->add($call, $version, Route::here($here));
1389                 } else {
1390                         dbg("ROUTE: added user $call to " . $parent->call) if isdbg('routelow');
1391                         @rout = $parent->add_user($call, Route::here($here));
1392                 }
1393                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1394                         $things_add{$call} = Route::get($call);
1395                         delete $things_del{$call};
1396                 }
1397         }
1398         return @rout;
1399 }
1400
1401 sub _del_thingy
1402 {
1403         my $parent = shift;
1404         my $s = shift;
1405         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1406         my @rout;
1407         if ($call) {
1408                 my $ref;
1409                 if ($is_node) {
1410                         $ref = Route::Node::get($call);
1411                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1412                         @rout = $ref->del($parent) if $ref;
1413                 } else {
1414                         $ref = Route::User::get($call);
1415                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1416                         @rout = $parent->del_user($ref) if $ref;
1417                 }
1418                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1419                         $things_del{$call} = $ref unless exists $things_add{$call};
1420                         delete $things_add{$call};
1421                 }
1422         }
1423         return @rout;
1424 }
1425
1426 # this will only happen if we are slugging changes and
1427 # there are some changes to be sent, it will create an add or a delete
1428 # or both
1429 sub gen_pc92_changes
1430 {
1431         my @add = values %things_add;
1432         my @del = values %things_del;
1433         return (\@add, \@del);
1434 }
1435
1436 sub clear_pc92_changes
1437 {
1438         %things_add = %things_del = ();
1439         $last_pc92_slug = $main::systime;
1440 }
1441
1442 my $_last_time;
1443 my $_last_occurs;
1444 my $_last_pc9x_id;
1445
1446 sub last_pc9x_id
1447 {
1448         return $_last_pc9x_id;
1449 }
1450
1451 sub gen_pc9x_t
1452 {
1453         if (!$_last_time || $_last_time != $main::systime) {
1454                 $_last_time = $main::systime;
1455                 $_last_occurs = 0;
1456                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1457         } else {
1458                 $_last_occurs++;
1459                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1460         }
1461 }
1462
1463 sub check_pc9x_t
1464 {
1465         my $call = shift;
1466         my $t = shift;
1467         my $pc = shift;
1468         my $create = shift;
1469
1470         my $parent = ref $call ? $call : Route::Node::get($call);
1471         if ($parent) {
1472                 # we only do this for external calls whose routing table
1473                 # record come and go. The reference for mycall is permanent
1474                 # and not that frequently used, it also never times out, so
1475                 # the id on it is completely unreliable. Besides, only commands
1476                 # originating on this box will go through this code...
1477                 if ($parent->call ne $main::mycall) {
1478                         my $lastid = $parent->lastid || 0;
1479                         if ($t < $lastid) {
1480                                 if ($t+86400-$lastid > $pc9x_past_age) {
1481                                         dbg("PCPROT: dup id on $t <= $lastid, ignored") if isdbg('chanerr');
1482                                         return;
1483                                 }
1484                         } elsif ($t == $lastid) {
1485                                 dbg("PCPROT: dup id on $t == $lastid, ignored") if isdbg('chanerr');
1486                                 return;
1487                         } else {
1488                                 # $t > $lastid, check that the timestamp offered isn't too far away from 'now'
1489                                 if ($t+$main::systime_daystart-$main::systime > $pc9x_future_age ) {
1490                                         dbg("PCPROT: id $t too far in the future, ignored") if isdbg('chanerr');
1491                                         return;
1492                                 }
1493                         }
1494                 }
1495         } elsif ($create) {
1496                 $parent = Route::Node->new($call);
1497         }
1498         $parent->lastid($t) if $parent;
1499
1500         return $parent;
1501 }
1502
1503 # DXSpider routing entries
1504 sub handle_92
1505 {
1506         my $self = shift;
1507         my $pcno = shift;
1508         my $line = shift;
1509         my $origin = shift;
1510
1511         my (@radd, @rdel);
1512
1513         my $pcall = $_[1];
1514         my $t = $_[2];
1515         my $sort = $_[3];
1516
1517         if ($pcall eq $main::mycall) {
1518                 dbg("PCPROT: looped back, ignored") if isdbg('chanerr');
1519                 return;
1520         }
1521
1522         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
1523                 if ($self->{isolate}) {
1524                         dbg("PC9x received, but $pcall is isolated, ignored");
1525                         return;
1526                 } elsif (!$self->user->wantpc9x) {
1527                         dbg("PC9x explicitly switched off on $pcall, ignored");
1528                         return;
1529                 } else {
1530                         $self->state('init92');
1531                         $self->{do_pc9x} = 1;
1532                         dbg("Do pc9x set on $pcall");
1533                 }
1534         }
1535         unless ($self->{do_pc9x}) {
1536                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1537                 return;
1538         }
1539
1540         my $parent = check_pc9x_t($pcall, $t, 92, 1) || return;
1541         my $oparent = $parent;
1542
1543         $parent->do_pc9x(1);
1544         $parent->via_pc92(1);
1545
1546         if ($sort eq 'F' || $sort eq 'R') {
1547
1548                 # this is the route finding section
1549                 # here is where the consequences of the 'find' command
1550                 # are dealt with
1551
1552                 my $from = $_[4];
1553                 my $target = $_[5];
1554
1555                 if ($sort eq 'F') {
1556                         my $flag;
1557                         my $ref;
1558                         my $dxchan;
1559                         if ($ref = DXChannel::get($target)) {
1560                                 $flag = 1;              # we are directly connected
1561                         } else {
1562                                 $ref = Route::get($target);
1563                                 $dxchan = $ref->dxchan;
1564                                 $flag = 2;
1565                         }
1566                         if ($ref && $flag && $dxchan) {
1567                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
1568                                 return;
1569                         }
1570                 } elsif ($sort eq 'R') {
1571                         if (my $dxchan = DXChannel::get($from)) {
1572                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @_[6,7]);
1573                         } else {
1574                                 my $ref = Route::get($from);
1575                                 if ($ref) {
1576                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
1577                                         if (@dxchan) {
1578                                                 $_->send($line) for @dxchan;
1579                                         } else {
1580                                                 dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1581                                         }
1582                                 } else {
1583                                         dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1584                                 }
1585                         }
1586                         return;
1587                 }
1588         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
1589
1590                 # remember the last channel we arrived on
1591                 $parent->PC92C_dxchan($self->{call}) unless $self->{call} eq $parent->call;
1592
1593                 # this is the main route section
1594                 # here is where all the routes are created and destroyed
1595
1596                 # cope with missing duplicate node calls in the first slot for A or D
1597                 my $me = $_[4] || '';
1598                 if (($sort eq 'A' || $sort eq 'D')) {
1599                         $me ||= _encode_pc92_call($parent) if !$me ;
1600                 } else {
1601                         unless ($me) {
1602                                 dbg("PCPROT: this type of PC92 *must* have a node call in the first slot, ignored") if is_dbg('chanerr');
1603                                 return;
1604                         }
1605                 }
1606
1607                 my @ent = map {[ _decode_pc92_call($_) ]} grep {$_ && /^[0-7]/} $me, @_[5 .. $#_];
1608
1609                 if (@ent) {
1610
1611                         # look at the first one which will always be a node of some sort
1612                         # except in the case of 'A' or 'D' in which the $pcall is used
1613                         # otherwise use the node call and update any information
1614                         # that needs to be done.
1615                         my ($call, $is_node, $is_extnode, $here, $version, $build) = @{$ent[0]};
1616                         if ($call && $is_node) {
1617                                 if ($call eq $main::mycall) {
1618                                         dbg("PCPROT: $call looped back onto $main::mycall, ignored") if isdbg('chanerr');
1619                                         return;
1620                                 }
1621                                 # this is only accepted from my "self".
1622                                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
1623                                 # locally connected. Local nodes always take precedence. But we remember the lastid
1624                                 # to try to reduce the number of dupe PC92s for this external node.
1625                                 if (DXChannel::get($call) && $call ne $self->{call}) {
1626                                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
1627                                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
1628                                         return;
1629                                 }
1630                                 if ($is_extnode) {
1631                                         # reparent to external node (note that we must have received a 'C' or 'A' record
1632                                         # from the true parent node for this external before we get one for the this node
1633                                         unless ($parent = Route::Node::get($call)) {
1634                                                 if ($is_extnode && $oparent) {
1635                                                         @radd =  _add_thingy($oparent, $ent[0]);
1636                                                         $parent = $radd[0];
1637                                                 } else {
1638                                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
1639                                                         return;
1640                                                 }
1641                                         }
1642                                         $parent = check_pc9x_t($call, $t, 92) || return;
1643                                         $parent->via_pc92(1);
1644                                         $parent->PC92C_dxchan($self->{call});
1645                                 }
1646                         } else {
1647                                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
1648                                 return;
1649                         }
1650                         $parent->here(Route::here($here));
1651                         $parent->version($version || $pc19_version) if $version;
1652                         $parent->build($build) if $build && $build > $parent->build;
1653                         $parent->PC92C_dxchan($self->{call}) unless $self->{call} eq $parent->call;
1654                         shift @ent;
1655                 }
1656
1657                 # do a pass through removing any references to either locally connected nodes or mycall
1658                 my @nent;
1659                 for (@ent) {
1660                         next unless $_;
1661                         if ($_->[0] eq $main::mycall || DXChannel::get($_->[0])) {
1662                                 dbg("PCPROT: $_->[0] refers to locally connected node, ignored") if isdbg('chanerr');
1663                                 next;
1664                         }
1665                         push @nent, $_;
1666                 }
1667
1668                 if ($sort eq 'A') {
1669                         for (@nent) {
1670                                 push @radd, _add_thingy($parent, $_);
1671                         }
1672                 } elsif ($sort eq 'D') {
1673                         for (@nent) {
1674                                 push @rdel, _del_thingy($parent, $_);
1675                         }
1676                 } elsif ($sort eq 'C') {
1677                         my (@nodes, @users);
1678
1679                         # we only reset obscounts on config records
1680                         $oparent->reset_obs;
1681                         dbg("ROUTE: reset obscount on $pcall now " . $oparent->obscount) if isdbg('obscount');
1682                         if ($oparent != $parent) {
1683                                 $parent->reset_obs;
1684                                 dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1685                         }
1686
1687                         #
1688                         foreach my $r (@nent) {
1689                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
1690                                 if ($r->[0]) {
1691                                         if ($r->[1]) {
1692                                                 push @nodes, $r->[0];
1693                                         } else {
1694                                                 push @users, $r->[0];
1695                                         }
1696                                 } else {
1697                                         dbg("PCPROT: pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr');
1698                                 }
1699                         }
1700
1701                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
1702
1703                         # add users here
1704                         foreach my $r (@nent) {
1705                                 my $call = $r->[0];
1706                                 if ($call) {
1707                                         push @radd,_add_thingy($parent, $r) if grep $call eq $_, (@$nnodes, @$nusers);
1708                                 }
1709                         }
1710                         # del users here
1711                         foreach my $r (@$dnodes) {
1712                                 push @rdel,_del_thingy($parent, [$r, 1]);
1713                         }
1714                         foreach my $r (@$dusers) {
1715                                 push @rdel,_del_thingy($parent, [$r, 0]);
1716                         }
1717
1718                         # remember this last PC92C for rebroadcast on demand
1719                         $parent->last_PC92C($line);
1720                 } else {
1721                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
1722                         return;
1723                 }
1724
1725                 foreach my $r (@rdel) {
1726                         next unless $r;
1727
1728                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
1729                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
1730                 }
1731                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
1732                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
1733                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
1734                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
1735                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
1736         }
1737
1738         # broadcast it if we get here
1739         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1740 }
1741
1742
1743 sub handle_93
1744 {
1745         my $self = shift;
1746         my $pcno = shift;
1747         my $line = shift;
1748         my $origin = shift;
1749
1750 #       $self->{do_pc9x} ||= 1;
1751
1752         my $pcall = $_[1];                      # this is now checked earlier
1753
1754         # remember that we are converting PC10->PC93 and self will be $main::me if it
1755         # comes from us
1756         unless ($self->{do_pc9x}) {
1757                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1758                 return;
1759         }
1760
1761         my $t = $_[2];
1762         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
1763
1764         my $to = uc $_[3];
1765         my $from = uc $_[4];
1766         my $via = uc $_[5];
1767         my $text = $_[6];
1768         my $onode = uc $_[7];
1769         $onode = $pcall if @_ <= 8;
1770
1771         # this is catch loops caused by bad software ...
1772         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
1773                 return;
1774         }
1775
1776         # will we allow it at all?
1777         if ($censorpc) {
1778                 my @bad;
1779                 if (@bad = BadWords::check($text)) {
1780                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
1781                         return;
1782                 }
1783         }
1784
1785         # if this is a 'bad spotter' user then ignore it
1786         my $nossid = $from;
1787         $nossid =~ s/-\d+$//;
1788         if ($badspotter->in($nossid)) {
1789                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
1790                 return;
1791         }
1792
1793         # if it is routeable then then treat it like a talk
1794         my $ref = Route::get($to);
1795         if ($ref) {
1796                 # local talks
1797                 my $dxchan;
1798                 $dxchan = DXChannel::get($main::myalias) if $to eq $main::mycall;
1799                 $dxchan = DXChannel::get($to) unless $dxchan;
1800                 # check it...
1801                 if ($dxchan) {
1802                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
1803                                 if ($dxchan->is_user) {
1804                                         $dxchan->talk($from, $to, $via, $text, $onode);
1805                                         return;
1806                                 }
1807                         } else {
1808                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (local talk)");
1809                         }
1810                 }
1811
1812                 # convert to PC10 talks where appropriate
1813                 # just go for the "best" one for now (rather than broadcast)
1814                 $dxchan = $ref->dxchan;
1815
1816                 # check it...
1817                 if (ref $dxchan && $dxchan->isa('DXChannel')) {
1818                         if ($dxchan->{do_pc9x}) {
1819                                 $dxchan->send($line);
1820                         } else {
1821                                 $dxchan->talk($from, $to, $via, $text, $onode);
1822                         }
1823                 } else {
1824                         dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
1825                 }
1826                 return;
1827
1828         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
1829                 # announces
1830                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
1831                 my $wx = $to eq 'WX' ? '1' : '0';
1832                 my $local = $via eq 'LOCAL' ? '*' : $via;
1833
1834                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
1835                 return if $via eq 'LOCAL';
1836         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
1837                 # chat messages to non-pc9x nodes
1838                 $self->send_chat(1, pc12($from, $text, undef, $to, undef, $pcall), $from, '*', $text, $to, $pcall, '0');
1839         }
1840         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1841 }
1842
1843 # if get here then rebroadcast the thing with its Hop count decremented (if
1844 # there is one). If it has a hop count and it decrements to zero then don't
1845 # rebroadcast it.
1846 #
1847 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
1848 #        REBROADCAST!!!!
1849 #
1850
1851 sub handle_default
1852 {
1853         my $self = shift;
1854         my $pcno = shift;
1855         my $line = shift;
1856         my $origin = shift;
1857
1858         unless (eph_dup($line)) {
1859                 if ($pcno >= 90) {
1860                         my $pcall = $_[1];
1861                         unless (is_callsign($pcall)) {
1862                                 dbg("PCPROT: invalid callsign string '$_[1]', ignored") if isdbg('chanerr');
1863                                 return;
1864                         }
1865                         my $t = $_[2];
1866                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
1867                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1868                 } else {
1869                         unless ($self->{isolate}) {
1870                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
1871                         }
1872                 }
1873         }
1874 }
1875
1876 1;