perl/Route/Node.pm

   1 #
   2 # Node routing routines
   3 #
   4 # Copyright (c) 2001 Dirk Koopman G1TLH
   5 #
   6 # $Id$
   7 #
   8
   9 package Route::Node;
  10
  11 use DXDebug;
  12 use Route;
  13 use Route::User;
  14 use DXUtil;
  15
  16 use strict;
  17
  18 use vars qw($VERSION $BRANCH);
  19 ($VERSION, $BRANCH) = dxver( q$Revision$);
  20
  21 use vars qw(%list %valid @ISA $max $filterdef $obscount);
  22 @ISA = qw(Route);
  23
  24 %valid = (
  25                   parent => '0,Parent Calls,parray',
  26                   nodes => '0,Nodes,parray',
  27                   users => '0,Users,parray',
  28                   usercount => '0,User Count',
  29                   version => '0,Version',
  30                   handle_xml => '0,Using XML,yesno',
  31                   lastmsg => '0,Last Route Msg,atime',
  32                   lastid => '0,Last Route MsgID',
  33                   do_pc92 => '0,Uses pc92,yesno',
  34                   via_pc92 => '0,Came in via pc92,yesno',
  35                   obscount => '0,Obscount',
  36 );
  37
  38 $filterdef = $Route::filterdef;
  39 %list = ();
  40 $max = 0;
  41 $obscount = 3;
  42
  43 sub count
  44 {
  45         my $n = scalar (keys %list);
  46         $max = $n if $n > $max;
  47         return $n;
  48 }
  49
  50 sub max
  51 {
  52         count();
  53         return $max;
  54 }
  55
  56 #
  57 # this routine handles the possible adding of an entry in the routing
  58 # table. It will only add an entry if it is new. It may have all sorts of
  59 # other side effects which may include fixing up other links.
  60 #
  61 # It will return a node object if (and only if) it is a completely new
  62 # object with that callsign. The upper layers are expected to do something
  63 # sensible with this!
  64 #
  65 # called as $parent->add(call, dxchan, version, flags)
  66 #
  67
  68 sub add
  69 {
  70         my $parent = shift;
  71         my $call = uc shift;
  72         confess "Route::add trying to add $call to myself" if $call eq $parent->{call};
  73         my $self = get($call);
  74         if ($self) {
  75                 $self->_addparent($parent);
  76                 $parent->_addnode($self);
  77                 return undef;
  78         }
  79         $self = $parent->new($call, @_);
  80         $parent->_addnode($self);
  81         return $self;
  82 }
  83
  84 #
  85 # this routine is the opposite of 'add' above.
  86 #
  87 # It will return an object if (and only if) this 'del' will remove
  88 # this object completely
  89 #
  90
  91 sub del
  92 {
  93         my $self = shift;
  94         my $pref = shift;
  95
  96         # delete parent from this call's parent list
  97         $pref->_delnode($self);
  98     $self->_delparent($pref);
  99         my @nodes;
 100         my $ncall = $self->{call};
 101
 102         # is this the last connection, I have no parents anymore?
 103         unless (@{$self->{parent}}) {
 104                 foreach my $rcall (@{$self->{nodes}}) {
 105                         next if grep $rcall eq $_, @_;
 106                         my $r = Route::Node::get($rcall);
 107                         push @nodes, $r->del($self, $ncall, @_) if $r;
 108                 }
 109                 $self->_del_users;
 110                 delete $list{$self->{call}};
 111                 push @nodes, $self;
 112         }
 113         return @nodes;
 114 }
 115
 116 # this deletes this node completely by grabbing the parents
 117 # and deleting me from them
 118 sub delete
 119 {
 120         my $self = shift;
 121         my @out;
 122
 123         $self->_del_users;
 124         foreach my $call (@{$self->{parent}}) {
 125                 my $parent = Route::Node::get($call);
 126                 push @out, $parent->del($self) if $parent;
 127         }
 128         return @out;
 129 }
 130
 131 sub del_nodes
 132 {
 133         my $parent = shift;
 134         my @out;
 135         foreach my $rcall (@{$parent->{nodes}}) {
 136                 my $r = get($rcall);
 137                 push @out, $r->del($parent, $parent->{call}, @_) if $r;
 138         }
 139         return @out;
 140 }
 141
 142 sub _del_users
 143 {
 144         my $self = shift;
 145         for (@{$self->{users}}) {
 146                 my $ref = Route::User::get($_);
 147                 $ref->del($self) if $ref;
 148         }
 149         $self->{users} = [];
 150 }
 151
 152 # add a user to this node
 153 sub add_user
 154 {
 155         my $self = shift;
 156         my $ucall = shift;
 157
 158         confess "Trying to add NULL User call to routing tables" unless $ucall;
 159
 160         my $uref = Route::User::get($ucall);
 161         my @out;
 162         if ($uref) {
 163                 @out = $uref->addparent($self);
 164         } else {
 165                 $uref = Route::User->new($ucall, $self->{call}, @_);
 166                 @out = $uref;
 167         }
 168         $self->_adduser($uref);
 169         $self->{usercount} = scalar @{$self->{users}};
 170
 171         return @out;
 172 }
 173
 174 # delete a user from this node
 175 sub del_user
 176 {
 177         my $self = shift;
 178         my $ref = shift;
 179         my @out;
 180
 181         if ($ref) {
 182                 @out = $self->_deluser($ref);
 183                 $ref->del($self);
 184         } else {
 185                 confess "tried to delete non-existant $ref->{call} from $self->{call}";
 186         }
 187         $self->{usercount} = scalar @{$self->{users}};
 188         return @out;
 189 }
 190
 191 sub usercount
 192 {
 193         my $self = shift;
 194         if (@_ && @{$self->{users}} == 0) {
 195                 $self->{usercount} = shift;
 196         }
 197         return $self->{usercount};
 198 }
 199
 200 sub users
 201 {
 202         my $self = shift;
 203         return @{$self->{users}};
 204 }
 205
 206 sub nodes
 207 {
 208         my $self = shift;
 209         return @{$self->{nodes}};
 210 }
 211
 212 sub parents
 213 {
 214         my $self = shift;
 215         return @{$self->{parent}};
 216 }
 217
 218 sub rnodes
 219 {
 220         my $self = shift;
 221         my @out;
 222         foreach my $call (@{$self->{nodes}}) {
 223                 next if grep $call eq $_, @_;
 224                 push @out, $call;
 225                 my $r = get($call);
 226                 push @out, $r->rnodes($call, @_) if $r;
 227         }
 228         return @out;
 229 }
 230
 231 # this takes in a list of node and user calls (not references) from
 232 # a config type update for a node and returns
 233 # the differences as lists of things that have gone away
 234 # and things that have been added.
 235 sub calc_config_changes
 236 {
 237         my $self = shift;
 238         my %nodes = map {$_ => 1} @{$self->{nodes}};
 239         my %users = map {$_ => 1} @{$self->{users}};
 240         my $cnodes = shift;
 241         my $cusers = shift;
 242         if (isdbg('route')) {
 243                 dbg("ROUTE: start calc_config_changes");
 244                 dbg("ROUTE: incoming nodes on $self->{call}: " . join(',', sort @$cnodes));
 245                 dbg("ROUTE: incoming users on $self->{call}: " . join(',', sort @$cusers));
 246                 dbg("ROUTE: existing nodes on $self->{call}: " . join(',', sort keys %nodes));
 247                 dbg("ROUTE: existing users on $self->{call}: " . join(',', sort keys %users));
 248         }
 249         my (@dnodes, @dusers, @nnodes, @nusers);
 250         push @nnodes, map {my @r = $nodes{$_} ? () : $_; delete $nodes{$_}; @r} @$cnodes;
 251         push @dnodes, keys %nodes;
 252         push @nusers, map {my @r = $users{$_} ? () : $_; delete $users{$_}; @r} @$cusers;
 253         push @dusers, keys %users;
 254         if (isdbg('route')) {
 255                 dbg("ROUTE: deleted nodes on $self->{call}: " . join(',', sort @dnodes));
 256                 dbg("ROUTE: deleted users on $self->{call}: " . join(',', sort @dusers));
 257                 dbg("ROUTE: added nodes on $self->{call}: " . join(',', sort  @nnodes));
 258                 dbg("ROUTE: added users on $self->{call}: " . join(',', sort @nusers));
 259                 dbg("ROUTE: end calc_config_changes");
 260         }
 261         return (\@dnodes, \@dusers, \@nnodes, \@nusers);
 262 }
 263
 264 sub new
 265 {
 266         my $pkg = shift;
 267         my $call = uc shift;
 268
 269         confess "already have $call in $pkg" if $list{$call};
 270
 271         my $self = $pkg->SUPER::new($call);
 272         $self->{parent} = ref $pkg ? [ $pkg->{call} ] : [ ];
 273         $self->{version} = shift || 5401;
 274         $self->{flags} = shift || Route::here(1);
 275         $self->{users} = [];
 276         $self->{nodes} = [];
 277         $self->{lastid} = {};
 278         $self->reset_obs;                       # by definition
 279
 280         $list{$call} = $self;
 281
 282         return $self;
 283 }
 284
 285 sub get
 286 {
 287         my $call = shift;
 288         $call = shift if ref $call;
 289         my $ref = $list{uc $call};
 290         dbg("Failed to get Node $call" ) if !$ref && isdbg('routerr');
 291         return $ref;
 292 }
 293
 294 sub get_all
 295 {
 296         return values %list;
 297 }
 298
 299 sub _addparent
 300 {
 301         my $self = shift;
 302     return $self->_addlist('parent', @_);
 303 }
 304
 305 sub _delparent
 306 {
 307         my $self = shift;
 308     return $self->_dellist('parent', @_);
 309 }
 310
 311
 312 sub _addnode
 313 {
 314         my $self = shift;
 315     return $self->_addlist('nodes', @_);
 316 }
 317
 318 sub _delnode
 319 {
 320         my $self = shift;
 321     return $self->_dellist('nodes', @_);
 322 }
 323
 324
 325 sub _adduser
 326 {
 327         my $self = shift;
 328     return $self->_addlist('users', @_);
 329 }
 330
 331 sub _deluser
 332 {
 333         my $self = shift;
 334     return $self->_dellist('users', @_);
 335 }
 336
 337 sub dec_obs
 338 {
 339         my $self = shift;
 340         $self->{obscount}--;
 341         return $self->{obscount};
 342 }
 343
 344 sub reset_obs
 345 {
 346         my $self = shift;
 347         $self->{obscount} = $obscount;
 348 }
 349
 350 sub DESTROY
 351 {
 352         my $self = shift;
 353         my $pkg = ref $self;
 354         my $call = $self->{call} || "Unknown";
 355
 356         dbg("destroying $pkg with $call") if isdbg('routelow');
 357 }
 358
 359 #
 360 # generic AUTOLOAD for accessors
 361 #
 362
 363 sub AUTOLOAD
 364 {
 365         no strict;
 366         my $name = $AUTOLOAD;
 367         return if $name =~ /::DESTROY$/;
 368         $name =~ s/^.*:://o;
 369
 370         confess "Non-existant field '$AUTOLOAD'" unless $valid{$name} || $Route::valid{$name};
 371
 372         # this clever line of code creates a subroutine which takes over from autoload
 373         # from OO Perl - Conway
 374         *$AUTOLOAD = sub {$_[0]->{$name} = $_[1] if @_ > 1; return $_[0]->{$name}};
 375         goto &$AUTOLOAD;
 376 }
 377
 378 1;
 379