perl/Filter.pm

   1 #
   2 # The User/Sysop Filter module
   3 #
   4 # The way this works is that the filter routine is actually
   5 # a predefined function that returns 0 if it is OK and 1 if it
   6 # is not when presented with a list of things.
   7 #
   8 # This set of routines provide a means of maintaining the filter
   9 # scripts which are compiled in when an entity connects.
  10 #
  11 # Copyright (c) 1999 Dirk Koopman G1TLH
  12 #
  13 #
  14 #
  15 # The NEW INSTRUCTIONS
  16 #
  17 # use the commands accept/spot|ann|wwv|wcy and reject/spot|ann|wwv|wcy
  18 # also show/filter spot|ann|wwv|wcy
  19 #
  20 # The filters live in a directory tree of their own in $main::root/filter
  21 #
  22 # Each type of filter (e.g. spot, wwv) live in a tree of their own so you
  23 # can have different filters for different things for the same callsign.
  24 #
  25
  26
  27 package Filter;
  28
  29 use DXVars;
  30 use DXUtil;
  31 use DXDebug;
  32 use Data::Dumper;
  33 use Prefix;
  34 use DXLog;
  35 use DXJSON;
  36
  37 use strict;
  38
  39 use vars qw ($filterbasefn $in);
  40
  41 $filterbasefn = "$main::root/filter";
  42 $in = undef;
  43 my $json;
  44
  45
  46 # initial filter system
  47 sub init
  48 {
  49         $json = DXJSON->new->indent(1);
  50 }
  51
  52 sub new
  53 {
  54         my ($class, $sort, $call, $flag) = @_;
  55         $flag = ($flag) ? "in_" : "";
  56         return bless {sort => $sort, name => "$flag$call.pl" }, $class;
  57 }
  58
  59 # standard filename generator
  60 sub getfn
  61 {
  62         my ($sort, $call, $flag) = @_;
  63
  64     # first uppercase
  65         $flag = ($flag) ? "in_" : "";
  66         $call = uc $call;
  67         my $fn = "$filterbasefn/$sort/$flag$call.pl";
  68
  69         # otherwise lowercase
  70         unless (-e $fn) {
  71                 $call = lc $call;
  72                 $fn = "$filterbasefn/$sort/$flag$call.pl";
  73         }
  74         $fn = undef unless -e $fn;
  75         return $fn;
  76 }
  77
  78 # this reads in a filter statement and returns it as a list
  79 #
  80 # The filter is stored in straight perl so that it can be parsed and read
  81 # in with a 'do' statement. The 'do' statement reads the filter into
  82 # @in which is a list of references
  83 #
  84 sub compile
  85 {
  86         my $self = shift;
  87         my $fname = shift;
  88         my $ar = shift;
  89         my $ref = $self->{$fname};
  90         my $rr;
  91
  92         if ($ref->{$ar} && exists $ref->{$ar}->{asc}) {
  93                 my $s = $ref->{$ar}->{asc};     # an optimisation?
  94                 $s =~ s/\$r/\$_[0]/g;
  95 #               $s =~ s/\\\\/\\/g;
  96                 $ref->{$ar}->{code} = eval "sub { $s }" ;
  97                 if ($@) {
  98                         my $sort = $ref->{sort};
  99                         my $name = $ref->{name};
 100                         dbg("Error compiling $ar $sort $name: $@");
 101                         Log('err', "Error compiling $ar $sort $name: $@");
 102                 }
 103                 $rr = $@;
 104         }
 105         return $rr;
 106 }
 107
 108 sub read_in
 109 {
 110         my ($sort, $call, $flag) = @_;
 111         my $fn;
 112
 113         # load it
 114         if ($fn = getfn($sort, $call, $flag)) {
 115                 $in = undef;
 116                 my $s = readfilestr($fn);
 117                 my $newin;
 118                 if ($s =~ /^\s*{/) {
 119                         eval {$newin = $json->decode($s, __PACKAGE__)};
 120                 } else {
 121                         $newin = eval $s;
 122                 }
 123                 if ($@) {
 124                         dbg($@);
 125                         unlink($fn);
 126                         return undef;
 127                 }
 128                 if ($in) {
 129                         $newin = new('Filter::Old', $sort, $call, $flag);
 130                         $newin->{filter} = $in;
 131                 } elsif (ref $newin && $newin->can('getfilkeys')) {
 132                         my $filter;
 133                         my $key;
 134                         foreach $key ($newin->getfilkeys) {
 135                                 $newin->compile($key, 'reject');
 136                                 $newin->compile($key, 'accept');
 137                         }
 138                 } else {
 139                         # error on reading file, delete and exit
 140                         dbg("empty or unreadable filter: $fn, deleted");
 141                         unlink($fn);
 142                         return undef;
 143                 }
 144                 return $newin;
 145         }
 146         return undef;
 147 }
 148
 149
 150 # this writes out the filter in a form suitable to be read in by 'read_in'
 151 # It expects a list of references to filter lines
 152 sub write
 153 {
 154         my $self = shift;
 155         my $sort = $self->{sort};
 156         my $name = $self->{name};
 157         my $dir = "$filterbasefn/$sort";
 158         my $fn = "$dir/$name";
 159
 160         mkdir $dir, 0775 unless -e $dir;
 161     rename $fn, "$fn.o" if -e $fn;
 162         my $fh = new IO::File ">$fn";
 163         if ($fh) {
 164 #               my $dd = new Data::Dumper([ $self ]);
 165 #               $dd->Indent(1);
 166 #               $dd->Terse(1);
 167 #               $dd->Quotekeys($] < 5.005 ? 1 : 0);
 168                 #               $fh->print($dd->Dumpxs);
 169
 170                 # remove code references, do the encode, then put them back again (they can't be represented anyway)
 171                 my $key;
 172                 foreach $key ($self->getfilkeys) {
 173                         $self->{$key}->{reject}->{code} = undef if exists $self->{$key}->{reject};
 174                         $self->{$key}->{accept}->{code} = undef if exists $self->{$key}->{accept};
 175                 }
 176                 $fh->print($json->encode($self));
 177                 foreach $key ($self->getfilkeys) {
 178                         $self->compile($key, 'reject');
 179                         $self->compile($key, 'accept');
 180                 }
 181                 $fh->close;
 182         } else {
 183                 rename "$fn.o", $fn if -e "$fn.o";
 184                 return "$fn $!";
 185         }
 186         return undef;
 187 }
 188
 189 sub getfilters
 190 {
 191         my $self = shift;
 192         my @out;
 193         my $key;
 194         foreach $key (grep {/^filter/ } keys %$self) {
 195                 push @out, $self->{$key};
 196         }
 197         return @out;
 198 }
 199
 200 sub getfilkeys
 201 {
 202         my $self = shift;
 203         return grep {/^filter/ } keys %$self;
 204 }
 205
 206 #
 207 # This routine accepts a composite filter with a reject rule and then an accept rule.
 208 #
 209 # The filter returns 0 if an entry is matched by any reject rule and also if any
 210 # accept rule fails otherwise it returns 1
 211 #
 212 # Either set of rules may be missing meaning an implicit 'opposite' ie if it
 213 # a reject then ok else if an accept then not ok.
 214 #
 215 # you can set a default with either an accept/xxxx all or reject/xxxx all
 216 #
 217 # Unlike the old system, this is kept as a hash of hashes so that you can
 218 # easily change them by program.
 219 #
 220 # You can have 10 filter lines (0->9), they are tried in order until
 221 # one matches
 222 #
 223 # There is a parser that takes a Filter::Cmd object which describes all the possible
 224 # things you can filter on and then converts that to a bit of perl which is compiled
 225 # and stored as a function.
 226 #
 227 # The result of this is that in theory you can put together an arbritrarily complex
 228 # expression involving the things you can filter on including 'and' 'or' 'not' and
 229 # 'brackets'.
 230 #
 231 # eg:-
 232 #
 233 # accept/spots hf and by_zone 14,15,16 and not by pa,on
 234 #
 235 # accept/spots freq 0/30000 and by_zone 4,5
 236 #
 237 # accept/spots 2 vhf and (by_zone 14,15,16 or call_dxcc 61)
 238 #
 239 # no filter no implies filter 1
 240 #
 241 # The field nos are the same as for the 'Old' filters
 242 #
 243 #
 244
 245 sub it
 246 {
 247         my $self = shift;
 248
 249         my $filter;
 250         my @keys = sort $self->getfilkeys;
 251         my $key;
 252         my $type = 'Dunno';
 253         my $asc = '?';
 254
 255         my $r = @keys > 0 ? 0 : 1;
 256         foreach $key (@keys) {
 257                 $filter = $self->{$key};
 258                 if ($filter->{reject} && exists $filter->{reject}->{code}) {
 259                         $type = 'reject';
 260                         $asc = $filter->{reject}->{user};
 261                         if (&{$filter->{reject}->{code}}(ref $_[0] ? $_[0] : \@_)) {
 262                                 $r = 0;
 263                                 last;
 264                         } else {
 265                                 $r = 1;
 266                         }
 267                 }
 268                 if ($filter->{accept} && exists $filter->{accept}->{code}) {
 269                         $type = 'accept';
 270                         $asc = $filter->{accept}->{user};
 271                         if (&{$filter->{accept}->{code}}(ref $_[0] ? $_[0] : \@_)) {
 272                                 $r = 1;
 273                                 last;
 274                         } else {
 275                                 $r = 0;
 276                         }
 277                 }
 278         }
 279
 280         # hops are done differently (simply)
 281         my $hops = $self->{hops} if exists $self->{hops};
 282
 283         if (isdbg('filter')) {
 284                 my $call = $self->{name};
 285                 my $args = join '\',\'', map {defined $_ ? $_ : 'undef'} (ref $_[0] ? @{$_[0]} : @_);
 286                 my $true = $r ? "OK " : "REJ";
 287                 my $sort = $self->{sort};
 288                 my $dir = $self->{name} =~ /^in_/i ? "IN " : "OUT";
 289
 290                 $call =~ s/\.PL$//i;
 291                 my $h = $hops || '';
 292                 dbg("Filter: $call $true $dir: $type/$sort with '$asc' on '$args' $h") if isdbg('filter');
 293         }
 294         return ($r, $hops);
 295 }
 296
 297 sub print
 298 {
 299         my $self = shift;
 300         my $name = shift || $self->{name};
 301         my $sort = shift || $self->{sort};
 302         my $flag = shift || "";
 303         my @out;
 304         $name =~ s/.pl$//;
 305
 306         push @out, join(' ',  $name , ':', $sort, $flag);
 307         my $filter;
 308         my $key;
 309         foreach $key (sort $self->getfilkeys) {
 310                 my $filter = $self->{$key};
 311                 if (exists $filter->{reject} && exists $filter->{reject}->{user}) {
 312                         push @out, ' ' . join(' ', $key, 'reject', $filter->{reject}->{user});
 313                 }
 314                 if (exists $filter->{accept} && exists $filter->{accept}->{user}) {
 315                         push @out, ' ' . join(' ', $key, 'accept', $filter->{accept}->{user});
 316                 }
 317         }
 318         return @out;
 319 }
 320
 321 sub install
 322 {
 323         my $self = shift;
 324         my $remove = shift;
 325         my $name = uc $self->{name};
 326         my $sort = $self->{sort};
 327         my $in = "";
 328         $in = "in" if $name =~ s/^IN_//;
 329         $name =~ s/.PL$//;
 330         my $nossid = $name;
 331         $nossid =~ s/-\d+$//;
 332         my $dxchan = shift;
 333
 334         my @dxchan;
 335         if ($name eq 'NODE_DEFAULT') {
 336                 @dxchan = DXChannel::get_all_nodes();
 337         } elsif ($name eq 'USER_DEFAULT') {
 338                 @dxchan = DXChannel::get_all_users();
 339         } elsif ($dxchan) {
 340                 push @dxchan, $dxchan;
 341         } else {
 342                 $dxchan = DXChannel::get($name);
 343                 push @dxchan, $dxchan if $dxchan;
 344         }
 345         foreach $dxchan (@dxchan) {
 346                 my $n = "$in$sort" . "filter";
 347                 my $i = $in ? 'IN_' : '';
 348                 if ($remove) {
 349                         $dxchan->{$n} = undef;
 350                 }
 351                 unless ($dxchan->{$n}) {
 352                         Filter::load_dxchan($dxchan, $sort, $in);
 353                 }
 354         }
 355 }
 356
 357 # This simply fixes up an existing (or recently modified) Filter into
 358 # an existing dxchan
 359 sub load_dxchan
 360 {
 361         my $dxchan = shift;
 362         my $sort = lc shift;
 363         my $in = shift ? 'in' : '';
 364         my $nossid = $dxchan->call;
 365         $nossid =~ s/-\d+$//;
 366         my $n = "$in$sort" . "filter";
 367
 368         $dxchan->{$n} =
 369                 Filter::read_in($sort, $dxchan->call,  $in)     ||
 370                         Filter::read_in($sort, $nossid,  $in) ||
 371                                 Filter::read_in($sort, $dxchan->is_user ? 'user_default' : 'node_default', $in);
 372 }
 373
 374 sub delete
 375 {
 376         my ($sort, $call, $flag, $fno, $dxchan) = @_;
 377
 378         # look for the file
 379         my $fn = getfn($sort, $call, $flag);
 380         my $filter = read_in($sort, $call, $flag);
 381         if ($filter) {
 382                 if ($fno eq 'all') {
 383                         my $key;
 384                         foreach $key ($filter->getfilkeys) {
 385                                 delete $filter->{$key};
 386                         }
 387                         delete $filter->{getfilkeys};
 388                 } elsif (exists $filter->{"filter$fno"}) {
 389                         delete $filter->{"filter$fno"};
 390                 }
 391
 392                 # get rid
 393                 if ($filter->{hops} || $filter->getfilkeys) {
 394                         $filter->write;
 395                         Filter::load_dxchan($dxchan, $sort, $in);
 396                 } else {
 397                         unlink $fn;
 398                         $filter->install(1, $dxchan);
 399                 }
 400         }
 401 }
 402
 403
 404
 405 package Filter::Cmd;
 406
 407 use strict;
 408 use DXVars;
 409 use DXUtil;
 410 use DXDebug;
 411 use vars qw(@ISA);
 412 @ISA = qw(Filter);
 413
 414 sub encode_regex
 415 {
 416         my $s = shift;
 417         $s =~ s/\{(.*?)\}/'{'. unpack('H*', $1) . '}'/eg if $s;
 418         return $s;
 419 }
 420
 421 sub decode_regex
 422 {
 423         my $r = shift;
 424         my ($v) = $r =~ /^\{(.*?)}$/;
 425         return pack('H*', $v);
 426 }
 427
 428
 429 # the general purpose command processor
 430 # this is called as a subroutine not as a method
 431 sub parse
 432 {
 433         my ($self, $dxchan, $sort, $line, $forcenew) = @_;
 434         my $ntoken = 0;
 435         my $fno = 1;
 436         my $filter;
 437         my ($flag, $call);
 438         my $s;
 439         my $user = '';
 440
 441         # check the line for non legal characters
 442         dbg("Filter::parse line: '$line'") if isdbg('filter');
 443         my @ch = $line =~ m|([^\s\w,_\.:\/\-\*\(\)\$!])|g;
 444         return ('ill', $dxchan->msg('e19', join(' ', @ch))) if $line !~ /{.*}/ && @ch;
 445
 446         $line = lc $line;
 447
 448         # disguise regexes
 449
 450         dbg("Filter parse line after regex check: '$line'") if isdbg('filter');
 451         $line = encode_regex($line);
 452
 453         # add some spaces for ease of parsing
 454         $line =~ s/([\(\!\)])/ $1 /g;
 455
 456         my @f = split /\s+/, $line;
 457         dbg("filter parse: tokens '" . join("' '", @f) . "'") if isdbg('filter');
 458
 459         my $lasttok = '';
 460         while (@f) {
 461                 if ($ntoken == 0) {
 462
 463                         if (!$forcenew &&  @f && $dxchan->priv >= 8 && ((is_callsign(uc $f[0]) && DXUser::get(uc $f[0])) || $f[0] =~ /(?:node|user)_default/)) {
 464                                 $call = shift @f;
 465                                 if ($f[0] eq 'input') {
 466                                         shift @f;
 467                                         $flag++;
 468                                 }
 469                         } else {
 470                                 $call = $dxchan->call;
 471                         }
 472
 473                         if (@f && $f[0] =~ /^\d$/) {
 474                                 $fno = shift @f;
 475                         }
 476
 477                         $filter = Filter::read_in($sort, $call, $flag) unless $forcenew;
 478                         $filter = Filter->new($sort, $call, $flag) if !$filter || $filter->isa('Filter::Old');
 479
 480                         $ntoken++;
 481                         next;
 482                 }
 483
 484                 # do the rest of the filter tokens
 485                 if (@f) {
 486                         my $tok = shift @f;
 487
 488                         dbg("filter::parse: tok '$tok'") if isdbg('filter');
 489
 490                         if ($tok eq 'all') {
 491                                 $s .= '1';
 492                                 $user .= $tok;
 493                                 last;
 494                         } elsif (grep $tok eq $_, qw{and or not ( )}) {
 495                                 $s .= ' && ' if $tok eq 'and';
 496                                 $s .= ' || ' if $tok eq 'or';
 497                                 $s .= ' !' if $tok eq 'not';
 498                                 $s .=  $tok if $tok eq '(' or $tok eq ')';
 499                                 $user .= " $tok ";
 500                                 next;
 501                         } elsif ($tok eq '') {
 502                                 next;
 503                         }
 504
 505                         if (@f) {
 506                                 my $val = shift @f;
 507                                 my @val = split /,/, $val;
 508
 509                                 dbg("filter::parse: tok '$tok' val '$val'") if isdbg('filter');
 510                                 $user .= " $tok $val";
 511
 512                                 my $fref;
 513                                 my $found;
 514                                 foreach $fref (@$self) {
 515
 516                                         if ($fref->[0] eq $tok) {
 517                                                 if ($fref->[4]) {
 518                                                         my @nval;
 519                                                         for (@val) {
 520                                                                 push @nval, split(',', &{$fref->[4]}($dxchan, $_));
 521                                                         }
 522                                                         @val = @nval;
 523                                                 }
 524                                                 if ($fref->[1] eq 'a' || $fref->[1] eq 't') {
 525                                                         my @t;
 526                                                         foreach my $v (@val) {
 527                                                                 $v =~ s/\*//g;        # remove any trailing *
 528                                                                 if (my ($r) = $v =~ /^\{(.*)\}$/) { # we have a regex
 529                                                                         dbg("Filter::parse regex b: '\{$r\}'") if isdbg('filter');
 530                                                                         $v = decode_regex($v);
 531                                                                         dbg("Filter::parse regex a: '$v'") if isdbg('filter');
 532                                                                         return  ('regex', $dxchan->msg('e38', $v)) unless (qr{$v});
 533                                                                         push @t, "\$r->[$fref->[2]]=~m{$v}i";
 534                                                                         $v = "{$r}"; # put it back together again for humans
 535                                                                 } else {
 536                                                                         push @t, "\$r->[$fref->[2]]=~m{$v}i";
 537                                                                 }
 538                                                         }
 539                                                         $s .= "(" . join(' || ', @t) . ")";
 540                                                         dbg("filter parse: s '$s'") if isdbg('filter');
 541                                                 } elsif ($fref->[1] eq 'c') {
 542                                                         my @t;
 543                                                         for (@val) {
 544                                                                 s/\*//g;
 545                                                                 push @t, "\$r->[$fref->[2]]=~m{^\U$_}";
 546                                                         }
 547                                                         $s .= "(" . join(' || ', @t) . ")";
 548                                                         dbg("filter parse: s '$s'") if isdbg('filter');
 549                                                 } elsif ($fref->[1] eq 'n') {
 550                                                         my @t;
 551                                                         for (@val) {
 552                                                                 return ('num', $dxchan->msg('e21', $_)) unless /^\d+$/;
 553                                                                 push @t, "\$r->[$fref->[2]]==$_";
 554                                                         }
 555                                                         $s .= "(" . join(' || ', @t) . ")";
 556                                                         dbg("filter parse: s '$s'") if isdbg('filter');
 557                                                 } elsif ($fref->[1] =~ /^n[ciz]$/ ) {    # for DXCC, ITU, CQ Zone
 558                                                         my $cmd = $fref->[1];
 559                                                         my @pre = Prefix::to_ciz($cmd, @val);
 560                                                         return ('numpre', $dxchan->msg('e27', $_)) unless @pre;
 561                                                         $s .= "(" . join(' || ', map {"\$r->[$fref->[2]]==$_"} @pre) . ")";
 562                                                         dbg("filter parse: s '$s'") if isdbg('filter');
 563                                                 } elsif ($fref->[1] =~ /^ns$/ ) {    # for DXCC, ITU, CQ Zone
 564                                                         my $cmd = $fref->[1];
 565                                                         my @pre = Prefix::to_ciz($cmd, @val);
 566                                                         return ('numpre', $dxchan->msg('e27', $_)) unless @pre;
 567                                                         $s .= "(" . "!\$USDB::present || grep \$r->[$fref->[2]] eq \$_, qw(" . join(' ' ,map {uc} @pre) . "))";
 568                                                         dbg("filter parse: s '$s'") if isdbg('filter');
 569                                                 } elsif ($fref->[1] eq 'r') {
 570                                                         my @t;
 571                                                         for (@val) {
 572                                                                 return ('range', $dxchan->msg('e23', $_)) unless /^(\d+)\/(\d+)$/;
 573                                                                 push @t, "(\$r->[$fref->[2]]>=$1 && \$r->[$fref->[2]]<=$2)";
 574                                                         }
 575                                                         $s .= "(" . join(' || ', @t) . ")";
 576                                                         dbg("filter parse: s '$s'") if isdbg('filter');
 577                                                 } else {
 578                                                         confess("invalid filter function $fref->[1]");
 579                                                 }
 580                                                 ++$found;
 581                                                 last;
 582                                         }
 583                                 }
 584                                 return (1, $dxchan->msg('e20', $tok)) unless $found;
 585                         } else {
 586                                 $s = $tok =~ /^{.*}$/ ? '{' . decode_regex($tok) . '}' : $tok;
 587                                 return (1, $dxchan->msg('filter2', $s));
 588                         }
 589                         $lasttok = $tok;
 590                 }
 591         }
 592
 593         # tidy up the user string (why I have to stick in an if statement when I have initialised it I have no idea! 5.28 bug)?
 594         if ($user) {
 595                 $user =~ s/\)\s*\(/ and /g;
 596                 $user =~ s/\&\&/ and /g;
 597                 $user =~ s/\|\|/ or /g;
 598                 $user =~ s/\!/ not /g;
 599                 $user =~ s/\s+/ /g;
 600                 $user =~ s/\{(.*?)\}/'{'. pack('H*', $1) . '}'/eg;
 601                 $user =~ s/^\s+//;
 602                 dbg("filter parse: user '$user'") if isdbg('filter');
 603         }
 604
 605         if ($s) {
 606                 $s =~ s/\)\s*\(/ && /g;
 607                 dbg("filter parse: s '$s'") if isdbg('filter');
 608         }
 609
 610
 611         return (0, $filter, $fno, $user, $s);
 612 }
 613
 614 # a filter accept/reject command
 615 sub cmd
 616 {
 617         my ($self, $dxchan, $sort, $type, $line) = @_;
 618         return $dxchan->msg('filter5') unless $line;
 619
 620         my ($r, $filter, $fno, $user, $s) = $self->parse($dxchan, $sort, $line);
 621         return (1, $filter) if $r;
 622
 623         my $u = DXUser::get_current($user);
 624         return (1, $dxchan->msg('isow', $user)) if $u && $u->isolate;
 625
 626         my $fn = "filter$fno";
 627
 628         $filter->{$fn} = {} unless exists $filter->{$fn};
 629         $filter->{$fn}->{$type} = {} unless exists $filter->{$fn}->{$type};
 630
 631         $filter->{$fn}->{$type}->{user} = $user;
 632         $filter->{$fn}->{$type}->{asc} = $s;
 633         $r = $filter->compile($fn, $type);   # NOTE: returns an ERROR, therefore 0 = success
 634         return (0,$r) if $r;
 635
 636         $r = $filter->write;
 637         return (1,$r) if $r;
 638
 639         $filter->install(1);            # 'delete'
 640         $filter->install;
 641
 642     return (0, $filter, $fno);
 643 }
 644
 645 package Filter::Old;
 646
 647 use strict;
 648 use DXVars;
 649 use DXUtil;
 650 use DXDebug;
 651 use vars qw(@ISA);
 652 @ISA = qw(Filter);
 653
 654 # the OLD instructions!
 655 #
 656 # Each filter file has the same structure:-
 657 #
 658 # <some comment>
 659 # @in = (
 660 #      [ action, fieldno, fieldsort, comparison, action data ],
 661 #      ...
 662 # );
 663 #
 664 # The action is usually 1 or 0 but could be any numeric value
 665 #
 666 # The fieldno is the field no in the list of fields that is presented
 667 # to 'Filter::it'
 668 #
 669 # The fieldsort is the type of field that we are dealing with which
 670 # currently can be 'a', 'n', 'r' or 'd'.
 671 #    'a' is alphanumeric
 672 #    'n' is# numeric
 673 #    'r' is ranges of pairs of numeric values
 674 #    'd' is default (effectively, don't filter)
 675 #
 676 # Filter::it basically goes thru the list of comparisons from top to
 677 # bottom and when one matches it will return the action and the action data as a list.
 678 # The fields
 679 # are the element nos of the list that is presented to Filter::it. Element
 680 # 0 is the first field of the list.
 681 #
 682
 683 #
 684 # takes the reference to the filter (the first argument) and applies
 685 # it to the subsequent arguments and returns the action specified.
 686 #
 687 sub it
 688 {
 689         my $self = shift;
 690         my $filter = $self->{filter};            # this is now a bless ref of course but so what
 691
 692         my ($action, $field, $fieldsort, $comp, $actiondata);
 693         my $ref;
 694
 695         # default action is 1
 696         $action = 1;
 697         $actiondata = "";
 698         return ($action, $actiondata) if !$filter;
 699
 700         for $ref (@{$filter}) {
 701                 ($action, $field, $fieldsort, $comp, $actiondata) = @{$ref};
 702                 if ($fieldsort eq 'n') {
 703                         my $val = $_[$field];
 704                         return ($action, $actiondata)  if grep $_ == $val, @{$comp};
 705                 } elsif ($fieldsort eq 'r') {
 706                         my $val = $_[$field];
 707                         my $i;
 708                         my @range = @{$comp};
 709                         for ($i = 0; $i < @range; $i += 2) {
 710                                 return ($action, $actiondata)  if $val >= $range[$i] && $val <= $range[$i+1];
 711                         }
 712                 } elsif ($fieldsort eq 'a') {
 713                         return ($action, $actiondata)  if $_[$field] =~ m{$comp}i;
 714                 } else {
 715                         return ($action, $actiondata);      # the default action (just pass through)
 716                 }
 717         }
 718 }
 719
 720 sub print
 721 {
 722         my $self = shift;
 723         my $call = shift;
 724         my $sort = shift;
 725         my $flag = shift || "";
 726         return "$call: Old Style Filter $flag $sort";
 727 }
 728
 729 1;
 730 __END__